VBAで２列のRangeをDictionaryに変換したい

Question

タイトル通り、VBAでRnageをDictionaryに変換したくて以下のような処理をかきました。
しかし構文エラーがと表示されます。どこが間違ているのでしょうか？

またRange.RowsはFor Eachで回すと一行ごとに配列で値参照できるという認識であってますでしょうか？MSのRange.Rowsの解説がガバガバ翻訳すぎて使い方が合ってる自信がありません。Debug.Printで確認できたらいいんですけど、構文エラーで先に進めないです。

ソースコード

Function SetDict(ByVal default_array As Range) As Object
    Dim dict
    Dim dar
    Set dict = CreateObject("Scripting.Dictionary")
    For Each dar As default_array.Rows
        dict.Add dar(1), dar(2)
    Next
    Set SetDict = dict
End Function
Sub Main()
    Debug.Print(SetDict(Range("M2:N8")))
End Sub

Answer 1

Yahoo知恵袋でも同様の質問をしており、そちらで頂いた解答をもとに最終的に以下のような形で落ち着きました。構文エラーはFor Each dar Inとすべき場所がAsになってました。

Function SetDict(ByVal default_array As Range) As Object
    Dim dict
    Dim dar
    Set dict = CreateObject("Scripting.Dictionary")
    For Each dar In default_array.Rows
        dict.Add dar.Cells(1).Text, dar.Cells(2).Value
    Next
    Set SetDict = dict
End Function

Sub InsertEquation(left, top, str)
    ActiveSheet.Shapes.AddLabel(msoTextOrientationHorizontal, left, top, 0, 0).Select
    Application.CommandBars.ExecuteMso "InsertBuildingBlocksEquationsGallery"
    Selection.Text = str
    Selection.Font.Size = 14
    Selection.ShapeRange.TextFrame2.WordWrap = msoFalse
    Application.CommandBars.ExecuteMso "EquationProfessional"
End Sub

Sub Main()
    Dim dict
    Set dict = SetDict(Range("M2:N8"))
End Sub

Answer 2

「２列のRangeをDictionaryに変換」の意味がよく分からないのですが。
最終的にDictionaryを使って何をしたいのか説明された方が適切な回答が得られると思います。

とりあえず、Dictionaryに、1列目の値をkeyとして、Itemに2列目の値を格納する、ということだとします。高速に検索する場合によく使う手法です。

なお、keyは重複は許されないので、1列目に重複がある場合は2つ目以降はスキップしてます。

Function SetDict(ByVal default_array As Range) As Object
    Dim dict
    Dim dar As Range
    Set dict = CreateObject("Scripting.Dictionary")
    For Each dar In default_array.Rows
        If Not myDic.Exists(dar.Cells(1).Value) Then
            dict.Add dar.Cells(1).Value, dar.Cells(2).Value
        End If
    Next
    Set SetDict = dict
End Function

Sub Main()
    Dim dict
    Set dict = SetDict(Range("M2:N8"))

    'KeyとItemを列挙
    Debug.Print "Key", "Item"
    Debug.Print "------", "-------"
    Dim k
    For Each k In dict
      Debug.Print k, dict.Item(k)
    Next
End Sub

---

dict.Add dar.Cells(1), dar.Cells(2) とか、dar.Columns(1), dar.Columns(2)
というように .Value を付けないと、Rangeオプジェクトそのものが格納されます。
こうすると、検索とか重複排除などの使い方ができないのであまり意味がないように思います。

Answer 3

こんな感じでどうでしょうか。

Function SetDict(ByVal default_array As Range) As Object
    Dim dict
    Dim dar As Range
    Set dict = CreateObject("Scripting.Dictionary")
    For Each dar In default_array.Rows
        dict.Add dar.Columns(1), dar.Columns(2)
    Next
    Set SetDict = dict
End Function
Sub Main()
    Dim d, e
    Set d = SetDict(Range("M2:N8"))
    For Each e In d
        Debug.Print e, d(e)
    Next
End Sub

---

＜追記＞

Function SetDict(ByVal default_array As Range) As Object
    Set SetDict = CreateObject("Scripting.Dictionary")
    Dim arr, i
    arr = default_array.Value
    For i = 1 To UBound(arr)
        SetDict.Item(arr(i, 1)) = arr(i, 2)
    Next
End Function