エクセルVBAを使い関数で表示された値を取得したい

Question

前提・実現したいこと

いつもお世話になっています。
エクセルのVBAを使用しShhet2の指定のセルに「異常」「警告」等、特定の文字が表示されるとSheet1に配置した図形の色を対応した物に変更される物を作りたいのですが、
現在のものだとSheet2のセルに直接文字を打ち込むと正常に作動するのですが、関数や他のVBAを使用して入力された値だと反応しません。
今のVBAを応用して、関数やVBAで表示した値でも正しく作動するようにはできないでしょうか？

該当のソースコード（Sheet2に入力中）

Private Sub Worksheet_Change(ByVal Target As Range)

 Dim shpName
 Select Case Target.Address
 Case "$B$2"
 shpName = "図形1"
 Case "$B$3"
 shpName = "図形2"
 Case Else
 Exit Sub
 End Select

 If Target.Value = "異常" Then
 Worksheets("Sheet1").Shapes(shpName).Fill.Visible = msoTrue
 Worksheets("Sheet1").Shapes(shpName).Fill.ForeColor.SchemeColor = 2 '赤
ElseIf Target.Value = "警告" Then
 Worksheets("Sheet1").Shapes(shpName).Fill.Visible = msoTrue
 Worksheets("Sheet1").Shapes(shpName).Fill.ForeColor.SchemeColor = 4 '黄

Else
 Worksheets("Sheet1").Shapes(shpName).Fill.Visible = msoFalse
 End If


 End Sub 

やりたいこと

1）Sheet1に図形配置（複数）が配置されている
2）Sheet2のチェックリストを入力すると内容に応じて指定のセル（今回のサンプルではB2・B3）に「異常」「警告」が表示
3）2の値が表示されるとSheet1の図形の色がそれぞれ赤・黄に変更

どうかよろしくお願いします。

Answer 1

Private Sub Worksheet_Change(ByVal Target As Range)
    Call 異常判定
End Sub

Sub 異常判定()

    Dim ws As Worksheet
    Set ws = Worksheets("Sheet2")
    
    Dim targetSheet As Worksheet
    Set targetSheet = Worksheets("Sheet1")
    
    With targetSheet.Shapes("図形1")
        Select Case ws.Range("$B$2").Value
        Case "異常"
            .Fill.Visible = msoTrue
            .Fill.ForeColor.SchemeColor = 2 '赤
        Case "警告"
            .Fill.Visible = msoTrue
            .Fill.ForeColor.SchemeColor = 4 '黄
        Case Else
            .Fill.Visible = msoFalse
        End Select
    End With
    
    With targetSheet.Shapes("図形2")
        Select Case ws.Range("$B$3").Value
        Case "異常"
            .Fill.Visible = msoTrue
            .Fill.ForeColor.SchemeColor = 2 '赤
        Case "警告"
            .Fill.Visible = msoTrue
            .Fill.ForeColor.SchemeColor = 4 '黄
        Case Else
            .Fill.Visible = msoFalse
        End Select
    End With

 End Sub

Comments

[texDL]

回答ありがとうございます！
このような書き方もできるのですね。
参考にさせていただきます。

Answer 2

通常はVBAで入力してもWorksheet_Changeイベントは発動するはずなので、

VBAで入力する前に、Application.EnableEvents = False としてませんか。

それはないとういことなら、「関数や他のVBAを使用して入力」の内容を提示してください。

Comments

[texDL]

お世話になります。
回答ありがとうございます。
現在質問内容にあるVBA以外何も設定していません。
例えばSheet2のB2を　=IF(C2>=80,"異常","警告")　入力し、C3に数字を入力しても図形の色を変えることはできませんでした。試しに　=C2 としC2セルに異常・警告の文字を入力しても作動しません。
お手数おかけしますが、よろしくお願いします。

[hatena19]

式の設定されたセルでは Changeイベントは発生しません。

提示のコードでは、
B2 または B3 が変更された時に処理してますので、Target はB2 または B3 です。
その隣のC2またはC3の値を調べないとだめですね。

If Target.Offset(,1).Value = "異常" Then
Worksheets("Sheet1").Shapes(shpName).Fill.Visible = msoTrue
Worksheets("Sheet1").Shapes(shpName).Fill.ForeColor.SchemeColor = 2 '赤
ElseIf Target.Offset(,1).Value = "警告" Then
Worksheets("Sheet1").Shapes(shpName).Fill.Visible = msoTrue
Worksheets("Sheet1").Shapes(shpName).Fill.ForeColor.SchemeColor = 4 '黄

[texDL]

ありがとうございます。

教えてくださった　Target.Offset(, 1)というのは一つ右のセルに変更があった場合という指示しょうか？
後出しで条件を追加して申し訳ございませんがC2のセルの内容を=SUM(D2:G2)とし、D2～G2の合計で判定したい場合はどのようなコードが必要でしょうか？

また、現状下記のように変更しましたが色は変わりませんでした。
そもそもの理解が間違えているのでしょうか？

Private Sub Worksheet_Change(ByVal Target As Range)

Dim shpName
Select Case Target.Address
Case "$B$2"
shpName = "図形1"
Case "$B$3"
shpName = "図形2"
Case Else
Exit Sub
End Select

If Target.Offset(, 1).Value = "異常" Then
Worksheets("Sheet1").Shapes(shpName).Fill.Visible = msoTrue
Worksheets("Sheet1").Shapes(shpName).Fill.ForeColor.SchemeColor = 2 '赤
ElseIf Target.Offset(, 1).Value = "警告" Then
Worksheets("Sheet1").Shapes(shpName).Fill.Visible = msoTrue
Worksheets("Sheet1").Shapes(shpName).Fill.ForeColor.SchemeColor = 5 '黄

Else
Worksheets("Sheet1").Shapes(shpName).Fill.Visible = msoFalse
End If

End Sub

予備知識もほとんどなくお手数おかけしますが、よろしくお願いします。

[hatena19]

あっ、勘違いしてました。B2、B3に式が設定されているのでしたね。
C2、C３の変更でB2、B3の表示が変わるので、

Dim shpName
Select Case Target.Address
Case "$C$2"
shpName = "図形1"
Case "$C$3"
shpName = "図形2"
Case Else
Exit Sub
End Select
If Target.Offset(, -1).Value = "異常" Then
Worksheets("Sheet1").Shapes(shpName).Fill.Visible = msoTrue
Worksheets("Sheet1").Shapes(shpName).Fill.ForeColor.SchemeColor = 2 '赤
ElseIf Target.Offset(, -1).Value = "警告" Then
Worksheets("Sheet1").Shapes(shpName).Fill.Visible = msoTrue
Worksheets("Sheet1").Shapes(shpName).Fill.ForeColor.SchemeColor = 5 '黄

Else
Worksheets("Sheet1").Shapes(shpName).Fill.Visible = msoFalse
End If

[hatena19]

> =SUM(D2:G2)

なら、
If Not Intersect(Target, Range("D2:G3")) Then
というように判断します。

式が参照しているセルが変更されたかどうかをチェックする必要があります。

[texDL]

ありがとうございます。
お返事遅くなり大変申し訳ございませんでした。
思っていた通りの動作をするようになりました！

またわからないことがあれば質問させていただきたいと思います、その時はぜひよろしくお願いします。