VBA stream 新規保存をしたい

Question

こちらでご教示いただきました。
下記のコードでエクセルシート状に出力後、
シート上で値の書き換えを行います。(例：Sheet2 A4に”04”をValue)
そのあと保存をしたいのですが、ActiveWorkbook.SaveAsを使用すると数字の0が消えてしまいます。
こちらもstreamで保存しないといけないと思うのですが…
上書きでなく、新規保存する場合のコードの書き方が分からないです。。

Sub sample2()
    Dim i As Long
    Dim j As Long
    Dim strList As String
    Dim strSplit() As String
    Dim adoSt As New ADODB.Stream
    Dim selectFileName
    
    '//ダイアログを開く
'    ws.Cells.Clear '//ファイルクリア
    selectFileName = Application.GetOpenFilename(FileFilter:="CSVファイル(*.csv),*.csv", _
                                        Title:="CSVファイルの選択")
        If selectFileName = False Then
        Exit Sub
        End If
        
    i = 1
    With adoSt
        .Type = adTypeText
        .charset = "Shift-JIS"
        .LineSeparator = adLF
        .Open
        .LoadFromFile (selectFileName)
        Do While Not (.EOS)
            strList = .ReadText(adReadLine)
            strSplit = Split(strList, ",")
            For j = LBound(strSplit) To UBound(strSplit)
                ThisWorkbook.Worksheets("Sheet2").Cells(i, j + 1) = strSplit(j)
            Next
            i = i + 1
        Loop
        .Close
       
    
    
    End With
End Sub

Answer 1

そのあと保存をしたいのですが、ActiveWorkbook.SaveAsを使用すると数字の0が消えてしまいます。

数字の0が消えてしまうというのは、セルの書式設定の問題だと思います。
最初は「標準」になってますが、数値と判断できるものは数値となり、先頭の0は消えます。
事前に代入範囲のセル書式を「文字列」に設定しておけば0は消えません。
SaveAsは関係ないです。

VBAでその都度書式設定するなら、下記のようにすればいいでしょう。

        For j = LBound(strSplit) To UBound(strSplit)
            ThisWorkbook.Worksheets("Sheet2").Cells(i, j + 1).NumberFormatLocal = "@"
            ThisWorkbook.Worksheets("Sheet2").Cells(i, j + 1).Value = strSplit(j)
        Next

上書きでなく、新規保存する場合のコードの書き方が分からないです。。

SaveAsは新規保存です。
Saveなら上書きです。

Comments

[12356]

ご回答ありがとうございます。
もう1つご質問ですが
>VBAでその都度書式設定するなら、下記のようにすればいいでしょう。
こちらのコードですがカラム指定で書式設定することは可能でしょうか。
例）Sheet2の"B"

可能であればご回答いただけると幸いです。

[hatena19]

可能です。

ThisWorkbook.Worksheets("Sheet2").Range("B:B”).NumberFormatLocal = "@"

とか

ThisWorkbook.Worksheets("Sheet2").Columns(2).NumberFormatLocal = "@"

[12356]

ありがとうございます！
そういう書き方もできるのですね。
とても勉強になりました！