スプシでArrayFormula×vlookupかつ大文字小文字を区別したい

Question

■やりたいこと
スプシでArrayformulaを活用して、vlookup関数でデータの引き当てを行いたいです。
例）シート1のA列の文字（大文字小文字混在）をキーに、シート2のB列にあるデータを引き当てたい。

■困っていること
諸々調べましたが大文字小文字を区別するにはindex match関数を使うしかないが、arrayformulaとindex matchは併用できないという状況で詰まっております。

以前こちらで教えていただいたREGEXREPLACEを利用して以下のような式も試してみたのですが、うまく動作いたしませんでした。よろしければアドバイスいただけますと幸いです。

=ArrayFormula(vlookup(REGEXREPLACE(A2:A,"([a-z])","$1"),REGEXREPLACE('シート2'!$A:$B,"([a-z])","$1"),2,0))

Answer 1

ArrayFormula×vlookupかつ大文字小文字を区別

以下、サンプルです。

シート：シート1
( A列・B列 ) ※1行目はヘッダ、データはA列の2行目以降のみ

文字	式
a
A
AB
c
ab

シート：シート2
( A列・B列 ) ※データはA列B列ともに1行目から

C	1
d	2
a	3
A	4
ab	5
AB	6
B	7
c	8

シートAのB2セルに式を記述

=arrayFormula(
    ifError(
        vLookup(regexReplace(A2:A, "([a-z])", "_$1")
              , {
                    arrayFormula(
                        regexReplace('シート2'!A:A, "([a-z])", "_$1")
                    )
                  , query('シート2'!B:B, "select B")
                }
             , 2
             , false
        )
      ,
    )
)

■結果( シート1 )

文字	式
a	3
A	4
AB	6
c	8
ab	5

Comments

[NN77]

こちら実現できました！query関数を利用するという手があったのですね。大変勉強になりました！