VBA:一つ上のセルとセル結合がしたい

Question

前提・実現したいこと

A列のセルが一つ上のセルと値が同じだったら、
B列の一つ上のセルとセル結合をしたいです。

コードを書いてみたのですが、エラーが起きてしまいます。

発生している問題・エラーメッセージ

ws.Range("B" & cnt).Offset(-1, 0).Select.Merge

ここの部分でアプリケーション定義、オブジェクト定義のエラーとでてしまいます。

該当のソースコード

Sub セル結合()
Dim ws As Worksheet
Dim i
Dim cnt As Long
Set ws = Worksheets("Sheet1")
cnt = 1

 For i = 2 To ws.Range("A10000").End(xlUp).Row
   
     If ws.Range("A" & i).value = ws.Range("A" & i - 1).value Then

        
         ws.Range("B" & cnt).Offset(-1, 0).Select.Merge
         
         cnt = cnt + 1
         
     End If
     
 Next

End Sub

よろしければ、ご回答お願いしたいです。

Answer 1

ws.Range("B" & cnt).Offset(-1, 0).Select.Merge

でなぜエラーになるのかというと、Selectはセルを選択しなさいというメソッド(命令)なので、それがMergeというメソッドは持っていないからエラーになる。

下記のようにSelectで選択して、
選択した範囲(Selection)に対してMergeすればエラーにはならない。

ws.Range("B" & cnt).Offset(-1, 0).Select
Selection.Merge

ただし、選択範囲は１セルのみなのでセル結合にはならない。
下記のようにResizeで選択範囲を平げる必要があります。

ws.Range("B" & cnt).Offset(-1, 0).Resize(2).Select
Selection.Merge

ただMergeするのに選択する必要はないので、下記のようにすればOKです。

ws.Range("B" & cnt).Offset(-1, 0).Resize(2).Merge

とりあえずエラーの原因だけの指摘です。
やりたいことが不明瞭なので、コード全体が希望と合致しているかはわかりません。
cntを使う意味など。

---

たぶんやりたいことは下記のようなことかな。
For Eachを使ったコード例。

Sub セル結合()
    Dim ws As Worksheet
    Set ws = Worksheets("Sheet1")
    
    Dim c As Range
    For Each c In ws.Range(ws.Cells(2, 1), ws.Range("A10000").End(xlUp)).Cells
        If c.Value = c.Offset(-1).Value Then
            c.Offset(-1, 1).Resize(2).Merge
        End If
    Next
End Sub

Comments

[aaaskw123123]

すごくわかりやすくて納得しました。
勉強になります。ありがとうございます!!

Answer 2

こんな感じでどうでしょうか。

 For i = 2 To ws.Range("A10000").End(xlUp).Row
     If ws.Range("A" & i).Value = ws.Range("A" & i - 1).Value Then
         ws.Range("B" & i, "B" & i - 1).Merge
     End If
 Next

Comments

[aaaskw123123]

結合することができました。ありがとうございます!!