VBA 同じ処理だがオブジェクトが違う処理のまとめ方

Question

前提・実現したいこと

Formの複数ある日付を入力するTextBoxに、Format関数で変換処理をさせたい

発生している問題・エラーメッセージ

Private Sub Text_Date1_AfterUpdate()
    Text_Date1.Value = Format(Text_Date1.Value, "ge年mm月dd日")
End Sub
Private Sub Text_Date2_AfterUpdate()
    Text_Date2.Value = Format(Text_Date2.Value, "ge年mm月dd日")
End Sub
   ・
   ・
   ・

変換したい項目は5つ程あるので一つにまとめたいが、データ元が異なるのでまとめ方がわかりません。

Private Sub Text_Date1_AfterUpdate(), Text_Date2_AfterUpdate(),・・・

End Sub

イメージとしては上記のような感じでひとまとまりにしたいです。
※イメージなのでまとめ方は問いません。

試したこと

「同じ処理のまとめ方」などで調べたのですが、関数の使い方しか出てこず。
調べる際のキーワードも教えていただけると幸いです。

Answer 1

Text_Date1_AfterUpdate() ということは複数コントロールのイベントを共通化したいということですね。

こういう場合はクラスモジュールを使うことになります。
VBAウィンドウで、[挿入]→[クラスモジュール]でクラスモジュールを新規作成して、オブジェクト名を
clsTextBoxとします。
そこに下記のコードを記述します。

Option Explicit

Public WithEvents pTextBox As MSForms.TextBox

Private Sub pTextBox_KeyDown(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
    Select Case KeyCode
    Case vbKeyTab, vbKeyReturn
        If IsDate(pTextBox.Value) Then
            pTextBox.Value = Format(pTextBox.Value, "ge年mm月dd日")
        End If
    End Select
End Sub

本当は AfterUpdateイベントを使いたいのですが、クラスモジュールでは使えないので、KeyDownイベントでEnterキーかTabキーを押したときに発動するようにしてます。
これを保存します。

ユーザーフォームには下記のコードを記述します。

テキストボックスが４つある場合です。
TextBox1～TextBox4

Option Explicit

Dim myTB(1 To 4) As New clsTextbox

Private Sub UserForm_Initialize()
    Dim i As Long
    For i = 1 To 4
        Set myTB(i).pTextBox = Me.Controls("TextBox" & i)
    Next
End Sub

以上です。
分かりやすいようにシンプルなコードにしましたので、かなり手抜きのコードです。
興味がありましたら、「VBA クラスモジュール」でWEB検索してみてください。

---

参考

AfterUpdateイベントは使えないと書きましたが、下記で紹介されている方法を使えば使えるようにできます。

イベントプロシージャーの共通化（Enter,Exit）｜ユーザーフォーム入門

Comments

[D0NKAMA]

回答ありがとうございます。クラスモジュールを使うと思った通りの処理を簡潔に書くことができました！
まだ何となくでしか理解できていないので自分で調べて応用できるようにしたいと思います。

Answer 2

こんな感じでどうでしょうか。

Sub test()
    DateFormat TextBox1, TextBox2
End Sub

Function DateFormat(ParamArray tb())
    Dim t
    For Each t In tb
        t.Value = Format(t.Value, "ge年mm月dd日")
    Next
End Function