awkを使った２つのファイル要素の計算

Question

awkで２つのファイルの要素を算術計算して，出力することはできますか？
具体的には
1 2 3
4 5 6
というファイルと（実際はもっと行列とも数が多い）
3 4 5
6 7 8
というファイルの各要素を足して（あるいは四則演算して）
4 6 8
10 12 14
というようなファイルに出力したいのです．
よろしくお願いします．

Comments

[takasima20]

とくにこだわりがないのなら Python とか使った方がラクな気がします。

[KojiDoi]

画像ファイルの演算なら、imagemagickを使うのが手っ取り早い気がします。

Answer 1

わざわざご回答をいただいた皆様．どうもありがとうございました．awkは単一ファイル内だと処理が簡単なのですが，複数ファイルの処理はやや手間取ることがわかりました．それでもawkの使い方にまた精進できました．くだんのpgm画像ファイルは書き出し部分のコードを変更して，２つのファイルの加算を書き出しの部分で行えることがわかりました．お手数をおかけしました．また何かありましたらどうぞよろしくお願いします．

Answer 2

スクリプトを作ってみました。
ファイルの行数,列数が違っている場合は少ない方に0が入っていると見なして加算するような動作になります。
ファイルが3個以上ある場合でも、すべてのファイルについて行と列をそのまま足していくような動作になります。

{
        # v[行,列] にデータを加算していく
        for(x=1;x<=NF;++x){
                v[FNR,x]+=$x
        }
        # 行ごとの最大列を調べておく
        if(fields[FNR]<NF){
                fields[FNR]=NF
        }
        # 最大行を調べておく
        if(lines<FNR){
                lines=FNR
        }
}
END{
        # 最後に結果を出力する
        for(y=1;y<=lines;++y){
                for(x=1;x<=fields[y];++x){
                        printf v[y,x] " "
                }
                print ""
        }
}

実行結果です。

$ cat plus.awk
{
        # v[行,列] にデータを加算していく
        for(x=1;x<=NF;++x){
                v[FNR,x]+=$x
        }
        # 行ごとの最大列を調べておく
        if(fields[FNR]<NF){
                fields[FNR]=NF
        }
        # 最大行を調べておく
        if(lines<FNR){
                lines=FNR
        }
}
END{
        # 最後に結果を出力する
        for(y=1;y<=lines;++y){
                for(x=1;x<=fields[y];++x){
                        printf v[y,x] " "
                }
                print ""
        }
}

$ cat 1.txt
1 2 3
4 5 6

$ cat 2.txt
3 4 5
6 7 8

$ cat 3.txt
10 20 30 40
50 60 70
80 90

$ awk -f plus.awk 1.txt 2.txt
4 6 8 
10 12 14 

$ awk -f plus.awk 1.txt 2.txt 3.txt
14 26 38 40 
60 72 84 
80 90 

Comments

[Wombat]

回答ありがとうございました．上記で目的は達成できそうですが，元のpgmの書き出しコードを変更して，２つのファイルの加算と同じ効果が出るようにしました．お手数をおかけして申しわけありませんでした．またどうぞよろしくお願いします．

Answer 3

両ファイルの列数が完全に同じであったとして、

# test.awk
NR==1{
    n=NF/2
}
{
    for(i=1; i<n; i++){
        j=i+n
        printf "%d%s", $i+$j, OFS
    }
    print $i+$NF
}

$ paste a.txt b.txt |awk -f test.awk 

Comments

[Wombat]

ご回答ありがとうございます．実はターゲットファイルはpgm画像ファイルなので，現在その扱いを検討しています．ご回答いただきありがとうございました．pgmファイルなので行と列は同じ数のファイルとなります．

[Wombat]

Imagemagickを使う件，ご示唆ありがとうございます．なるほどぞの手もありましたね．気付きませんでした．pgmファイルはヘッダが付いているので，Processingでの扱いも単純に行列（Table）として扱えず，色々と試行しております．ご回答を感謝します！