同時に発生するオブジェクトのクリック・ドラッグイベントを判別する方法について

インジケーターにてオブジェクトのクリック・ドラッグイベントをモニタリングした所、

mq4
1void OnChartEvent(const int id, const long &lparam, const double &dparam, const string &sparam)
2{
3  if (id == CHARTEVENT_OBJECT_CLICK || id == CHARTEVENT_OBJECT_DRAG)
4    Print(
5      "[click] ", (id == CHARTEVENT_OBJECT_CLICK), " ",
6      "[drag] ", (id == CHARTEVENT_OBJECT_DRAG), " ",
7      "[x, y] ", (int)lparam, ", ", (int)dparam
8    );
9}

ターミナルに出力されたログは以下の様になりました。

txt
1// 水平線をクリックした時
22021.09.02 14:16:35.506 TestIndicator NZDJPY,M15: [click] true [drag] false [x, y] 467, 72
32021.09.02 14:16:35.506 TestIndicator NZDJPY,M15: [click] false [drag] true [x, y] 0, 0
4
5// 水平線をドラッグした時
62021.09.02 14:25:14.912 TestIndicator NZDJPY,M15: [click] true [drag] false [x, y] 477, 136
72021.09.02 14:25:14.912 TestIndicator NZDJPY,M15: [click] false [drag] true [x, y] 0, 0

同じオブジェクトに対してクリックとドラッグで処理を分けたいのですが、
ログの様に両イベントが同時に発生しておりどちらの操作を行ったのかが判別できません。

質問ですが、
クリックとドラッグのどちらの操作を行ったかを判別する方法はないでしょうか？

よろしくお願いいたします。

行動規範の内容に同意します

回答1件

ベストアンサー

マウスの左ボタンを押したときの座標と放したときの座標が一致する場合はクリック、
それ以外はドラッグという感じで判定してみました。

基本的には、座標が格納されてくるCHARTEVENT_OBJECT_CLICKだけを使って判定しています。

ただ、チャートの何もないところで左ボタンを押して、オブジェクトの上で放すと
CHARTEVENT_OBJECT_CLICKイベントだけがくるので、ドラッグの判定のために
CHARTEVENT_OBJECT_DRAGが来ていたかどうかも判定しています。

判定ミスとかはあるかもしれません。

MQL4
1int OnInit()
2{
3    ChartSetInteger(0, CHART_EVENT_MOUSE_MOVE, 1);
4
5    return INIT_SUCCEEDED;
6}
7
8bool IsMouseDown(uint state)
9{
10    return (state & 1) != 0;
11}
12
13void OnChartEvent(const int id, const long &lparam, const double &dparam, const string &sparam)
14{
15    static int prevX = INT_MIN;
16    static int prevY = INT_MIN;
17    static bool isDown = false;
18    static bool isDragging = false;
19
20    if (id == CHARTEVENT_OBJECT_DRAG)
21    {
22        isDragging = true;
23    }
24
25    if (id == CHARTEVENT_OBJECT_CLICK)
26    {
27        if (prevX == INT_MIN && prevY == INT_MIN)
28        {
29            //printf("double click");
30            return;
31        }
32
33        int x = (int)lparam;
34        int y = (int)dparam;
35
36        if (prevX != x || prevY != y)
37        {
38            if (isDragging)
39            {
40                printf("drag  prev = (%d, %d), curr = (%d, %d)", prevX, prevY, x, y);
41            }
42        }
43        else
44        {
45            printf("click prev = (%d, %d), curr = (%d, %d)", prevX, prevY, x, y);
46        }
47
48        prevX = INT_MIN;
49        prevY = INT_MIN;
50        isDown = false;
51        isDragging = false;
52    }
53
54    if (id == CHARTEVENT_MOUSE_MOVE)
55    {
56        int x = (int)lparam;
57        int y = (int)dparam;
58
59        if (IsMouseDown((uint)sparam))
60        {
61            if (!isDown)
62            {
63                //printf("mouse down prev = (%d, %d), curr = (%d, %d)", prevX, prevY, x, y);
64                prevX = x;
65                prevY = y;
66                isDown = true;
67                isDragging = false;
68            }
69        }
70        else
71        {
72            prevX = INT_MIN;
73            prevY = INT_MIN;
74            isDown = false;
75            isDragging = false;
76        }
77    }
78}
79