MQLで最新足を更新するには？

Question

発生している問題

MQL5で終値をラインで結ぶ簡単なカスタムインジケーターを作ってみたんですが

このように上手く更新されません。
サブウィンドウは別の自作インジケーターですが、これも０に張り付いています
過去足は上手く計算できているみたいですが、最新足が更新されると０になります
調べて試行錯誤してみたのですが解決できなかったので皆さんのお力を貸してください

該当のソースコード

int OnInit(){
//--- indicator buffers mapping
   SetIndexBuffer(0, Label1Buffer, INDICATOR_DATA);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[]){
//---

   int num_uncalculated = rates_total - prev_calculated;
   for(int i = num_uncalculated - 1; i >= 0; i--){
      
      Label1Buffer[i]  = close[i];
      
      }
//--- return value of prev_calculated for next call
   return(rates_total);
  }

試したこと

return(rates_total);　を return(rates_total - 1);　にしてみましたが解決しませんでした

Answer 1

MT5からはrates_total - 1が最新の足になります。
なので、今のままだと
0. 初回: prev_calculatedが0なので全てのバーを更新
0. 最新のローソク足が更新されたとき: rates_total - prev_calculatedが0なので計算なし
0. 新しいローソク足が出来たとき: rates_total - prev_calculatedが1なのでLabel1Buffer0だけ更新

となり、最新のバーが更新されないことが原因です。

ArraySetAsSeriesで反転させるか、普通にループするようにしましょう。

#property strict

#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots 1
#property indicator_type1 DRAW_LINE
#property indicator_style1 STYLE_SOLID
#property indicator_color1 clrRed
#property indicator_width1 1

double Label1Buffer[];

int OnInit()
{
    SetIndexBuffer(0, Label1Buffer);
    return INIT_SUCCEEDED;
}

int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
{
    int start = MathMax(0, prev_calculated - 1);
    for(int i = start; i < rates_total; i++)
    {
        Label1Buffer[i]  = close[i];
    }

    return rates_total;
}

Comments

[z4m1]

MQL4の情報を参考にしていたので間違えていたんですね！ご丁寧にありがとうございます！