Processing で虹色を描くにはどうしたらよいでしょうか？

Question

前提・実現したいこと

Processingで顔を認識し、
顔の周りに放射線状の虹色の線を描きたいと考えています。

発生している問題

・lineの角度によって色を変化させる（虹色にする）　

にはどのようにしたら良いのでしょうか。
ご教授頂けますと幸いです。

### import gab.opencv.*;
import processing.video.*;
import java.awt.Rectangle;

Capture cam;
OpenCV opencv;
Rectangle[] faces;
boolean playing; 

int x;
float angle;

void setup(){
  size(displayWidth, displayHeight);
  
  String[] cameras = Capture.list();
  cam = new Capture(this, cameras[0]);
  cam.start();
}

void draw(){
  if(cam.available() == true){
    cam.read(); 
    image(cam, 0, 0, displayWidth, displayHeight);
    opencv = new OpenCV(this, cam);
    opencv.loadCascade(OpenCV.CASCADE_FRONTALFACE);
    faces = opencv.detect();
    
  }  

  for (int i=0; i<faces.length; i++) {
    
      angle +=0.07;
      
      //顔のx座標とy座標
      float cx = displayWidth-(faces[i].x*2+faces[i].width);
      float cy = faces[i].width;
      
      int a = 7;
      int b = 7;

 　　　//角度に合わせて、色を変化させる
      rotate( radians( angle ) );
      stroke( angle, 100, 100 );
      strokeWeight(1);
      
      line(
        cx + cos(angle * a) * 50,
        cy + sin(angle * b) * 50,
        cx + cos(angle * a) * 150,
        cy + sin(angle * b) * 150
        );
        
      for (int j = 1; j <= 50; j++) {
        
      line(
        cx + cos(j) * 50,
        cy + sin(j) * 50,
        cx + cos(j) * 150,
        cy + sin(j) * 150
        );
      } 
  }
  
}

現在のディスプレイウインドウです。虹色にする事ができません。
下記の部分が間違っているのでしょうか。

　　　//角度に合わせて、色を変化させる
      rotate( radians( angle ) );
      stroke( angle, 100, 100 );
      strokeWeight(1);

環境

Processing3.5.4
Mac OS

Answer 1

現在のディスプレイウインドウです。虹色にする事ができません。
下記の部分が間違っているのでしょうか。

stroke(angle, 100, 100)のように書くときは、HSBモードを使用します（colorMode(HSB, 360, 100, 100)等）

デフォルトはRGBモードですので、赤成分だけをいじっていることになります。
それでは虹色にはなりようがありませんね？

colorMode / Processing.org

---

lineの長さを変化させ、波打っているように見せる

編集されたので取り下げたということだと思いますが、一応やってみました。

完全にランダムだと波打っているようには見えないため、noise（パーリンノイズ）でやるのがいいんでしょう（よくわかっていませんが^^;

単純にnoiseでやるとスムーズにつながらない部分が出るため、ググって出てきたこちらをそのまま使わわせていただきました。
周期的ノイズについて（2020.06.12） • Koji's Site

しかし線がピクピクする（微妙に角度が変わる）のが気になります（精度の問題?? 線が十分長い（2000とか）と気にならないのですが^^;

import java.awt.Rectangle;

Rectangle[] faces;


void setup() {
  size(400, 400);
  //             色相 彩度 明るさ
  colorMode(HSB, 360, 100, 100);
  noFill();

  faces = new Rectangle[]{ new Rectangle(100, 100), };
}

void draw() {
  background(0);

  faces[0].setLocation(mouseX - 50, mouseY - 50);

  for (Rectangle face : faces) {
    niji(face);
  }
}

void niji(Rectangle rect) {
  pushMatrix();
  translate(rect.x + rect.width/2, rect.y + rect.height/2);

  for (int j = 1; j <= 50; j++) {
    // colorModeで色相を0～360に設定したので、jを度に変える 360°以上回っているので剰余をとって360内に収める
    stroke(degrees(j) % 360, 100, 100);

    // 周期的ノイズ 1のところを大きくすると変動が早くなる 小さくすると遅くなる
    float d = cnoise(degrees(j) + frameCount * 1, 360) * 30;
    // 上のforを j <= 500 とかにするとわかりやすいが、単純にnoiseだと3時の位置がスムーズに繋がらない
    //float d = noise((degrees(j) % 360) * 0.05, frameCount * 0.05) * 30;

    float l = 150 + d;
    line(cos(j) * 50, sin(j) * 50, cos(j) * l, sin(j) * l);
  }
  popMatrix();
}

// [周期的ノイズについて（2020.06.12） • Koji's Site](http://koji.jpn.org/mytweetprocessing/tw20200612/)
float cnoise(float t, float c) {
  float p = t * TWO_PI / c;
  return noise(cos(p) + 1, sin(p) + 2);
}

Comments

[mia_flower]

先日質問した際はお世話になりました。今回もご丁寧に回答して頂きまして感謝しております。

colorModeには2種類の書き方があったのですね。。理解いたしました。
色相の設定の仕方なども非常に勉強になりました。今後活用したいと思います。

教えて頂いたコードをもとに、顔の中心座標から虹を描くように設定してみました。
綺麗な虹が描かれ感動しています。波打つ表現に周期的ノイズを使うというアイデアに、目から鱗でした。

ありがとうございます。