RowとColumnを引数とした切り替えコードを作成したいです。

Question

VBA初学者です。回答よろしくお願い致します。

#####目的
（１）規則的に『行』を非表示にする 少し複雑なコード（最下部の※を参照）があり
これを、コピペし『Row』を『Column』に手で入力し直せば『列』方向のコードになります。

（２）しかし、メンテンナンス性の向上のため、ベースとなるコードに対して
**『Rows』『Columns』**を入力すれば、『行・列』の切り替えができるコードが作りたいです。

#####具体的に欲しいコード

以下のコードは全く作動しませんが、例をあげると こういった感じかなと思っています。

Sub test2()

Dim a As String
a = InputBox("入力して下さい")　←Rows か Columnsを入力
a & "("4:7")".Select　　　　　　　←Columns("4:7").Selectとなり、列方向が選択される

End Sub

#####※規則的に『行』を非表示にするコード
以下のコードを、引数を使って、行・列を切り替えられたらと思っています。

Sub 選択行を非表示()

Dim my非行 As Long
my非行 = 5
     
Dim my行始め As Long
my行始め = Selection.Row
Dim my行終わり
my行終わり = Selection.Rows.Count + my行始め - 1
Dim my行終わり2 As Long
my行終わり2 = (Selection.Rows.Count \ my非行) * my非行 + my行始め - 1


If my行終わり - my行始め < 2001 Then

    Rows(my行始め & ":" & my行終わり).Hidden = False
    
    Dim i As Long
    For i = my行始め To my行終わり2 Step my非行
    
       Rows(i + 1 & ":" & i + my非行 - 1).Hidden = True
    Next i
    
Else
    MsgBox "処理量が大きいので、マクロを中止しました"

End If

End Sub

Answer 1

オブジェクト指向のポリモーフィズム（多態性）という手法を使う方法があります。

元のコードを以下に書き換えます

Option Explicit

Sub 選択行を非表示()
    
'    Dim objSelection As ClassRow
'    Dim objSelection As ClassCol
    Dim objSelection As Object
    Dim a
    a = InputBox("入力して下さい")
    If a = "col" Then
        Set objSelection = New ClassCol
    Else
        Set objSelection = New ClassRow
    End If
    
    Dim my非行 As Long
    my非行 = 5
    
    Dim my行始め As Long
'    my行始め = Selection.Row
    my行始め = objSelection.Num
    
    Dim my行終わり
'    my行終わり = Selection.Rows.Count + my行始め - 1
    my行終わり = objSelection.Count + my行始め - 1
    
    Dim my行終わり2 As Long
'    my行終わり2 = (Selection.Rows.Count \ my非行) * my非行 + my行始め - 1
    my行終わり2 = (objSelection.Count \ my非行) * my非行 + my行始め - 1
    
    If my行終わり - my行始め < 2001 Then
    
'        Rows(my行始め & ":" & my行終わり).Hidden = False
        objSelection.RowOrCols(my行始め, my行終わり).Hidden = False
        
        Dim i As Long
        For i = my行始め To my行終わり2 Step my非行
'            Rows(i + 1 & ":" & i + my非行 - 1).Hidden = True
            objSelection.RowOrCols(i + 1, i + my非行 - 1).Hidden = True
        Next i
    
    Else
        MsgBox "処理量が大きいので、マクロを中止しました"
    End If
End Sub

ClassCol と ClassRow というクラスを作成します。
クラスモジュールをメニューから選択して作成してください

Option Explicit
Private objSelection As Range

'いわゆるコンストラクタ
Private Sub Class_Initialize()
    Set objSelection = Selection
End Sub

Public Property Get Num() As Long
    Num = objSelection.Column
End Property

Public Property Get Count() As Long
    Count = objSelection.Columns.Count
End Property

Public Property Get RowOrCols(ByVal 始め As Long, ByVal 終わり As Long) As Range
    Set RowOrCols = Range(Columns(始め), Columns(終わり))
End Property

Option Explicit
Private objSelection As Range

'いわゆるコンストラクタ
Private Sub Class_Initialize()
    Set objSelection = Selection
End Sub

Public Property Get Num() As Long
    Num = objSelection.Row
End Property

Public Property Get Count() As Long
    Count = objSelection.Rows.Count
End Property

Public Property Get RowOrCols(ByVal 始め As Long, ByVal 終わり As Long) As Range
    Set RowOrCols = Range(Rows(始め), Rows(終わり))
End Property

Comments

[ta-]

回答ありがとうございます。
マクロにも様々な機能があるのですね。勉強になりました。

まだ初心者レベルなので、今後 さらに勉強して、教えて頂いた事を活用できるようになりたいと思います。

今回は、『Row』を『Column』に手で入力し直して、対応してみます。

ありがとうございました。