エクセルのデータをカンマ区切りで文字連結

Question

前提・実現したいこと

Excelで以下のようなデータがあった時。

||レイン|ウォーター|パンツスリム|パンツワイド|パッカブル|コラボ||
|:--:|:--:|:--:|:--:|:--:|:--:|:--:|
|TD001|〇||||〇||タグ|
|TD002|||〇||||タグ|

カンマ区切りで
TD001行目は => タグ,レイン,パッカブル
TD002行目は =>タグ,パンツスリム

というように文字連結をExcel関数で実現したいです。
ご教授願います。

該当のソースコード

下記のように、レイン列からコラボ列まで下記のように繋げればよいと
考えたのですが、2つ以上〇があった時"タグ"は取得してほしくないため
悩んでいます。

= IF(OR(O11 = "○", O11 = "〇"),U11&","&O8,FALSE)

補足情報（FW/ツールのバージョンなど）

os Windows
Excel バージョン2105

Answer 1

A	B	C	D	E	F	G	H	I
	レイン	ウォーター	パンツスリム	パンツワイド	パッカブル	コラボ
TD001	〇		〇	タグ	=TEXTJOIN(",",TRUE,H2,IF($B2:$F2="〇",$B$1:$F$1,""))
TD002		〇		タグ	=TEXTJOIN(",",TRUE,H3,IF($B3:$F3="〇",$B$1:$F$1,""))

Comments

[zeze]

回答ありがとうございます。
入力文字の「〇」が「○」の時など複数条件の時には、機能しませんでした。
「〇」「○」のように混合していても可能なようにしたいです。

以下のように、ORで繋げましたがヘッダーが全て取得されてしまいました。
= IF(H2<>0,TEXTJOIN(",",TRUE,H2,IF(OR($B2:$G2 = "〇",$B2:$G2 = "○"), $B$1:$G$1,"")), "")

[jinoji]

=IF(H2<>0,TEXTJOIN(",",TRUE,H2,IF($B2:$F2="〇",$B$1:$F$1,IF($B2:$F2="○",$B$1:$F$1,""))),"")
でどうでしょうか。
あるいは、もう少し割り切って
=IF(H2<>0,TEXTJOIN(",",TRUE,H2,IF(ISBLANK($B2:$F2)=FALSE,$B$1:$F$1,"")),"")
とか。

[zeze]

回答ありがとうございます。
1番目に提示いただいたもので、結合できましたありがとうございます!!

只、H列の値がエラー(#REF!)などの値が入った場合、出力は空にしたいのですが
この場合、ISERRORを使えばよいでしょうか？
お手数をおかけしますが宜しくお願い致します。

[zeze]

ISERRORで書けました！

= IF(ISERROR(H2),"",IF(W11<>0,TEXTJOIN(",",TRUE,H2,IF($B2:$G2 = "〇",$B$1:$G$1, IF($B2:$G2 = "○", $B$1:$G$1, ""))), ""))