画像をランダムに表示

Question

イラスト時計

発生している問題・エラーメッセージ

本来なら13：00：00にプログラムを起動したら13：00：00～13：00：59までは１枚の画像が表示され13：01：00に１２枚の画像の中からランダムに１枚が表示されるようにしたいが
プログラムを起動したら１２枚の画像が常にランダムに表示されるようになっている

実際のコード

PImage a[];
PFont font;
void setup(){
  size(540,960);
  noStroke();
  a =new PImage[12];
  a[0]=loadImage("A1.jpg");
  a[1]=loadImage("H1.jpg");
  a[2]=loadImage("J1.jpg");
  a[3]=loadImage("J2.jpg");
  a[4]=loadImage("J3.jpg");
  a[5]=loadImage("K1.jpg");
  a[6]=loadImage("O1.jpg");
  a[7]=loadImage("O2.jpg");
  a[8]=loadImage("O3.jpg");
  a[9]=loadImage("T1.jpg");
  a[10]=loadImage("T2.jpg");
  a[11]=loadImage("Y1.jpg");
}

int old_s=-1;
void draw(){
 background(100);
 int h=hour();
 int m=minute();
 int s=second();
 println(h+";"+m+","+s);  
 
 if(s<=59){
   old_s=s;
 image(a[ int(random(0,11))],0,0);
 //image(a[0],0,0);
 }
 else{
 }
   
 
 fill(0);
 rect(0,960/60*s,540,960);

 fill(250);
 
 font=createFont("Stencil Std",40);
 textFont(font);
 
  if(h<10){
  text("0"+h+":",10,40);
 }
 else{
  text(h+":",10,40);
 }
 if(m<10){
  text("0"+m+":",80,40);
 }
 else{
  text(m+":",80,40); 
 }
 if(s<10){
  text("0"+s,150,40);
 }
 else{
 text(s,150,40); 
 }
}

補足情報（FW/ツールのバージョンなど）

Processing2.2.1

Yahoo知恵袋に投稿をしていて回答して頂けてその回答を試したのですが上手く機能しなかったためこちらでも投稿させて頂きました
リンク内容

Comments

[thkana]

https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q10246330215
https://teratail.com/help#posted-otherservice に則って処置をお願いします。
---
やむを得ず複数のサイトに質問を投稿された場合は、質問内容にマルチポストをする理由を書き、他のサイトの投稿へのリンクを貼ってください。また、解決した際には必ずteratail及びすべての投稿に解決した旨と、どのように解決したかを記載してください。
---
まぁ、知恵袋は解決した質問に追記できないのでどうしよもないですけれど、前半はできますよね。

[KI1153]

先ほど質問内容を更新しました

Answer 1

13：00：00にプログラムを起動したら13：00：00～13：00：59までは１枚の画像が表示され13：01：00に１２枚の画像の中からランダムに１枚が表示されるようにしたい

ちょっと意味が分からないんですが、１分ごとに画像を変えたいってことでしょうか？（０秒丁度に新たな画像に入れ替える）

秒（old_s）でなくて分（old_m）が変わったかを、見たらいいんじゃないでしょうか。

デフォルトでは1秒に60回drawが呼ばれます（frameRate(60)）
同じ秒数でも複数回drawに入るということを、頭に入れておかねばなりません。

PImage[] images;
int old_m = -1;
int index;

void setup() {
  size(540, 960);
  noStroke();
  textFont(createFont("Stencil Std", 40));

  images = new PImage[]{
    loadImage("A1.jpg"),
    loadImage("H1.jpg"),
    loadImage("J1.jpg"),
    loadImage("J2.jpg"),
    loadImage("J3.jpg"),
    loadImage("K1.jpg"),
    loadImage("O1.jpg"),
    loadImage("O2.jpg"),
    loadImage("O3.jpg"),
    loadImage("T1.jpg"),
    loadImage("T2.jpg"),
    loadImage("Y1.jpg"),
  };
}

void draw() {
  background(100);

  int h = hour();
  int m = minute();
  int s = second();
  println(h + ";" + m + "," + s);

  if (old_m != m) {
    old_m = m;
    index = int(random(0, images.length));
  }
  image(images[index], 0, 0);

  fill(0);
  rect(0, height / 60 * s, width, height);

  fill(250);
  String time = nf(h, 2) + ":" + nf(m, 2) + ":" + nf(s, 2);
  text(time, 10, 40);
}

Processing3.5.4で書きましたので、もしかしたらどこかエラーが出るかもしれません。
偶然同じ画像（index）が選ばれる可能性があります。

---

本題とは関係ないですが、数字の０埋めには便利関数が用意されています（名前が覚えにくいのが難点ですが^^;
nf() \ Language (API) \ Processing 2+

Comments

[KI1153]

先ほど試して見たところ無事に理想通りに起動しました
ありがとうございました
助かりました