VBAメール送信＆PDF添付がうまくいきません。コードを見ていただけると助かります。

Question

Option Explicit

Sub sendmail()

Dim ws As Worksheet

Set ws = ThisWorkbook.Sheets("mail")

Dim OutApp As Outlook.Application

Set OutApp = New Outlook.Application

Dim R As Long, lastrow As Long

lastrow = ws.Cells(2, 1).End(xlDown).Row

For R = 3 To lastrow

Dim OutMail As Outlook.MailItem

Set OutMail = OutApp.CreateItem(olMailItem)

Dim BodyOfMail As String

BodyOfMail = CreateBodyOfMail(ws, R)

'PDFファイル名生成

Dim R As Cells, ws  As Object, dt As Variant

Set R = Cells(3, 7)

Set ws = CreateObject("WScript.shell")

dt = ws.SpecialFolders("Desktop") & "＼" & "返信.pdf"

With OutMail

.SendUsingAccount = Session.Accounts([e-mail])

.To = ws.Cells(R, 5).Value

.CC = ws.Cells(R, 6).Value & [e-mail] &　[e-mail] & [e-mail]

.subject = Replace(ws.Cells(2, 10).Value, "コード", ws.Cells(R, 3).Value, "都道府県", ws.Cells(R, 2).Value)

.body = BodyOfMail

.Attachments.Add dt & " .pdf"

End With

OutMail.Save

Set OutMail = Nothing

Next R

End Sub

Function CreateBodyOfMail(ws As Worksheet, R As Long) As String

Dim shimei As String, link As String

shimei = ws.Cells(R, 4).Value

shisetsu = ws.Cells(R, 2).Value

Dim subject As String

subject = ws.Cells(2, 2).Value

subject = Replace(subject, "都道府県", todou)

subject = Replace(subject, "コード", code)

Dim body As String

body = ws.Cells(3, 10).Value

body = Replace(body, "名前", shimei)

body = Replace(body, "都道府県", todou)

body = body & vbCrLf

CreateBodyOfMail = body

End Function
```### 前提・実現したいこと

メール一斉作成PDF添付付きのコードを作成しています。

件名はエクセルの（2,10)にあり、件名中の（コード：都道府県）の箇所にエクセルのコード→（R,3)、都道府県→(R,2)を挿入したいと考えています。

本文にも名前と都道府県を挿入したく、名前はsimei 都道府県はtodou　と命名しています。
それぞれエクセルの箇所は、名前→(r,4) 都道府県→(R,2)にあります。
また、PDFはデスクトップに置き、返信.pdfの名前を付けて保存しております。

エラーメッセージが発生してしまい、困っております。

コンパイルエラー　ユーザー定義型は定義されていません。

### 該当のソースコード
R As Cells

```ここに言語名を入力
ソースコード

試したこと

いろいろ調べてみたのですが改善されず困っております。
具体的には調べたのですが、エラー箇所から進めず困っています。

補足情報（FW/ツールのバージョンなど）

あと、可能でありましたら本文中の氏名と都道府県を太字にしたいのですがこちらもうまくいきません。

Comments

[meg_]

・コードは「コードの挿入」で記入してください。
・エラー発生箇所はどこでしょうか？
・エラーメッセージを提示してください。

> いろいろ調べてみたのですが改善されず困っております。
具体的にお願いします。

[sazi]

どのような参照設定を行っているのかも追記して下さい。

[rotaww]

saziさん、本当に素人でネット検索にてコードを作成したので参照設定もよくわからないので教えていただけますでしょうか。すみません。

Answer 1

エラーメッセージが発生してしまい、困っております。

ネット検索にてコードを作成したので参照設定もよくわからないので教えていただけますでしょうか。

単にコピペの継ぎはぎしてるからです。

参照設定をクリアしても、変数が重複したりもしてますので、同じコピペするにしても、一つずつエラーの無い状態にしてから、次のコピペを行うようにして下さい。

Answer 2

まず、いきなりやみくもにコードをコピペして何とかしようとするのはやめましょう。
マクロで使用される VBA は「言語」です。
単語の意味や文法もわからずにコピペで作ったプログラムではまともに動作しないでしょうし、何か問題があっても自分ではどうにもできないでしょう。
以下の URL から VBA の言語に関するトピックにアクセスできますので、これらを一通り理解してマクロを作成してください。
https://docs.microsoft.com/ja-jp/office/vba/language/reference/user-interface-help/visual-basic-conceptual-topics

提示いただいたマクロをある程度動作するように修正したマクロは以下の通りです。
コメントで修正した内容について記載しています。

Option Explicit

Sub sendmail()
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Sheets("mail")

    ' 参照設定がなくても以下なら動作します。
    Dim OutApp As Variant ' Outlook.Application
    ' 参照設定がなくても以下なら動作します。
    Set OutApp = CreateObject("Outlook.Application") ' New Outlook.Application

    Dim R As Long, lastrow As Long
    lastrow = ws.Cells(2, 1).End(xlDown).Row

    ' 3 で良いのでしょうか? 3 行目には本文があるのでは?
    For R = 3 To lastrow
        ' 参照設定がなくても以下なら動作します。
        Dim OutMail As Variant 'Outlook.MailItem
        ' 参照設定がなくても以下なら動作します。
        Set OutMail = OutApp.CreateItem(0) ' olMailItem)

        Dim BodyOfMail As String
        BodyOfMail = CreateBodyOfMail(ws, R)

        'PDFファイル名生成
        ' R や ws ってすでに使ってますよね?
        'Dim R As Cells, ws  As Object, dt As Variant
        Dim wShell As Object, dt As Variant
        ' ここで設定した R の Cells(3, 7) の値って使ってないようです。
        'Set R = Cells(3, 7)
        
        Set wShell = CreateObject("WScript.shell")
        ' パス区切りが全角バックスラッシュになってます
        'dt = ws.SpecialFolders("Desktop") & "＼" & "返信.pdf"
        dt = wShell.SpecialFolders("Desktop") & "\" & "返信.pdf"

        With OutMail
            ' Session を直接使えたり、Accounts の Item を省略できるのは Outlook VBA の中だけです。
            ' また、文字列は "" でくくる必要があります。
            '.SendUsingAccount = Session.Accounts([e-mail])
            .SendUsingAccount = OutApp.Session.Accounts.Item("[e-mail]")
            .To = ws.Cells(R, 5).Value
            ' 文字列は "" でくくる必要があり、複数アドレスを指定する場合はアドレス文字列の間に ; が必要です。
            '.CC = ws.Cells(R, 6).Value & [e-mail] &　[e-mail] & [e-mail]
            .CC = ws.Cells(R, 6).Value & ";[e-mail];[e-mail];[e-mail]"
            ' Replace 関数は一度に一つの文字列を置き換えます。複数の文字列を置き換えることはできません。
            '.subject = Replace(ws.Cells(2, 10).Value, "コード", ws.Cells(R, 3).Value, "都道府県", ws.Cells(R, 2).Value)
            .Subject = Replace(ws.Cells(2, 10).Value, "コード", ws.Cells(R, 3).Value)
            .Subject = Replace(.Subject, "都道府県", ws.Cells(R, 2).Value)
            .body = BodyOfMail
            ' dt には既に拡張子 .pdf がついています
            .Attachments.Add dt ' & " .pdf"
        End With

        OutMail.Save
        Set OutMail = Nothing
    Next R
End Sub

Function CreateBodyOfMail(ws As Worksheet, R As Long) As String
    ' link って使ってませんよね?
    Dim shimei As String ', link As String
    shimei = ws.Cells(R, 4).Value
    
    ' shisetsu って宣言してませんし、後でも使ってませんよね?
    'shisetsu = ws.Cells(R, 2).Value
    ' subject って結局この関数の中で使っているだけで実際の件名には使われてないですよね?
    'Dim subject As String
    'subject = ws.Cells(2, 2).Value
    'subject = Replace(subject, "都道府県", todou)
    'subject = Replace(subject, "コード", code)
    
    ' 都道府県の取得の記述が必要です。
    Dim todou As String
    todou = ws.Cells(R, 2).Value
    
    Dim body As String
    body = ws.Cells(3, 10).Value
    body = Replace(body, "名前", shimei)
    body = Replace(body, "都道府県", todou)
    body = body & vbCrLf
    CreateBodyOfMail = body
End Function

なお、氏名と都道府県を太字にしたいということになると、本文形式に HTML を使用する必要があります。
HTML の書き方がわからないようであれば素直にあきらめていただいたほうが良いです。
もし、HTML がわかるなら Cell(3, 19) の本文の内容を HTML で記述し、.body = BodyOfMail を .htmlbody = BodyOfMail としてください。

Comments

[rotaww]

ありがとうございます。施設→都道府県に変更したのを失念しておりました。
勉強になりました。

[rotaww]

millefeuille様、お世話になっております。度々で申し訳ごじざいません。この度はマクロのご教示をいただきありがとうございました。
教えていただいた、コードにて作成させていただいたのですが
送信元のみ変更できず苦戦しております。再度教えていただくことは可能でしょうか。

Answer 3

わからないから聞いております。
どなたか親切な方教えていただけますと助かります。
ネットで調べたので切り貼りしているのは承知でございす。

Comments

[sazi]

同じ切り貼りするにしても、一度にではなく少しずつやってみて下さいと言っているんですが。
どのような動作するかは関係なく、コンパイルエラーにならないように教えるだけでいいんですか？