Googleスプレッドシート query関数のエラーについて

Question

以前の質問

https://teratail.com/questions/329305

下記のようなスプレッドシートがあり、その当日に訪問した相手・翌営業日に訪問予定のリストを作りたいと思っています。
当日分・翌日分を関数で集計して今までは問題なく稼働していたのですが、#valueのエラーが出て使えなくなりました。

||7/1|7/2|7/3|
|:--|:--:|--:|
|Aさん|訪問|未訪問|未訪問|
|Bさん|未訪問|訪問|未訪問|

実際の表で作成した関数

★当日分
=query('202105'!$A$1:$IP$100,"SELECT C where " & SUBSTITUTE(ADDRESS(1,MATCH(TODAY(),'202105'!$A$1:$IP$1,0),4,1),1,) & "='訪問'",false)

上記の当日分のリストは問題なく動いています。

★翌営業日分
=query('202105'!$A$1:$IP$100,"SELECT C where " & SUBSTITUTE(ADDRESS(1,MATCH(workday(B7,1,J9:J38),'202105'!$A$1:$IP$1,0),4,1),1,) & "='訪問'",false)

workday関数を使用し、J9:J38には祝日を入力して翌営業日の分を集計できていたのですが、
この翌営業日分のみが数日前よりエラーになり正常に出力されません。
以前の版から復元してもエラーが解消しないのでお力添えをいただきたいです。

エラー内容

関数 QUERY のパラメータ 2 のクエリ文字列を解析できません: PARSE_ERROR: Encountered " "by" "BY "" at line 1, column 16. Was expecting one of: "true" ... "false" ... "not" ... "date" ... "timeofday" ... "datetime" ... "timestamp" ... "min" ... "max" ... "avg" ... "count" ... "sum" ... "no_values" ... "no_format" ... "is" ... "null" ... "year" ... "month" ... "day" ... "hour" ... "minute" ... "second" ... "millisecond" ... "with" ... "contains" ... "starts" ... "ends" ... "matches" ... "like" ... "now" ... "dateDiff" ... "quarter" ... "lower" ... "upper" ... "dayOfWeek" ... "toDate" ... <ID> ... <INTEGER_LITERAL> ... <DECIMAL_LITERAL> ... <STRING_LITERAL> ... <QUOTED_ID> ... "(" ... "-" ...

試したこと

①TODAY()+1
=query('202105'!$A$1:$IP$100,"SELECT C where " & SUBSTITUTE(ADDRESS(1,MATCH(TODAY()+1,'202105'!$A$1:$IP$1,0),4,1),1,) & "='訪問'",false)
→エラー

②別のセル(例：B32)に翌営業日を入力して参照
=query('202105'!$A$1:$IP$100,"SELECT C where " & SUBSTITUTE(ADDRESS(1,MATCH(B32,'202105'!$A$1:$IP$1,0),4,1),1,) & "='訪問'",false)
→エラー

③workdayの引数にTODAY()を代入
=query('202105'!$A$1:$IP$100,"SELECT C where " & SUBSTITUTE(ADDRESS(1,MATCH(workday(TODAY(),1,J9:J38),'202105'!$A$1:$IP$1,0),4,1),1,) & "='訪問'",false)

恐れ入りますが、知恵をお貸しいただけたら幸いです。
宜しくお願いいたします。

Answer 1

BY列を参照しているため、予約語と解釈されてBY列での検索が行われていないようですね。

調べた所、queryにおける列の指定には他の方法もあるようで以下の式に変えるといけるようです。

=query({'202105'!$A$1:$IP$100},"SELECT Col3 where " & "Col" & MATCH(workday(B7,1,J9:J38),'202105'!$A$1:$IP$1,0) & "='訪問'",false)

この「{'202105'!$A$1:$IP$100}」と言うように、{}で範囲を囲えば、Col1,Col2とかいう列の指定の仕方になるようです。
これにより、BY列ではなくCol77という指定が出来るようになるとのことでした。

（参考にしたHP）
スプレッドシートのQUERY関数にてデータ列を指定する方法

(追記)

=query('202105'!$A$1:$IP$100,"SELECT C where `" & SUBSTITUTE(ADDRESS(1,MATCH(workday(B7,1,J9:J38),'202105'!$A$1:$IP$1,0),4,1),1,) & "`='訪問'",false)

上記のように、列指定を ``　で囲むという方法もあるようでした。
どっちでもいいと思います。

Comments

[joeyinaba]

ありがとうございます！
最初の方法で無事動作するようになりました！