frameCountを使った動きについて

Question

前提・実現したいこと

180フレーム（３秒）ごとに半透明の円がランダムな箇所に流れて消えていくアニメーションを制作しています。
実行すると３秒ごとに円は表示されるのですが、流れる動きがつかず一瞬だけの処理になってしまいます。
どのようにすれば泡の動き（if内）が上手く動作するでしょうか？

該当のソースコード

Processing3.5.4を使用しています。

float y =2;//泡の動き
int tmi =100;//泡の透明度
float tki = random(50, 100);//泡の直径

void setup(){
size(1000, 1000, P2D);
frameRate(60);
}

void bg(){
noStroke();
beginShape();
fill(30, 40, 80);
vertex(0, 0);
vertex(1000, 0);
fill(0, 0, 0);
vertex(1000, 1000);
vertex(0, 1000);
endShape();
}

void draw(){
bg();
translate(500, 400);
rotate(radians(20));

ellipse(0,0, 50,50);

if (frameCount % 180 == 0) {

 y=y+2;//上昇する動き
 tmi=tmi-3;//消えていく動き
 noStroke();
 fill(200, 255, 255, 10+tmi);//徐々に消える泡
 ellipse(0+random(-400,400) , 0+random(-400,400)+y, tki, tki);

}

}

試したこと

https://note.com/deconbatch/n/nb1b1dc857fe8

frameCountの処理はこちらを参考にさせて頂きました。
frameCountの部分のみなので回答のご参考になるかは分かりませんが、記載させて頂きます。

Answer 1

if (frameCount % 180 == 0)ということは、180フレーム中の1フレームしか入りません。
y=y+2;やellipseもその瞬間だけです。

180フレーム（３秒）ごとに半透明の円がランダムな箇所に流れて消えていくアニメーション

ということはy=y+2;やellipseは常に実行し、if内は位置のリセット等の処理が入るべきでしょう。

float x = random(-400, 400); // 泡のX座標
float y = random(-400, 400); // 泡のY座標
int tmi = 100;
float tki = random(50, 100);

void setup() {
  size(1000, 1000, P2D);
}

void bg() {
  noStroke();
  beginShape();
  fill(30, 40, 80);
  vertex(0, 0);
  vertex(1000, 0);
  fill(0, 0, 0);
  vertex(1000, 1000);
  vertex(0, 1000);
  endShape();
}

void draw() { 
  bg();
  translate(500, 400);
  rotate(radians(20));

  circle(0, 0, 50);

  y += 2;
  tmi -= 3;
  noStroke();
  fill(200, 255, 255, 10 + tmi);
  circle(x, y, tki);

  if (frameCount % 180 == 0) {
    x = random(-400, 400);
    y = random(-400, 400);
    tmi = 100;
    tki = random(50, 100);
  }
}

Comments

[hiragana_100]

参考に順に組み直してみたところ、解決いたしました。frameへの理解が浅かったようです……確かに元の表記だと描画も１フレームのみになってしまいますね。
不要な部分まで添削して頂き、初学者のため大変勉強になりました。ありがとうございます！