VBAで、赤色の文字列があった場合、その下のセルを灰色で塗りたい

Question

VBAで、シート内に赤色の文字列があった場合、
その下のセル（直下9セル）を灰色にしたいと思っています

下記のコードを書いて実施したのですが、
セルの指定を9行に書いたため、冗長になってしまいました。

申し訳ございませんが、ここをまとめる方法（赤文字のあったセルの「１つ下～9つ下」の箇所）をご教授願えませんでしょうか

Sub ck_holiday()

Dim i As Integer, j As Integer
For i = 2 To 500
    For j = 2 To 50
        If Cells(i, j).Font.Color = 255 Then
            Cells(i, j).Offset(1, 0).Interior.Color = RGB(220, 220, 220)
            Cells(i, j).Offset(2, 0).Interior.Color = RGB(220, 220, 220)
            Cells(i, j).Offset(3, 0).Interior.Color = RGB(220, 220, 220)
            Cells(i, j).Offset(4, 0).Interior.Color = RGB(220, 220, 220)
            Cells(i, j).Offset(5, 0).Interior.Color = RGB(220, 220, 220)
            Cells(i, j).Offset(6, 0).Interior.Color = RGB(220, 220, 220)
            Cells(i, j).Offset(7, 0).Interior.Color = RGB(220, 220, 220)
            Cells(i, j).Offset(8, 0).Interior.Color = RGB(220, 220, 220)
            Cells(i, j).Offset(9, 0).Interior.Color = RGB(220, 220, 220)
        Else
        End If
    Next j
Next i

End Sub

Answer 1

こんな感じではどうでしょうか？
Rangeを定義すると色々と汎用的に使えます。

Sub ck_holiday()

Dim i As Integer
Dim j As Integer
Dim ChkRange As Range
Dim WrtRange As Range

For i = 2 To 500
    For j = 2 To 50
        Set ChkRange = Cells(i, j)
        If ChkRange.Font.Color = 255 Then
            Set WrtRange = Range(Cells(i + 1, j), Cells(i + 9, j))
            WrtRange.Interior.Color = RGB(220, 220, 220)
        End If
    Next j
Next i

Set ChkRange = Nothing
Set WrtRange = Nothing

End Sub

Comments

[amatsuno]

ありがとうございます。

こちらで実施可能なことも確認いたしました。
今回、変更があった場合の修正箇所を明確にすることが可能なほうがいい思いがあったため、
コードの短かった方をベストとさせていただきました

Answer 2

以下でいかがでしょう。

    Dim i As Integer, j As Integer
    
    For i = 2 To 500
        For j = 2 To 50
            If Cells(i, j).Font.Color = 255 Then
                '①
                Range(Cells(i, j).Offset(1, 0), Cells(i, j).Offset(9, 0)).Select
                '②
                Selection.Interior.Color = RGB(220, 220, 220)
            Else
            End If
        Next j
    Next i

①は背景色を変更するセルを範囲指定します。
②は上記①で範囲指定したセルの背景色を変更します。

###アドバイス①
質問を投稿する際は「Markdown記法」を利用したほうが回答者さんたちは理解しやすいです。
私も最初は「Markdown記法」ってなに？という感じでわからない事だらけでしたが
慣れると簡単です。
ちょっと調べてみてください。

###アドバイス②
上記のVBAコードはマクロ記録によりあらかたの内容を確認しました。
それを自分の経験で上記コードに変更しました。
マクロ記録を使うとVBAのコードにしてくれますので凄く助かります。
何度か実際に実施とその内容の調査をやると理解できるようになります。

Comments

[amatsuno]

ありがとうございます。

この方法で実施させていただきます

マクロに関しては、こちらでも実施したのですが、
相対位置（カレントセルから下に9つ）が取れなかったために途中であきらめていました

[indy_papa]

ベストアンサーに選んでいただきありがとうございます。
また、何かあれば！！

Answer 3

こんな感じでできると思います。

Cells(i, j).Offset(1, 0).Resize(9).Interior.Color = RGB(220, 220, 220)

Comments

[amatsuno]

すいません。

アプリケーション定義またはオブジェクトの定義のエラーです

と表示され、失敗いたしました

[jinoji]

すみません、誤記を修正しました。

[amatsuno]

ありがとうございます。
思っていたことが実行できたことが確認できました