VBA Worksheet_change で ドラッグやコピーをした時にも動くようにしたい

Question

前提・実現したいこと

Excel vba のworksheet changeを利用して、通常は白くぬりつぶされている、特定範囲のセルに対して０以上の数値が入力された場合に赤く塗りつぶしたい。
また、一度赤くなった複数セルをdeleteで消去したら、白く通常になり
コピー＆ペーストした場合でも動くようにしたい

発生している問題・エラーメッセージ

セルに単発入力した場合は、赤くなり問題無し
複数セルをdeleteしても白くなり問題はないのだが、
コピーペーストされた場合には反応せず、そしてドラッグした場合には一瞬赤くなるがすぐに白くなる

該当のソースコード

Private Sub Worksheet_Change(ByVal Target As Range)

'ターゲットセルを白に初期化
Target.Interior.Color = vbWhite

'ターゲットと指定エリアがかぶっていない場合は終了
If Intersect(Target, Range("A1:B10")) Is Nothing Then
    Exit Sub
Else

'複数セルを消去した場合 処理無し
    If IsArray(Target.Cells.Value) Then
        Exit Sub
    End If

'セル１つを削除した時　処理無し
    If IsEmpty(Target.Cells.Value) Then
        Exit Sub
    End If

'入力が０以上であれば、赤く塗りつぶす
    If Target.Value > 0 Then
        Target.Interior.Color = vbRed
    End If
    
End If
End Sub

Answer 1

こんな感じですか？

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim rng As Range, c As Range
    Set rng = Intersect(Target, Range("A1:B10"))
    If rng Is Nothing Then Exit Sub
    For Each c In rng
        c.Interior.Color = vbWhite
        If IsEmpty(c) Then
        ElseIf Not IsNumeric(c) Then
        ElseIf c.Value >= 0 Then
            c.Interior.Color = vbRed
        End If
    Next
End Sub

Comments

[miyabin09]

ありがとうございます。
target.valueだけでは、ドラックやコピペには対応しないので
for eachでの対応が必要なのですね。
さらに数値までの判断はifとelseifを使用して、条件を絞っていくやり方もあるんですね。
ありがとうございました。