vpc_idをサブネットリソースに渡す際のTerraformでの記載方法について

Question

前提・実現したいこと

TerraformにてAWS環境上でVPCとSubnetの簡単な構成を作成したく思っております。
VPCで作成したvpc_idをSubnetに上手く渡せていないように見受けられるので
解決方法についてアドバイスなど提示いただけますと幸いです。

構成については、複数リソースを作成することを想定して
for_eachとlookupを利用して呼び出しを行っております。

発生している問題・エラーメッセージ

$ terraform plan -var-file=prd/resource-prd-vars.tfvars 
module.create_vpc_module.aws_vpc.vpc["vpc01"]: Refreshing state... [id=vpc-0419f19a0980c568f]

Error: Invalid index

  on ..\modules\vpc\vpc-main.tf line 15, in resource "aws_subnet" "subnet":
  15:   vpc_id                  = aws_vpc.vpc[each.key].id
    |----------------
    | aws_vpc.vpc is object with 1 attribute "vpc01"
    | each.key is "subnet01"

The given key does not identify an element in this collection value.

■ディレクトリ構成

└─VPC
    ├─modules
    │  └─vpc
    │          output.tf
    │          vpc-main.tf
    │          vpc-variavles.tf
    │
    └─resource
        │  backend.tf
        │  provider.tf
        │  resource-main.tf
        │  resource-variables.tf
        │  terraform.tfstate
        │  terraform.tfstate.backup
        └─prd
                resource-prd-vars.tfvars

■modules/vpc/vpc-main.tf

# ---------------------------------------------
# VPC
# ---------------------------------------------
resource "aws_vpc" "vpc" {
  for_each   = var.vpc
  cidr_block = lookup(each.value, "cidr_block", null)
  tags       = lookup(each.value, "tags", null)
}

# ---------------------------------------------
# Subnet
# ---------------------------------------------
resource "aws_subnet" "subnet" {
  for_each                = var.subnet
  vpc_id                  = aws_vpc.vpc[each.key].id
  availability_zone       = lookup(each.value, "availability_zone", null)
  cidr_block              = lookup(each.value, "cidr_block", null)
  map_public_ip_on_launch = lookup(each.value, "map_public_ip_on_launch", null)
  tags                    = lookup(each.value, "tags", null)
}

■modules/vpc/vpc-variables.tf

# ---------------------------------------------
# VPC作成時に利用する変数
# ---------------------------------------------

variable "vpc" {
  default = {}
}

# ---------------------------------------------
# subnet作成時に利用する変数
# ---------------------------------------------

variable "subnet" {
  default = {}
}

■resource/resource-main.tf

# ---------------------------------------------
# 各種モジュールの呼び出し
# ---------------------------------------------
module "create_vpc_module" {
  source = "../modules/vpc"
  vpc    = var.vpc
  subnet = var.subnet
}

■resource/resource-variables.tf

# ---------------------------------------------
# 変数の呼び出し
# ---------------------------------------------
variable "vpc" {}

variable "subnet" {}

■resource/prd/resource-prd-vars.tfvars

# vpc tfvars
# 実際の変数値を宣言する内容

# ---------------------------------------------
# VPC
# ---------------------------------------------

vpc = {
  vpc01 = {
    description = "テスト用vpc"
    cidr_block  = "10.0.0.0/16"
    tags = {
      "Name" : "prd-vpc",
      "Env" : "prd"
    }
  }
}

subnet = {
  subnet01 = {
    availability_zone       = "ap-northeast-1a"
    cidr_block              = "10.0.0.0/20"
    map_public_ip_on_launch = "true"
    tags = {
      "Name" : "subnet",
      "Env" : "prd"
    }
  }
}

試したこと

outputを利用しmoduleに値を渡す、data形式で値を渡す、など
やってみましたが、正常に受け取れていないように見受けられます。

補足情報（FW/ツールのバージョンなど）

terraform_version": "0.14.6"

Comments

[mike2mike4]

同じ問題で悩んだのですが変数に””を入れることで回避できました。詳しい方に聞くと、vpc_idは予約後として登録されているのではないかとのことです。ご参考まで。。。

Answer 1

for_each = var.subnet

vpc_id = aws_vpc.vpc[each.key].id

ここのとこで参照しているeach.keyはvar.subnetのものです。
エラーメッセージに出ている通り、呼び出されているときはaws_vpc.vpc[subnet01].idとなっているはずですが、aws_vpc.vpcにはsubnet01というkeyがないのでエラーになっているということでしょう。

そもそもですが現状のこの変数の渡し方だとVPCとサブネットを紐付ける情報が変数側にないので、複数のVPCとサブネットを定義したときに複数のVPCに対して同じCIDRのサブネットを作ろうとしてしまうと思います。
サブネット側にVPCの情報を何かしら定義した上で、変数をネストさせるような感じでflattenでまとめれば実現したいことは一応出来なくはないみたいです。
Iterate over nested data with for / for_each at resource level

ただ、Terraformは0.13以降でmoduleのfor_eachができるようになったので、個人的にはモジュール自体には1つのVPCを作成する（※）機能を定義しておいて、module呼び出しのほうでループさせるべきかなと思います。
※サブネット等々はモジュール内部でループして複数作成することになるかとは思います。