一定時間での円の生成

Question

前提・実現したいこと

Processingで一定時間ごとにいくつか（１つや２つ）の円が発生するようにしたいのですがどのようにすれば良いのでしょうか。
↓参考にしたサイトです
https://science.shinshu-u.ac.jp/~tiiyama/?page_id=131

発生している問題・エラーメッセージ

一度に大量に描写される。

該当のソースコード

int num = 100;
float[] x = new float[num];  //円のx座標
float[] y = new float[num];  //円のy座標
float[] dx = new float[num];  //円のx方向の速度
float[] dy = new float[num];  //円のy方向の速度
int j;  //動かす円の番号
float b_r = 40;

void setup() {
  size(400, 400);
  background(0);
  smooth();
  for (int i=0; i<num; i++) {  //iを1づつ増やしてnumまで繰り返す
    x[i] = -20;  //円を画面の中心に
    y[i] = -20;
    dx[i] = 0;
    dy[i] = 0;
  }
}

void draw() {
  background(0);
  addBalls();
  for (int i=0; i<num; i++) {
    circle(x[i], y[i], b_r);  //円を描く
    x[i] += dx[i];  //i番目の円の位置を動かす
    y[i] += dy[i];
    if (x[i] - b_r/2 < 0 || x[i] + b_r/2 >= width) {
      dx[i] = -dx[i];
    }
    if (y[i] - b_r/2 < 0 || y[i] + b_r/2 >= height) {
      dy[i] = -dy[i];
    }
  }
}


void addBalls() {
  if ((millis()/1000)%3==0) {
    float deg;
    deg = random(2*PI);  //乱数で角度を決める
    x[j] = 20;  //位置を中心に戻す
    y[j] = 20;
    dx[j] = cos(deg);
    dy[j] = -sin(deg);
  }
  j = j + 1;  //円の番号を1動かす
  if (j == num) {  //もしjがnum番目まで行っていたら
    j = 0;  //jを0に戻す
  }
}

Answer 1

if ((millis()/1000)%3==0)は、millis()が0でも100でも999でもtrueです。
なのでその1秒以内に間に合った円は一気に出現します。

frameCountを使うのはどうでしょう？

int num = 100;
float[] x = new float[num];
float[] y = new float[num];
float[] dx = new float[num];
float[] dy = new float[num];
int j;
float b_r = 40;

void setup() {
  size(400, 400);
  background(0);
  smooth();
  for (int i = 0; i < num; i++) {
    x[i] = -20;
    y[i] = -20;
  }
}

void draw() {
  background(0);
  addBall();
  
  for (int i = 0; i < num; i++) {
    circle(x[i], y[i], b_r);
    x[i] += dx[i];
    y[i] += dy[i];
    if (x[i] - b_r / 2 < 0 || x[i] + b_r / 2 >= width) {
      dx[i] = -dx[i];
    }
    if (y[i] - b_r / 2 < 0 || y[i] + b_r / 2 >= height) {
      dy[i] = -dy[i];
    }
  }
}

void addBall() {
  if (frameCount % (60 * 3) == 1) { // 60（フレームレート） * 3（秒）の余り 0でもいいが最初の3秒なにも出ないので
    float deg = random(2 * PI);
    x[j] = 20;
    y[j] = 20;
    dx[j] = cos(deg);
    dy[j] = -sin(deg);

    j++;
    if (j == num) { 
      j = 0;
    }
  }
}

Comments

[wairaofsa]

frameCountは完全に盲点でした！ありがとうございます！