ocaml実行について

Question

ocamlをターミナルから実行するにあたり、例えば、リストを反転させるといった再帰関数などで関数の呼び出し毎にどのようにリストが変化していくのかを見たいのですが、それを見る方法はありますか？
よろしくお願いいたします。

Answer 1

#traceディレクティブを使うと指定した関数に対する入力（引数）と出力（戻り値）を表示できます。

• 公式のチュートリアルでの説明

たとえば、上のチュートリアルの例を拝借すると、以下のように使えます。

# (* fib関数を定義する *);;
# let rec fib x = if x <= 1 then 1 else fib (x - 1) + fib (x - 2);;
val fib : int -> int = <fun>

# (* fib関数に対するトレースをオンにする *)
# #trace fib;;
fib is now traced.

# (* fib関数を適用する *)
# fib 3;;
fib <-- 3
fib <-- 1
fib --> 1
fib <-- 2
fib <-- 0
fib --> 1
fib <-- 1
fib --> 1
fib --> 2
fib --> 3
- : int = 3

# (* fib関数に対するトレースをオフにする *)
# #untrace fib;;
fib is no longer traced.

fib <-- 3が入力で、fib --> 1が出力です。

この#traceはリストを反転させるような関数でももちろん使えますが、そのままだと多分うまくいきません。チュートリアルにも書かれているように、多相な関数（Polymorphic function）に対してトレースを使った場合、多相な値が<poly>のように表示されてしまい、実際の値を見ることができません。

たとえばリストを反転させるrev関数を以下のように定義したとします。

# let rec revAppend l1 l2 = 
      match l1 with
        [] -> l2
      | v :: l1' -> revAppend l1' (v :: l2);;
val revAppend : 'a list -> 'a list -> 'a list = <fun>

# let rev l = revAppend l [];;
val rev : 'a list -> 'a list = <fun>

注：この定義は書籍『プログラミング in Ocaml』（五十嵐淳 著、技術評論社）から拝借しました。

これに対して#traceをかけても有益な情報は得られません。

# #trace revAppend;;
revAppend is now traced.

# rev [1; 2; 3];;
revAppend <-- [<poly>; <poly>; <poly>]
revAppend --> <fun>
revAppend* <-- []
revAppend <-- [<poly>; <poly>]
revAppend --> <fun>
revAppend* <-- [<poly>]
revAppend <-- [<poly>]
revAppend --> <fun>
revAppend* <-- [<poly>; <poly>]
revAppend <-- []
revAppend --> <fun>
revAppend* <-- [<poly>; <poly>; <poly>]
revAppend* --> [<poly>; <poly>; <poly>]
revAppend* --> [<poly>; <poly>; <poly>]
revAppend* --> [<poly>; <poly>; <poly>]
revAppend* --> [<poly>; <poly>; <poly>]
- : int list = [3; 2; 1]

チュートリアルによると、これを回避する簡単な方法は引数に型制約を付けて単相な関数として定義することだそうです。以下のようにrevAppendの引数をそれぞれint list（整数のリスト）型に制限すれば実際の値を見ることができます。

# let rec revAppend (l1 : int list) (l2 : int list) =
      match l1 with
        [] -> l2
      | v :: l1' -> revAppend l1' (v :: l2);;
val revAppend : int list -> int list -> int list = <fun>

# let rev l = revAppend l [];;
val rev : int list -> int list = <fun>

# rev [1; 2; 3];;
revAppend <-- [1; 2; 3]
revAppend --> <fun>
revAppend* <-- []
revAppend <-- [2; 3]
revAppend --> <fun>
revAppend* <-- [1]
revAppend <-- [3]
revAppend --> <fun>
revAppend* <-- [2; 1]
revAppend <-- []
revAppend --> <fun>
revAppend* <-- [3; 2; 1]
revAppend* --> [3; 2; 1]
revAppend* --> [3; 2; 1]
revAppend* --> [3; 2; 1]
revAppend* --> [3; 2; 1]
- : int list = [3; 2; 1]

最後に、念のため補足しますと、トレースの最初の3行のところですが、

revAppend <-- [1; 2; 3]
revAppend --> <fun>
revAppend* <-- []

これは第1引数l1が[1; 2; 3]で、第2引数l2が[]であることを表しています。OCamlの関数はカリー化されており引数を1つだけとるため、このように表示されます。

Comments

[pocpocpoc]

ご回答ありがとうございます。
わかりやすく丁寧な説明でとてもありがたいです。
機会がありましたらまたよろしくお願いいたします。