haskellでIOのUnitテストをしたい

Question

前提・実現したいこと

標準出力、標準入力のテストをしたい
実際にはこの問題
のテストを作りたいです。

IOテストの現在の標準みたいなのがあればそれがしりたいです。

試したこと

1.Haskellで副作用をモックしてテストを書くを参考に書いてみたけど動かず
2.Haskell で書いた Web サービスにおける IO 部分の自動テストをもとに実装をしようと思ったが理解できず実装できなかった。

補足情報（FW/ツールのバージョンなど）

windows10

$stack --version
Version 2.5.1, Git revision d6ab861544918185236cf826cb2028abb266d6d5 x86_64 hpack-0.33.0

stack.yaml

resolver:
  url: https://raw.githubusercontent.com/commercialhaskell/stackage-snapshots/master/lts/17/10.yaml

サンプルコード(コンパイルエラー)

{-# LANGUAGE GeneralizedNewtypeDeriving #-}
import Control.Monad
import Control.Monad.Writer
import Control.Monad.Reader
import Control.Monad.Identity
import System.IO

prettyPrint :: (Monad m, MonadStdout m) => String -> m ()
prettyPrint ss= print ss

class MonadStdout m where
    putStrLnM:: String -> m ()

instance MonadStdout IO where
    putStrLnM = putStrLn

data Settings = Settings -- whatever you like
newtype MockT m a = MockT (WriterT String (ReaderT Settings m) a)
  deriving (Functor, Applicative, Monad)

runMockT :: MockT m a -> Settings -> m (a, String)
runMockT (MockT w) = runReaderT $ runWriterT w

runMock :: MockT Identity a -> Settings -> (a, String)
runMock = fmap runIdentity . runMockT

instance MonadTrans MockT where
    lift = MockT . lift . lift

instance Monad m => MonadStdout (MockT m) where
    putStrLnM s = MockT $ tell $ s <> "\n"

spec :: Monad m => m ((), String)
spec = flip runMockT Settings $
    prettyPrint "something1"

main  = spec

Answer 1

残念ながら、「IOテストの現在の標準」にあたるものはありません。ものすごくいろいろな方法が作られています。

ひとまず、挙げていただいたコードを直すとすると、 prettyPrint関数を例えば????のように直してください:

prettyPrint :: (Monad m, MonadStdout m) => String -> m ()
prettyPrint ss= putStrLnM $ show ss

print はあくまでも入出力のための関数であり、テストでは使いにくいので、テストで使わないために他の関数で置き換えてしまおう、というのが「試したこと」に挙げたページでのアプローチです。なのでここではprint関数を使わず、MonadStdoutのメソッド（putStrLnM）を使って定義する必要があります。

このように、「他の関数で置き換えてしまう」アプローチは本当にIOを使うわけではないので実行効率はいいものの、微妙に振る舞いが異なる場合がある、というのが弱点です。

Haskellで（実はHaskell以外でも）IOが絡んだテストをするときには、しばしばこのアプローチがとられます。調べて出てくる大半の方法は突き詰めればこの「他の関数で置き換えてしまおう」という作戦です。
（main-testerは敢えてそこで本物のIOを使うよう推奨することで、より実際に近いテストにしています）

Comments

[qoopty]

＞Haskellで（実はHaskell以外でも）IOが絡んだテストをするときには、しばしばこのアプローチがとられます。
一般的にmockって言われてるものと同じということでいいでしょうか？
pythonは比較的簡単にできますよね。
javaは何らかのframeworkを使ってできた記憶があります。(ほかの言語はあまりしらない)

ほんとの結合テストにするのか
ほかの関数で置き換えるのか
どちらかのアプローチしかなさそうですね。

#IOテストはずっと課題だと思うんですが、難しいのかな

[igrep]

そうです。Haskellの場合良くも悪くも、あらかじめ実装者がmockできる余地を作っておかなければmockできないという特性があるので、難易度は他の言語と比べて上がってしまいます。変に書き換えられないという意味で良いところでもあるのですが。

Answer 2

main-tester パッケージを使えば標準入出力のテストができるようになります。

main-tester に関する詳しい情報は Haskell-jp のブログをご覧ください。

まずライブラリーとして main を定義します。下記のコードでは仮に標準入力を標準出力にエコーしています。ただし AtCoder に提出するときはモジュール名を Main にしてください。

-- UnitTestIO.hs

module UnitTestIO (main) where

main :: IO ()
main = interact id

テストは次のように記述します。

-- UnitTestIOSpec

{-# LANGUAGE OverloadedStrings #-}

import qualified Data.ByteString as B
import           System.Exit     (ExitCode (ExitSuccess))
import           Test.Hspec      (hspec, it, shouldBe, shouldSatisfy)
import           Test.Main       (captureProcessResult, prExitCode, prStderr,
                                  prStdout, withStdin)
import qualified UnitTestIO

main =
  hspec $ do
    it "hello → hello" $ do
      result <- withStdin "hello" $ captureProcessResult UnitTestIO.main
      prExitCode result `shouldBe` ExitSuccess
      prStderr result `shouldSatisfy` B.null
      prStdout result `shouldBe` "hello"

プロジェクトファイルも含めた完全なコードは Gist に掲載します。

• https://gist.github.com/kakkun61/c6f52d196e66a6f5096cd07ac24f4310
• https://haskell.jp/blog/posts/2018/main-tester.html

Comments

[qoopty]

ありがとうございます。
これ事前に入力文字列をすべて与える必要があると思うのですが、
動的に入力を与えることってできないでしょうか？
最初の出力を受けて、それに応じて次の入力の文字列が変わるようなことをしたいのです。

[kakkun61]

既存ライブラリーでは解決できなさそうなケースですね。ちょっと考えてみます。