Q&A
とりあえず質問でエラーとなっている式ですが、括弧の数が合ってないです。まずはそこの修正を。
他のスプレッドシート（A）を参照し、クエリ関数（Query(IMPORTRANGE）を使い、BスプレッドシートのA列にある日付をwhereしてAスプレッドシートのキャンセル列にあるデータをBスプレッドシートに表示したいのですが、数式解析エラーが出てしまいできません。
該当のソースコード
=Query(IMPORTRANGE("シートID","キャンセル!$A$18024:D"),select D where A = date '"&text(A366,"YYYY-MM-DD")&"'"),"")")
エラー表示
「数式の解析エラーです」と出てきてしまいます。
やりたいこと
↓このようなAスプレッドシートのデータを参照して
|日付 |第３四半期 |週番号 |キャンセル
|2020/12/20| 第３四半期|51 | 5
|2020/12/21| 第３四半期|51 | 0
|2020/12/22| 第３四半期|51 | 7
↓Bスプレッドシートに「７」だけ表示させたいです。
|日付 |キャンセル
|2020/12/22| 7
AスプレッドシートのD列にある「７」だけをBスプレッドシートに表示させたいです。
試したこと
=iferror(query('キャンセル'!$A$18024:D,"select D where A = date '"&text(A7,"YYYY-MM-DD")&"'"),"")
=Query(IMPORTRANGE("シートID","キャンセル!$A$18024:D"),"where Col1 = '' ",true)
queryやIMPORTRANGEの書き方が間違ってると思い個別に書いてみました。
どちらも正常に機能したのですが、合体させると動きませんでした。
修正依頼ありがとうございます。助かります。
=Query(IMPORTRANGE("シートID","日経平均株価!$A$18024:D"),select D where A = date '"&text(A366,"YYYY-MM-DD")')
直してみましたが、同じエラーがでてしまいます。
他に気づいた点があれば教えていただければ嬉しいです。
回答1件
0
ベストアンサー
複雑な式を作った場合は、1つずつ解決していくしかないです。
- 質問文の式
=Query(IMPORTRANGE("シートID","キャンセル!$A$18024:D"),select D where A = date '"&text(A366,"YYYY-MM-DD")&"'"),"")")
↓
- 括弧の数を揃える
=Query(IMPORTRANGE("シートID","日経平均株価!$A$18024:D"),select D where A = date '"&text(A366,"YYYY-MM-DD")')
↓
- Query内の "(ダブルクォート) と & を見直す (selectの前の "がなくて最後も閉じれてないです)
=Query(IMPORTRANGE("シートID","日経平均株価!$A$18024:D"),"select D where A = date '"&text(A366,"YYYY-MM-DD")&"'")
↓
- 列の指定を A,Dではなく Col1,Col4 に修正(importrangeで参照した時はこっち)
=Query(IMPORTRANGE("シートID","日経平均株価!$A$18024:D"),"select Col4 where Col1 = date '"&text(A366,"YYYY-MM-DD")&"'")
投稿2021/04/14 04:07
編集2021/04/14 05:14総合スコア3002
sawa様ありがとうございます！できました!
困っていたので助けていただいて頭が下がる思いです。
最後の&"'")が何故こうなるのか分からないので調べてみたいと思います。
大変恐縮なのですが、シートIDを間違えて載せてしまったので、そこの部分を修正していただけると助かります・・・。申し訳ありません。
あなたの回答
tips
プレビュー
