VB.NETで制御している装置（オシロ）から画像データを取得したい（解決しました）
退会済みユーザー
総合スコア0

Question

### 前提・実現したいこと

オシロの画像データをVB.NETで取得しようとしています。
オシロメーカーからバイナリデータの出力の仕方は教わったのですが、肝心なその後の画像ファイルにする方法までは教えてくれませんでした。

画像データの拡張子はPNGです。
画像データを扱うのは初めてなので、やり方がさっぱり分からないです。
装置メーカーに画像ファイルの生成方法を聞くのも違うかなと思って、こちらに質問を出させていただきました。

### 発生している問題

```
バイナリデータもちゃんと取得できているか分かりませんが、ほかのコマンドで測定値は読めるので、出力されている前提でお願いします。
バイナリデータの取り込み方はいろいろと調べて、「試したこと」に記載したコードは見つけました。
ですが、これをどう使うのかが分かりません。
```

### 該当のソースコード

```VB.NET
Private Sub hard_copy_Click(sender As Object, e As EventArgs) Handles hard_cpopy.Click

        SerialPort1.Open()

        SerialPort1.WriteLine("HARDCOPY:PORT RS232")
        SerialPort1.WriteLine("HARDCOPY:FORMAT PNG")
        SerialPort1.WriteLine("HARDCOPY START")   'ここからバイナリデータが出力されるとメーカーから教わった

　　　　'ここに下記コードでデータは取得できそうですが、そこからPNGファイルに変換したいです
　　　　'画像ファイルに変換できるのなら、別の方法でも可です

　　　　SerialPort1.Close()

    End Sub
```


### 解決したコード
バイト配列をImageオブジェクトに変換するFunctionを追加しています。
（Web上から見つけました）

``` VB.NET
    Private Sub hard_cpopy_Click(sender As Object, e As EventArgs) Handles hard_cpopy.Click
        SerialPort1.Open()
        SerialPort1.WriteLine("HARDCOPY:PORT RS232")
        SerialPort1.WriteLine("HARDCOPY:LAYOUT PORTRAIT")
        SerialPort1.WriteLine("HARDCOPY:INKS ON")
        SerialPort1.WriteLine("HARDCOPY:FORMAT TIF")
        SerialPort1.WriteLine("HARDCOPY START")

        Dim img As Byte()
        img = ReadBinaryData(SerialPort1)

        Dim img2 As Image = ByteArrayToImage(img)

        img2.Save("hard.tif", System.Drawing.Imaging.ImageFormat.Tiff)

        SerialPort1.Close()

    End Sub 

   ' バイト配列をImageオブジェクトに変換
    Public Shared Function ByteArrayToImage(ByVal b As Byte()) As Image
        Dim img As Image = CType(imgconv.ConvertFrom(b), Image)
        Return img
    End Function

    Public Function ReadBinaryData(st As SerialPort) As Byte()
        Dim buf(32768) As Byte ' 一時バッファ
        '無限に待たれても困るので、ReadTimeoutがInfiniteTimeoutならとりあえず10秒に設定
        If st.ReadTimeout = SerialPort.InfiniteTimeout Then
            st.ReadTimeout = 10000
        End If
        Using ms As New MemoryStream()
            While (True)
                Try
                    ' シリアルポートから一時バッファに読み込む
                    Dim read As Integer = st.Read(buf, 0, buf.Length)
                    If read > 0 Then
                        ' 一時バッファの内容をメモリ・ストリームに書き込む
                        ms.Write(buf, 0, read)
                    Else
                        Exit While
                    End If
                Catch ex As TimeoutException
                    'タイムアウト処理も入れておく
                    Exit While
                End Try
            End While
            ' メモリ・ストリームの内容をバイト配列に格納
            Return ms.ToArray()
        End Using
    End Function
```
上記のコードで期待するTIFF画像を得ることができました。
課題は10秒待たないとTIFFが得られないこと。
オシロからのTIFFデータの転送終了を知ることが出来れば完璧ですが、とりあえず及第点です。

回答いただいた方、ありがとうございました。

Accepted Answer

おそらく、pngなのかjpegなのかは問題ではなく、読んだByte配列をファイルに書けば良いので、
```vbnet
　　　　'ここに下記コードでデータは取得できそうですが、そこからPNGファイルに変換したいです
　　　　'画像ファイルに変換できるのなら、別の方法でも可です
       Dim buf(SerialPort1.BytesToRead) As Byte
       SerialPort1.Read(buf, 0, SerialPort1.BytesToRead)
       File.WriteAllBytes("aaa.png", buf)
```
これで良い気がします。

（追記）

pngデータの終わりはIENDチャンクというのを認識すれば良いみたいです。
上記を削除して、下記参考にデバッグしてみてください。
```vbnet
        Dim fs As FileStream
        Dim last12Bytes(12) As Byte
        Dim allBytes As Byte() = {}

        fs = File.Create("aaa.png")
        While Not isIEND(last12Bytes)
            Dim buf(SerialPort1.BytesToRead) As Byte
            SerialPort1.Read(buf, 0, SerialPort1.BytesToRead)
            allBytes = allBytes.Concat(buf)
            last12Bytes = allBytes.Skip(allBytes.Length - 12).Take(12)
        End While
        fs.Write(allBytes, 0, allBytes.Length)
    End Sub

    'IENDチャンクが来たらファイル終わり
    '00 00 00 00 "IEND" AE 42 60 82
    Private Function isIEND(last12Bytes() As Byte) As Boolean
        Dim iend() As Byte =
            New Byte() {&H0, &H0, &H0, &H0} _
            .Concat("IEND".Select(Of Byte)(
                Function(c)
                    Return Byte.Parse(c)
                End Function)) _
            .Concat({&HAE, &H42, &H60, &H82})

        Return last12Bytes.SequenceEqual(iend)

    End Function

```

ソースの先頭にこれが要るかも。
```
Imports System.IO
```

Answer

> 「また、RS232のようなインターフェースでは転送の終了を確認する方法がないので
ご注意ください。転送されるデータがASCIIであれば、CRやLFをもって転送終了と
する事もできますが、バイナリデータではそれができません。複数回読み込みを
行っていただき、データがある程度(10秒程度)来ない事を確認して転送の終了と
するのが確実です。」

とのことですので、最終データ受信から10秒データの受信がなかったら画像データ終了とみなすしかないかと思います。(10秒間未受信というのも長いような気もしますが)
ただし、10秒間データを受信しなかったから正常に画像データを受信できたかの保障はありません。


```VBNET
    Public Sub ReadBinaryData(st As Stream, filename As String)

        Dim buf(32768) As Byte ' 一時バッファ
        Dim lastRecive As DateTime = Now

        Using fs As New FileStream(filename, FileMode.Create, FileAccess.Write)

            While (True)
                ' ストリームから一時バッファに読み込む
                Dim read As Integer = st.Read(buf, 0, buf.Length)

                If read > 0 Then
                    ' 一時バッファの内容をメモリ・ストリームに書き込む
                    fs.Write(buf, 0, read)
                    lastRecive = Now
                Else
                    if (Now - lastRecive).TotalSeconds > 10 Then
                        Exit While
                    End If
                End If
            End While

        End Using
    End Sub
```
上記ソースはイメージです（コンパイルも動作確認もしていません）

Answer

~~試したことに提示されているReadBinaryDataに、SerialPortのBaseStreamを渡し、~~戻ってきたバイト配列を、File.WriteAllBytesでファイルに出力すればよいのではないでしょうか。

BaseStreamはReadTimeoutを考慮してくれないようなので、SerialPortオブジェクトをそのまま使用した方がよいかもしれません。サンプルソースを少し弄ってみました。（デバッグはしてないです）
```vbnet
Public Function ReadBinaryData(st As SerialPort) As Byte()

    Dim buf(32768) As Byte ' 一時バッファ

    '無限に待たれても困るので、ReadTimeoutがInfiniteTimeoutならとりあえず10秒に設定
    If st.ReadTimeout = SerialPort.InfiniteTimeout Then
        st.ReadTimeout = 10000
    End If

    Using ms As New MemoryStream()

        While (True)
            Try
                ' シリアルポートから一時バッファに読み込む
                Dim read As Integer = st.Read(buf, 0, buf.Length)

                If read > 0 Then
                    ' 一時バッファの内容をメモリ・ストリームに書き込む
                    ms.Write(buf, 0, read)
                Else
                    Exit While
                End If

            Catch ex As TimeoutException
                'タイムアウト処理も入れておく
                Exit While
            End Try
        End While

        ' メモリ・ストリームの内容をバイト配列に格納
        Return ms.ToArray()

    End Using
End Function
```

前提・実現したいこと

発生している問題

該当のソースコード

解決したコード

関連した質問