[バッチファイル]for文で取り出すトークンの区切り文字について

Question

わからないこと

バッチファイルでDOSコマンドを扱っています。
その中で、echo文、for文に関して分からないことがあります。
下のバッチファイル①とバッチファイル②の出力結果が違う理由が分かりません。

下の参考にしたサイトにもあるように、for文で取り出したトークンは、半角スペースで区切ったものだと認識していたので、バッチファイル①の出力結果には納得しているのですが、バッチファイル②のように半角スペースを無視した上、トークンの区切りをカンマにして出力結果として出る理由が分かりません。

このような出力結果になる理由が書かれたサイト等あれば教えていただけますでしょうか。

バッチファイル①

バッチファイル

@echo off

set str=1,   2   ,   3   ,   4
echo %str% >A.txt
for /f "tokens=1,2,3,4" %%a in (A.txt) do @echo %%a/%%b/%%c/%%d

コマンドプロンプト上の出力結果

1,/2/,/3

バッチファイル②

バッチファイル

@echo off

set str=1,   2   ,   3   ,   4
for /f "tokens=1,2,3,4" %%a in ('echo %str%') do @echo %%a/%%b/%%c/%%d

コマンドプロンプト上の出力結果

1/2/3/4

参考にしたサイト

• テキストファイルの内容を区切り文字でトークンに分解し繰り返し処理を使う(FOR)
• For - DOS コマンド一覧 - Programming Field

環境

OS : Win10

Answer 1

コマンドラインの多くの場所では、"で囲まれていない, ; =は空白とみなされます。

例：

for %%A in (a b,c;d=e) do @echo [%%A]

echo > foo
ren foo, bar

echo %str%の結果に含まれるこれら文字も空白とみなされると言うことでしょう。
参考：

set str=1,   2   ,   3   ,   4
rem " で囲まれているので、そのままの文字として扱われる
for /f "tokens=1,2,3,4" %%a in ("%str%") do @echo %%a/%%b/%%c/%%d
rem " で囲まれていないので、空白として扱われる
for /f "tokens=1,2,3,4 usebackq" %%a in ('%str%') do @echo %%a/%%b/%%c/%%d

Comments

[vlb]

回答いただきありがとうございます。

なるほど、「"」で囲まれていれば「,」「;」「=」は文字として扱い、「"」で囲まれていなければ文字として扱わないのですね。

上の例だと「A.txt」内の文字と「"%str%"」の環境変数は文字として扱い、「'echo %str%'」の標準出力と「'%str%'」の環境変数は文字として扱わないという認識であっていますかね？

[otn]

'echo %str%' の結果がそういう扱いを受けるというのは今回まで知りませんでしたが、そういう結果ですね。" の外という意味では同じですが。

文字列の場合は、usebackq を使うかどうかで " で囲むかどうか決められますが、コマンド出力は usebackq を使っても使わなくても " の外なので、 , 等をそのま扱いたいという場合は、一旦ファイルに書かないといけなさそうです。