Terraformv0.14.8：indexの指定方法

Question

下記テンプレートをterraform applyで実行したところ、エラーとなりました。
Because aws_subnet.public_subnet_1a has "count" set, its attributes must be
accessed on specific instances
上記は、EC2作成時のサブネットの指定方法が謝っているが故のエラーなのですが、
この場合、例えば、「tf_public_subnet_1a」のサブネットを指定する場合、
どのように指定すればよろしいでしょうか？

variable "public_subnet" {
  default = {
    subnets = {
      tf_public_subnet_1a = {
        availability_zone = "ap-northeast-1a"
        cidr              = "10.0.0.0/24"
      }
      tf_public_subnet_1c = {
        availability_zone = "ap-northeast-1c"
        cidr              = "10.0.2.0/24"
      }
    }
  }
}

~~省略〜〜
resource "aws_subnet" "public_subnet_1a" {
  count = length(var.public_subnet.subnets)
  cidr_block        = values(var.public_subnet.subnets)[count.index].cidr
  availability_zone = values(var.public_subnet.subnets)[count.index].availability_zone
  tags = {
    Name = keys(var.public_subnet.subnets)[count.index]
  }
  vpc_id = aws_vpc.vpc_1.id
}
resource "aws_instance" "amazon_linux_01" {
  ami                    = data.aws_ami.ami.image_id
  vpc_security_group_ids = [aws_security_group.ssh_sg_01.id]
  subnet_id              = aws_subnet.public_subnet_1a.id
  key_name               = aws_key_pair.key_pair.id
  instance_type          = "t2.micro"

  tags = {
    Name  = "tf_amazon_linux",
    Owner = "suzukis"
  }
}
〜〜省略〜〜

Answer 1

リソースにindex numberをmappingする事が必須な要件ではない限り、for eachを使ったほうがシンプルで分かりやすい形で複数リソースを作成、及び値の参照ができます。countでもlookup、elementを利用すればloop時に利用する値の抽出はできなくはないですが、input valueのkeyにindex numberを埋め込む必要が出てくる等の制約が生まれ、可読性が下がるのであまりお勧めはできません。

#複数のリソースをfor eachによるloop処理で纏めて作成する
resource "aws_subnet" "public_subnet_each" {
  for_each 　　　　　= var.public_subnet.subnets
  cidr_block        = each.value.cidr
  availability_zone = each.value.availability_zone
  tags = {
    Name = each.key
  }
  vpc_id = aws_vpc.vpc_1.id
}

resource "aws_instance" "amazon_linux_01" {
  ami                    = data.aws_ami.ami.image_id
  vpc_security_group_ids = [aws_security_group.ssh_sg_01.id]
  subnet_id              = aws_subnet.public_subnet_each["tf_public_subnet_1a"].id
  key_name               = aws_key_pair.key_pair.id
  instance_type          = "t2.micro"

  tags = {
    Name  = "tf_amazon_linux",
    Owner = "suzukis"
  }
}

Comments

[fenethtool]

余談ですが、variableのdefault値にパラメータを記載するのは余りお勧めはしません。あくまでも外部からの入力受付用として機能するものなので、リソースをmodule化した場合に当該コードが紛れ込んでいると意図せぬリソースが作成されたり、といったリスクが考えられます。ユースケースによりけりですが、パラメータ記載には原則localsを使用する方が良いかと思います。