VBAでOutlookの予定を抽出したメールテンプレを作りたい

Question

前提・実現したいこと

日々の日報テンプレートを自動作成するため、Outlook2016のアプリから当日の予定のタイトルのみを抽出し、メールテンプレートを作成するマクロを組もうとしております。

発生している問題・エラーメッセージ

下記のサイトを参考にし、テンプレートファイルのパスのみを変更したコードを実行したところ、予定の抽出自体は問題なくできているものの、抽出される予定に意図しないものが含まれておりました。
具体的には、定期的な予定として登録されているものが1週間分全て記載されてしまっております。
例えば、月曜日のみの予定を取得したいのに、火曜日や水曜日にある定期的な予定も含まれてしまう（定期的ではない予定については取得されない）、といった事象です。
http://wiki.tk2kpdn.com/outlook-get-appointments-by-macro/

該当のソースコード

Public Sub CreateDailyMail()
    Dim l_calendar As Outlook.Folder
    Set l_calendar = Application.Session.GetDefaultFolder(Outlook.OlDefaultFolders.olFolderCalendar)
 
    Dim l_appointments As Outlook.Items
    Set l_appointments = l_calendar.Items
 
    Set l_appointments = l_appointments.Restrict( _
        "(([Start] = '2015/12/24 0:00') And ([AllDayEvent] = True)) Or " & _
        "(([Start] >= '2015/12/24 0:00') And ([End] < '2015/12/25 0:00'))")
 
    Dim l_appointmentList As String
    Dim l_appointment As Outlook.AppointmentItem
 
    For Each l_appointment In l_appointments
        l_appointmentList = l_appointmentList & l_appointment.Subject & vbCrLf
    Next
 
    ' テンプレート ファイルのパスの部分は、環境に応じて設定してください。
    Dim l_mail As Outlook.MailItem
    Set l_mail = Application.CreateItemFromTemplate("C:...\DailyReport.oft")
 
    l_mail.Body = Replace(l_mail.Body, "<<Appointments>>", l_appointmentList)
 
    l_mail.Display
End Sub
 

試したこと

恐らく、l_appointments.Resctictの中の条件が上手く絞れていないことが原因かと思い、AllDayEventの条件を削除したりしたのですが、出力結果は変わらずでした。何か上記の事象が引き起こされる原因についてご助言いただけますと最愛です。

Answer 1

Outlook で定期的な予定を展開して取得したい場合は、Items の IncludeRecurrences プロパティを True にする必要があります。
また、このプロパティを True にするには、開始日で予定をソートしておく必要もあります。
元のコードに上記の処理を追加し、余計な条件を削除すると以下のようになります。

Public Sub CreateDailyMail()
    Dim l_calendar As Outlook.Folder
    Set l_calendar = Application.Session.GetDefaultFolder(Outlook.OlDefaultFolders.olFolderCalendar)

    Dim l_appointments As Outlook.Items
    Set l_appointments = l_calendar.Items

    l_appointments.Sort "[Start]"
    l_appointments.IncludeRecurrences = True
    Set l_appointments = l_appointments.Restrict( _
        "(([Start] >= '2015/12/24 0:00') And ([End] < '2015/12/25 0:00'))")

    Dim l_appointmentList As String
    Dim l_appointment As Outlook.AppointmentItem

    For Each l_appointment In l_appointments
        l_appointmentList = l_appointmentList & l_appointment.Subject & vbCrLf
    Next

    ' テンプレート ファイルのパスの部分は、環境に応じて設定してください。
    Dim l_mail As Outlook.MailItem
    Set l_mail = Application.CreateItemFromTemplate("C:...\DailyReport.oft")

    l_mail.Body = Replace(l_mail.Body, "<<Appointments>>", l_appointmentList)

    l_mail.Display
End Sub

https://docs.microsoft.com/ja-jp/office/vba/api/outlook.items.includerecurrences

Comments

[FromMZ1500]

質問者さんは沙汰なしですが、IncludeRecurrences プロパティはたいへん参考になりました。

[Jeter_dx]

大変失礼いたしました、確認遅くなってしまいましたがこちらで試してみた結果、無事抽出することができました。お二方ともご助言いただき、ありがとうございました！

Answer 2

Start,Endともに対象日をまたいで設定された予定は入らないし、定期的な予定は無条件に含まれるようですね。
たぶんこれはこういうもので、基本その日中にStart,Endが設定されている単発予定だけを対象に考えて使うものなんでしょう。

定期的な予定を省くのは、For Eachのところで isRecurring を見てはじけばよいと思います。

定期的の条件をつぶさに見て省くのも検討したいところですが、AppointmentItem のインターフェースは定期的条件が簡単には取れないような感じです。さらには、定期的な予定の「ある日の予定」だけを切り離して個別の予定にしてしまった場合なども考慮すると、検索で対象を正確に捉えるのは データモデリング的に破綻している いろいろと難しすぎる 気がします。