パラメータが無効です

Question

内容

折れ線グラフに表示されているマーカーの色やサイズを
指定するマーカーのみを変更するマクロを作成しました。
しかし「パラメータが無効です」との表示がでて、動作が停止します。
原因を探りましたが、分かりませんでした。ご教授願います。
（使用環境：Windows7、Excel2013）

コード

'定義）異状と判定された回数
Dim 個数
個数 = Sheets("sheet1").Range("C1").Value

'定義）繰り返し処理の回数
Dim i
For i = 1 To 個数

'定義）異状と判定されたマーカーポイント
Dim 指定マーカー
指定マーカー = Sheets("sheet1").Cells(1 + i , 1).Value

'グラフを選択
ActiveSheet.ChartObjects("グラフ1").Activate

'対象のマーカーを選択

ActiveChart.FullSeriesCollection(1).Points(指定マーカー).Select

'マーカーの型とサイズ色を指定
With Selection
.MarkerStyle = 1
.MarkerSize = 8
.MarkerBackgroundColor = RGB(255, 0, 0)
.MarkerForegroundColor = RGB(255, 0, 0)
End With

Next i

Answer 1

指定マーカーは 1,2,3, のようなIndexですか？
Worksheets("Sheet1")などと異なり、
Pointsの添え字は"S1P1"のような名前ではエラーになるようです。

もし名前で指定したい場合は、たとえば以下のようなコードが考えられます。

Dim dic  As Scripting.Dictionary
Set dic = CreateObject("Scripting.Dictionary")
For i = 1 To 個数
    dic(Sheets(1).Cells(1 + i, 1).Value) = 0
Next
Dim pt As Point
For Each pt In ActiveChart.FullSeriesCollection(1).Points
    If dic.Exists(pt.Name) Then
        With pt
        .MarkerStyle = 1
        .MarkerSize = 8
        .MarkerBackgroundColor = RGB(255, 0, 0)
        .MarkerForegroundColor = RGB(255, 0, 0)
        End With
    End If
Next

なお、Indexの場合なら、以下のように変えたら改善するかもしれません。

    With ActiveSheet.ChartObjects(1).Chart.FullSeriesCollection(1).Points(指定マーカー)
        .MarkerStyle = 1
        .MarkerSize = 18
        .MarkerBackgroundColor = RGB(255, 0, 0)
        .MarkerForegroundColor = RGB(255, 0, 0)
    End With

Comments

[xail2222]

Pointsの添え字が"S1P1"のような名前の場合、「型が一致しません。」のようですね。
「パラメータが無効です」は、添え字が数値で範囲外の時に発生しました。
なので指定マーカーには数値が入ってるんじゃないかと想像します。

指定マーカーに何の値を入れているのか確認した方がいいかもしれないですね。

[Hayakawa3]

返信が遅くなり、大変申し訳ございません。
指定マーカーの数値が折れ線グラフの範囲外の数値があり、
「パラメーターが無効です」のエラー表示が出ていました。
ご解答、有難うございました。