VB.netでExcelに書いたグラフの軸ラベルを入力したい

Question

VB.netでExcelに書いたグラフの軸ラベルを入力したい

VBでエクセルにグラフを書いたのですが横軸ラベルと縦軸ラベルを入れたいと思っています。
VBAのコードが使えるかと思い試しましたがうまくいきませんでした。
コードをご存じの方がいらっしゃれば教えてください。

試したこと

    Dim sheets = objWorkBook.Worksheets
    Dim sheet = DirectCast(sheets(1), Excel.Worksheet)
    Dim chartObjects = DirectCast(sheet.ChartObjects, Excel.ChartObjects) ' チャートコレクション取得
    Dim chartArea = sheet.Range("G2:M20") ' チャートを配置するセル
    Dim chartObject = chartObjects.Add(
CDbl(chartArea.Left), CDbl(chartArea.Top),
CDbl(chartArea.Width), CDbl(chartArea.Height)) ' チャートオブジェクト作成
    Dim chart = chartObject.Chart ' チャート取得
    Dim xdata As Object
    Dim ydata As Object
    xdata = sh.Range(sh.Cells(1, 1), sh.Cells(count + 1, 1))
    ydata = sh.Range(sh.Cells(1, 2), sh.Cells(count + 1, 2))

    ' 系列作成
    Dim seriesCollection = DirectCast(chart.SeriesCollection, Excel.SeriesCollection)
    Dim series = seriesCollection.NewSeries()
    series.Name = ""
    series.Values = ydata
    series.XValues = xdata
    series.ChartType = Excel.XlChartType.xlXYScatterLinesNoMarkers ' 散布図

上記コードに
series.Values.xLAxis.text = ""
series.XValues .xLAxis.text = ""
を追記したのですが駄目でした。

Answer 1

（散布図Chartの概念はよくわからないのですが）、↓これで軸ラベルが設定できるかと思います。

        series.ChartType = Excel.XlChartType.xlXYScatterLinesNoMarkers ' 散布図

        Dim objAxesCat As Excel.Axis = chart.Axes(Excel.XlAxisType.xlCategory)
        Dim objAxesVal As Excel.Axis = chart.Axes(Excel.XlAxisType.xlValue)
        objAxesCat.HasTitle = True
        objAxesVal.HasTitle = True
        objAxesCat.AxisTitle.Text = "Categoryラベル"
        objAxesVal.AxisTitle.Text = "Valueラベル"

chart.ApplyLayout(10, Excel.XlChartType.xlXYScatterLinesNoMarkers)
とかで最初から軸ラベル有Layoutだと HasTitle = True は省けます。

Comments

[VBUser]

ありがとうございました。
非常に丁寧にが回答くださり理解できました。
貴重なお時間割いていただきありがとうございました。