WORDマクロの文字検索について

Question

マクロを勉強中です。
WORDマクロについてお知恵を拝借できないでしょうか。
よろしくお願い致します。

特定宛先の資料だけ扱いが違います。
以下条件が全て一致する場合、メッセージを出したいです。

◎条件
A：宛先A
B：○○○○社
D：資料名
C：お知らせします。

特定宛先(A)かつ資料がある場合のみ、注意メッセージを表示する。
資料名(D)は必ず社名(B)～文字列(C）の間に記載される。

Dim Myrng As Range

	Myrng = "文字列A"

	Do While Myrng.Find.Execute = True
	
	If .Found = True Then
		MsgBox "資料名(D)"  & "の送付方法にご注意ください" 
	End If

Comments

[退会済みユーザー]

②の意味するところがわかりません。
具体例を提示していただきたいです。
あと、コードを提示する際はマークダウンを使用してください。

[W.kirai]

御覧いただき、ありがとうございます。
記載内容を修正しました。
複数条件の設定方法が分からず、ご教示いただけると幸いです。

[退会済みユーザー]

複数の文字列を一回でFindすることはできないようですので、「資料がある場合」をどう判定するかを考えます。
「資料がある場合」＝「資料がない場合以外」ですが、資料がない場合にBとCの間はどうなりますか？
例えば「改行しか入らない」という条件が成り立つのであれば、「Bの末尾とCの先頭の間に改行以外が含まれない」場合は資料なし、と判定できます。

[W.kirai]

資料がない場合にBとCの間は「改行しか入らない」になります。

[退会済みユーザー]

お、でしたら上記をVBAで書けばOKですね。
明日また来ますので、ちょっと頑張ってみてください。

Answer 1

こんな感じでしょうか。

Option Explicit

Private Const SPECIAL_DESTINATION_STRING    As String = "宛先A"             '特定宛先を指定する文字列
Private Const SEARCH_START_STRING           As String = "○○○○社"        '検索開始条件となる文字列
Private Const SEARCH_END_STRING             As String = "お知らせします。"  '検索終了条件となる文字列

'資料の有無をチェックする
Public Sub CheckDocument()
    Dim startPosition   As Long     '資料検索開始位置
    Dim endPosition     As Long     '資料検索終了位置
    Dim documentName    As String   '資料名
    Dim foundRange      As Range    '検索用Range
    Dim i               As Long     'ループカウンタ
    
    '特定宛先でない場合は処理を終了する
    With ActiveDocument.Content.Find
        .ClearFormatting
        .Text = SPECIAL_DESTINATION_STRING
        If Not .Execute Then
            MsgBox "特定宛先ではありません"
            Exit Sub
        End If
    End With
    
    '変数を初期化する
    startPosition = 0
    endPosition = 0
    documentName = ""
    
    '資料検索開始位置を取得する
    Set foundRange = ActiveDocument.Content
    With foundRange.Find
        .ClearFormatting
        .Text = SEARCH_START_STRING
        If .Execute Then
            startPosition = foundRange.End + 1
        End If
    End With
    
    '資料検索終了位置を取得する
    Set foundRange = ActiveDocument.Content
    With foundRange.Find
        .ClearFormatting
        .Text = SEARCH_END_STRING
        If .Execute Then
            endPosition = foundRange.Start
        End If
    End With
    
    '改行以外の文字を検索する
    If startPosition > 0 And endPosition > 0 Then
        If startPosition < endPosition Then
            For i = startPosition To endPosition
                If ActiveDocument.Characters(i).Text <> vbCr Then
                    documentName = documentName & ActiveDocument.Characters(i).Text
                End If
            Next
        End If
    End If
    
    'チェック結果メッセージを表示する
    If documentName <> "" Then
        MsgBox documentName & "の送付方法にご注意ください"
    Else
        MsgBox "資料はありません"
    End If
End Sub

Comments

[W.kirai]

ありがとうございます。
助かります。m(_ _)m