VBA マクロ

Question

やりたいこと
毎回マクロ実行用コマンドボタン表示させたい。

Answer 1

こういうことですか？

Dim bt As Button
For Each bt In trgtSh.Buttons
    With trgtSh2.Buttons.Add(bt.Left, bt.Top, bt.Width, bt.Height)
        .Caption = bt.Caption
        .OnAction = bt.OnAction
    End With
Next

---

＜追記＞
こういうことですか？

Private Sub CommandButton1_Click()
    Dim trgtSh As Worksheet
    Dim trgtSh2 As Worksheet
    Set trgtSh = Worksheets("入力")
    Set trgtSh2 = Worksheets("グラフ")
    Dim dataRng As Range
    Set dataRng = trgtSh.Range("A1:D4")
    Dim pasteRng As Range
    Set pasteRng = trgtSh2.Range("G2")
    
    'グラフ作成
    With trgtSh2.Shapes.AddChart.Chart
        .ChartType = xlColumnClustered
        .SetSourceData dataRng
        .HasTitle = True
        .ChartTitle.Text = "売上"
    
        .Parent.Top = pasteRng.Top
        .Parent.Left = pasteRng.Left
    End With
    
    'ボタン追加（位置の準備）
    Dim wLeft, wTop
    With trgtSh2.Shapes(1)
        wLeft = .Left + .Width + 10
        wTop = .Top + 10
    End With
    
    '１つめのボタン
    Dim bt1 As Button
    Set bt1 = trgtSh2.Buttons.Add(wLeft, wTop, 100, 100)
    With bt1
        .Caption = "ボタン名1"
        .OnAction = "Sub名1"
        .AutoSize = True
    End With

    '２つめのボタン
    Dim bt2 As Button
    wTop = wTop + bt1.Height + 10
    Set bt2 = trgtSh2.Buttons.Add(wLeft, wTop, 100, 100)
    With bt2
        .Caption = "ボタン名2"
        .OnAction = "Sub名2"
        .AutoSize = True
    End With

End Sub

Comments

[m_ao]

ありがとうございました。はい、ボタンが作成されました。
すみませんが教えてください。
位置は指定できますか？グラフの横に表示したく。
また今回1個しかボタンが作成されませんでした。もう1個作成したい場合は、上記のコードをbt2として追記作成するのでしょうか？
今後作成しようとするマクロは、bt.OnActionという名前で作成すればいいのでしょうか？

[jinoji]

まず、前提がよくわからないのですが、
「入力」「グラフ」の２つのシートがある
「グラフ」シートは、最初は空
「入力」シートにはデータが入力されていて、ボタンが１つある
「入力」シートのボタンを押すと、「UserForm1」というフォームが表示される
「UserForm1」にはボタンが１つある
「UserForm1」のボタンを押すと、「グラフ」シートにグラフが追加される
そして、その後に「グラフ」シートに、ボタンを２つ追加させたい。

こういうことですか？

[jinoji]

私が書いたコードは、
「入力」シートにあるボタンと同じものを「グラフ」シートにも作る、という動きをしています。
1個しかボタンが作成されなかったということは、「入力」シートに1個だけボタンがあったということ。
ボタンの位置と大きさも「入力」シートのボタンと同じにしていますので、
（ Add(bt.Left, bt.Top, bt.Width, bt.Height)のところ。btは「入力」シートのボタン）
位置を変えたいのであれば、bt.Left, bt.Top のところを、
wLeft = 追加したグラフ.Left + 追加したグラフ.Width + 多少の隙間
wTop= 追加したグラフ.Top + 多少の調整
みたいにするとよいと思います。

[m_ao]

回答ありがとうございました。説明が不足し申し訳ありませんでした。
「グラフ」シートにグラフを作成し、さらに新たに2個コマンドボタンを作成しようとしていました。

[jinoji]

回答を追記しました。あとは、ボタン名1,ボタン名2のところをデータ比較1,データ比較2にして、Sub名1、Sub名2のところを、ボタンを押したときに走らせる処理の関数名にしたら良いはずです。

[m_ao]

どうもありがとうございました。こちらで無事にできました。