Terraformにてresource not foundでのstate lockエラーの解決について

Question

概要

Terraformの学習でState Lockingの導入の練習で詰まっている箇所があります。

# Specify the provider and access details
provider "aws" {
  region  = "ap-northeast-1"
  profile = "default"
}

terraform {
  backend "s3" {
    key            = "terraform.tfstate"
    bucket         = "terraform-sample-yuta"
    region         = "ap-northeast-1"
    dynamodb_table = "terraform-state-lock-dynamo"
  }
}

resource "aws_dynamodb_table" "dynamodb-terraform-state-lock" {
  name           = "terraform-state-lock-dynamo"
  hash_key       = "LockID"
  read_capacity  = 20
  write_capacity = 20

  attribute {
    name = "LockID"
    type = "S"
  }

  tags = {
    Name = "DynamoDB State Lock Table"
  }
}

resource "aws_instance" "web" {
  instance_type = "t3.small"
  # Amazon Linux2
  ami   = "ami-0992fc94ca0f1415a"
  count = 1
  tags = {
    Name = "EC2 instance terraform"
  }
}

こちらのHCLファイルをterraform planで実行しますと以下のエラーがでます。

$ terraform plan

Error: Error locking state: Error acquiring the state lock: 2 errors occurred:
	* ResourceNotFoundException: Requested resource not found
	* ResourceNotFoundException: Requested resource not found



Terraform acquires a state lock to protect the state from being written
by multiple users at the same time. Please resolve the issue above and try
again. For most commands, you can disable locking with the "-lock=false"
flag, but this is not recommended.

エラー内容を確認しますとリクエストしたリソースが見つからないというエラーのように見えます。
２つあるので、DynamoDBとEC2インスタンスの作成でリソースがないと怒られていると思うのですが、分割して実行したときはちゃんと上手く言ったので、足りていないとは思えないです。
非推奨のterraform apply -lock=falseで実行すればいちおう動きますが非推奨なのでなるべく使いたくないという気持ちです。
なにがいけないか分かる方いますでしょうか？

Answer 1

こちらの方の回答を基に解決に至りました。Terraform error “Error locking state: Error acquiring the state lock: 2 errors occurred”

原因としてはS3バックエンド宣言とDynamoDBの作成を一緒に行うとダメなようです。
まず最初にS3とDynamoDBを作成してから、S3バックエンドの宣言を行う必要があります。

# Specify the provider and access details
provider "aws" {
  region  = "ap-northeast-1"
  profile = "default"
}

resource "aws_s3_bucket" "terraform_state" {
  bucket = "terraform-sample-yuta"
  
  versioning {
    enabled = true
  }
  
  server_side_encryption_configuration {
    rule {
      apply_server_side_encryption_by_default {
        sse_algorithm = "AES256"
      }
    }
  }
}

resource "aws_dynamodb_table" "dynamodb-terraform-state-lock" {
  name           = "terraform-state-lock-dynamo"
  hash_key       = "LockID"
  read_capacity  = 20
  write_capacity = 20

  attribute {
    name = "LockID"
    type = "S"
  }

  tags = {
    Name = "DynamoDB State Lock Table"
  }
}

#terraform {
#  backend "s3" {
#    key            = "terraform.tfstate"
#    bucket         = "terraform-sample-yuta"
#    region         = "ap-northeast-1"
#    dynamodb_table = "terraform-state-lock-dynamo"
#  }
#}

この状態でterraform init、terraform applyを実施しS3とDynamoDBを作成後、改めてS3バックエンド宣言を行うことでリソースの作成に成功することが出来ました。

terraform apply
~~~~~~~~~~~~~~~~

Apply complete! Resources: 2 added, 0 changed, 0 destroyed.