VBA 貼り付け禁止と特定の文字列入力でそれの解除

Question

実現したいこと

不特定多数の人が使うファイルで、貼り付けでセルの内容が書き換えられるのを防ぐため
貼り付けはできなくし、管理者が使うときにそれをOFFにしたいと考えています。
そのようなことは可能でしょうか。

VBAを使用して、特定のシートのみコピーはできるが貼り付けができないようにし、
A1セルに特定の文字列を入れると確認のメッセージが出て選択で
貼り付けもできるようになるようにしたいです。
下記コードでは、貼り付けはできないですが、貼り付け禁止の解除もできません。

ご教示いただけますと幸いです。
Excel2016です。
よろしくお願いします。

該当のソースコード

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
If (Application.CutCopyMode <> False) Then
Application.CutCopyMode = False
End If
End Sub

Private Sub Copyボタン_Click()
Dim F As Integer
F = MsgBox("コピペを有効にしますか？", vbYesNo)
If F = vbYes Then
Application.CutCopyMode = True
Else
Application.CutCopyMode = False
End If
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
Dim MyRow As Long
Dim MyCol As Integer
    MyRow = Target.Row
    MyCol = Target.Column
    If MyRow = 1 And MyCol = 1 Then
        If Cells(1, 1) = 3 Then
            Copyボタン_Click
            End If
        End If
End Sub

Answer 1

こんな感じでいかがでしょうか。

Option Explicit

Dim CanPaste As Boolean

Private Sub Worksheet_Activate()
    If Not CanPaste Then Application.CutCopyMode = False
End Sub

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Not CanPaste Then Application.CutCopyMode = False
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Target.Address = "$A$1" Then Exit Sub
    If Target.Value = 3 Then Call Copyボタン_Click
End Sub

Private Sub Copyボタン_Click()
    CanPaste = MsgBox("コピペを有効にしますか？", vbYesNo) = vbYes
End Sub

Comments

[mutttttton]

早速のご回答ありがとうございます！
やりたいことが完璧にできました。
助かりました！