【VBA】ソートしたA列から特定の値をIF文で見つけ、違う値が出てきたら処理を終わらせたい

Question

こんにちは。
エクセルVBAにて以下の機能を実装しております。

〇表
Ａ　　　　　Ｂ　　　　　Ｃ
１００　　　１　　　　　あ
１００　　　２　　　　　い
１０１　　　３　　　　　う
１０１　　　４　　　　　え
１０２　　　５　　　　　お
１０２　　　６　　　　　か

〇機能
IF文とFOR文にて
A列に特定の値（今回は１０１）が存在する場合
その行のデータ（今回は３、う と ４、え）を取得する。

〇コード

Dim A As String
A = "１０１"

For i = 1 To MaxRow
    If Cells(i, 1) = A Then
        ～～～～
    Endif
Next i

〇質問
現状は最下行を取得し全行に対し「１０１かどうか」の判定を行っております。
ソートされた表のため、１０１の次の行が別の値や空欄となった場合
そこでFOR文を抜ける（Exit For）方法について
ご教示をお願い致します。

Answer 1

ちょっと変化球ですが。

Dim A As String
A = "１０１"

Dim c As Long, m As Long, r As Range
c = WorksheetFunction.CountIf(Columns(1), A)             'いくつあるかをカウント
If c > 0 Then
    m = WorksheetFunction.Match(A, Columns(1), False)    '最初に登場する行番号を見つける
    For Each r In Cells(m, 1).Resize(c)                  'ｍ行目からｃセル分の範囲でループ
        Debug.Print r.Offset(, 1), r.Offset(, 2)
    Next
End If

Comments

[arumikann]

回答ありがとうございました！

検索範囲をあらかじめ絞るという方法もあるのですね・・・。
別の機会にて活用してみたいと思います！

評価が遅くなり大変申し訳ございません・・・。

Answer 2

なんらかの形でフラグ持たせて条件判定でいいんじゃないですかね。

'Boolean型の初期値はFalse
Dim Checker As Boolean

For i = 1 To MaxRow
    If Cells(i, 1) = A Then
        '～～～～
        Checker = True
    ElseIf Checker = True Then
        Exit For
    End If
Next i

Comments

[arumikann]

回答ありがとうございました！

フラグを持たせるという方法を知ることができ勉強となりました。

評価が遅くなり大変申し訳ございません・・・。

Answer 3

Aにあたればjを1にして、Aを抜けてjが1ならExitしてます。

Dim j As Long
j=0

For i = 1 To MaxRow
    If Cells(i, 1) = A Then
        '～～～～
        j = 1
    ElseIf j = 1 Then
        Exit For
    End If
Next i

Comments

[radames1000]

低評価の方、理由を教えていただけたら幸いです。
MaxRowの部分は修正しましたが、それ以外にあれば。

[arumikann]

回答ありがとうございました！

最も早くご回答いただきましたため
ベストアンサーとさせて頂きます！
おかげさまで想定通りの機能が実装できました。

また、返答が遅くなり大変申し訳ございません・・・。