Excel タブごとにPDF化し名前を付けて保存 セルから取得

Question

Excel2016使用しております。

ExcelをタブごとにPDFとして名前をつけて保存したいです。
また、その時の名前をセルから取得した日付と文字で名前を付けたいです。

最終的なPDFの名前としては、
210208_仕入先名（客先名）_注請見.pdf
としたいです。

日付、仕入先名、客先名がそれぞれ別のセルに記載されている状態で、
、（）、、注請見　は毎回固定で入れたいです。

Sub ワークシートごとにPDFに変換()

Dim i As Long
For i = 4 To Sheets.Count

Sheets(i).ExportAsFixedFormat Type:=xlTypePDF, _
FileName:="K:\Desktop" & "" & Worksheets(i).Range("AB1") & Worksheets(i).Range("E6") & Worksheets(i).Range("E8"), _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
IgnorePrintAreas:=False, OpenAfterPublish:=True
Next i

End Sub

すいませんが、宜しくお願い致します。

Answer 1

ご提示のコードでほぼ正解に思えますが、
たとえばこんな感じでしょうか。

Sub sample()
    Const 日付セル = "AB1", 仕入先名セル = "E6", 客先名セル = "E8"
    Dim 日付, 仕入先名, 客先名, ファイル名
    Dim i
    Dim ws As Worksheet
    For i = 4 To Sheets.Count
        Set ws = Sheets(i)
        日付 = Format(ws.Range(日付セル).Value, "YYMMDD")
        仕入先名 = ws.Range(仕入先名セル).Value
        客先名 = ws.Range(客先名セル).Value
        ファイル名 = 日付 & "_" & 仕入先名 & "（" & 客先名 & "）_注請見"
        Debug.Print 日付, 仕入先名, 客先名, ファイル名
        ws.ExportAsFixedFormat xlTypePDF, ファイル名, xlQualityStandard, True, False, , , True
    Next
End Sub

Comments

[yu_tommy]

ご返信遅くなり大変申し訳ございません。
早々にご回答頂いており、誠にありがとうございます。
無事上手くいきました！本当にありがとうござました！