VBAでoutlookにPDFを添付したい

Question

前提・実現したいこと

エクセルVBAでoutlookを立ち上げ、事前にデスクトップに保存しておいたPDFを
outlookに添付後、送信。という形を取りたいです。

現在outlookに添付しようとしたところでエラーがでました。

尚、事前に作成したPDFの名前はエクセルのセル"B5"の文字列がそのまま名前になっています。
マクロ完成後は不特定多数で使用予定です

発生している問題・エラーメッセージ

実行時エラー13
型が一致しません。

該当のソースコード

    Dim OL As outlook.Application
    Set OL = CreateObject("Outlook.Application")
    Dim ws As Object, dt As Variant
    Dim outlook As Object
    Dim mail As Object
    Set ws = CreateObject("WScript.Shell")
    Dim MI As outlook.MailItem
    Set MI = OL.CreateItem(olMailItem)
    
    Dim R As Range
    Set R = Range("B5")
    dt = ws.SpecialFolders("Desktop") \ R
    
    Set outlook = CreateObject("Outlook.Application")
    Set mail = outlook.CreateItem(0)
    With mail
        .BodyFormat = 2
        .To = "[e-mail]"
        .Subject = "テスト送信"
        .Body = "テスト送信です"
        .Attachments.Add dt & ".pdf"
        .Send
    End With
        
    MI.Display

試したこと

上記コードの変数Rの部分を省いたりしましたが
エラーが出てしまいました

補足情報（FW/ツールのバージョンなど）

office2016

Comments

[m.ts10806]

PDFでなければ添付はできたのでしょうか。
あと添付なしでメール送信はできてるのでしょうか。

[hiro_01]

上記、修正させて頂きました。
添付なしであればDisplayで表示させた後に、送信まではできる状態です。

Answer 1

質問のエラーの原因はおそらく下記でしょう。

dt = ws.SpecialFolders("Desktop") \ R

PDFファイルのパスを生成しようとしているのだと思いますが、文字列なので、下記のようにしないと方不一致エラーになります。（文字列の扱いの基本です。）

dt = ws.SpecialFolders("Desktop") & "\" & R.Text

そもそも、
CreateObject("Outlook.Application")を2度したり、意味不明のコードになってます。コードの意味を理解せずに、複数の場所から切り貼りしたような印象ですね。

現状のコードの無駄なコードを削除して、読みやすいように並べ替えてみました。
それぞれのコードの簡単な意味をコメントにつけました。

    'Outlookのインスタンス生成
    Dim OL As outlook.Application
    Set OL = CreateObject("Outlook.Application")
    'メールオブジェクトの生成
    Dim MI As outlook.MailItem
    Set MI = OL.CreateItem(olMailItem)


    'PDFファイル名生成
    Dim R As Range, ws As Object, dt As Variant
    Set R = Range("B5")
    Set ws = CreateObject("WScript.Shell")
    dt = ws.SpecialFolders("Desktop") & "\" & R.Text

    With MI
        .BodyFormat = 2
        .To = "[e-mail]"
        .Subject = "テスト送信"
        .Body = "テスト送信です"
        .Attachments.Add dt & ".pdf" 'ファイル添付
        .Send                        'メール送信
    End With

    MI.Display

Comments

[hiro_01]

解答を頂くどころか、コードまで記述して頂きありがとうございます！

仰る通り、理解等はしようとせずにとりあえず・・・でやっておりました。
この度はお答え頂きありがとうございました！