Fortran csvファイルの数字をプログラムの変数に格納したい

Question

Fortran csvファイルの数字をプログラムの変数に格納したい
Nc=Nd=34
real(8)a(0:Nc+1,0:Nd+1)
real(8)b(0:Nc+1,0:Nd+1)
という2つの変数にcsvファイルからの数値を格納したいです

csv (:は3~1296まで1ずつ増加していることを意味しています)
1,1
2,2
3,3
:,:
1296,1296

上記のようなcsvファイルです．
1列目の値は変数aに，2列目の値は変数bに格納したく，
各列に関して，
i = 1,36
でまずa(i,0)で列の上から代入していって36行目まで格納した後に
→a(i,1)→a(i,2)・・
と移動し，
a(i,35)まで格納する方法を教えていただきたいです．

変数として代入する方法が良くわからないので，詳しいかたにご教授いただきたいです．

Comments

[Orlofsky]

[FORTRAN]タグを追加しては？

[退会済みユーザー]

ありがとうございます．
追加依頼します．

Answer 1

I/O の問題と、配列の変形の問題に切り分けよう。

csv は list-directed (* format のこと）で読み込めばいい。ただし、色々落とし穴があるので要注意だが。（ブービートラップだらけのべトコンの村を捜索するつもりで行けば問題ない。）

とりあえずワーク配列に一気にに読み込んで、その後で変形するのが楽。
Fortran は列優先なので、これは頭に叩き込んでおく必要がある。
wk に一気に読み込むと、入力ファイルの一列目は wk(1, :) に入り、二列目は wk(2,:) に入る。

次に、それぞれの一次元の列を二次元に直してやればいい。それには reshape 関数を使う。
Fortran は列優先なのを念頭に変形すると、今の場合は素直に配列サイズを与えればいい（はず）。
二次元配列が 0 始まりなので混乱するかもしれないが、単にサイズを与えればいい。

読み込み１行、変形２行で目的は達せられる。

プログラム

    program Console23
        implicit none
        integer, parameter :: nc = 2, nd = 2
        real(8) :: a(0:nc+1, 0:nd+1), b(0:nc+1, 0:nd+1)
        real(8) :: wk(2, (nc+2)*(nd+2))
        open(10, file = 'input.dat')
        read(10, *) wk

        a = reshape(wk(1, :), shape(a))   
        b = reshape(wk(2, :), shape(b))
! サイズを手動で与えてもいい a = reshape(wk(1, :), [nc+2, nd+2])
                
        
!check
        block
            integer :: i
            do i = 0, nc+1
                 print '(4(g0, 1x))', a(i, :)
            end do
        end block
    end program Console23

テスト入力ファイル

input.dat　めんどいので 4*4 サイズで。

1,1
2,2
3,3
4,4
5,5
6,6
7,7
8,8
9,9
10,10
11,11
12,12
13,13
14,14
15,15
16,16

実行結果

1.000000000000000 5.000000000000000 9.000000000000000 13.00000000000000
2.000000000000000 6.000000000000000 10.00000000000000 14.00000000000000
3.000000000000000 7.000000000000000 11.00000000000000 15.00000000000000
4.000000000000000 8.000000000000000 12.00000000000000 16.00000000000000

Comments

[退会済みユーザー]

詳しくありがとうございました，実行した結果うまく回りました．
また機会がございましたら，よろしくお願いいたします．