processingで円を描画する際大きさをランダムに変更する

Question

これまで出来たこと
processingを使用して3種類の大きさの円を重ならないように描画していました。
これまでは
大　36px
中　24px
小　12px
で円を描画していました。
以前回答いただいたコードを使用していました。
このコードでは
大2個
中30個
小2個
も円を描画していました。

// 必要サイズ候補を羅列(大きい順のほうが少し安全？ 時間がかかったり無限ループになりにくい)
int[] sizes = {
  36, 36, 
  24, 24, 24, 24, 24, 24, 24, 24, 24, 24,
  24, 24, 24, 24, 24, 24, 24, 24, 24, 24,
  24, 24, 24, 24, 24, 24, 24, 24, 24, 24, 
  12, 12, 
};
ArrayList<PVector> circles; // 円のデータ

void setup() {
  size(600, 600);
  smooth();

  frameRate(10); // 1秒に10回再描画（数字を増やすと早くなる）
}

void draw() {
  background(255);
  circles = new ArrayList<PVector>(); // 毎回circlesを作り直す

  // 円のデータを準備
  addCircle();

  // 円を全部描画
  for (int i = 0; i < circles.size(); i++) {
    PVector p = circles.get(i);
    noStroke();
    fill(0);
    ellipse(p.x, p.y, p.z, p.z);
  }

  // 画像の保存 a1.png a2.png ...
  save("F:/a/1/" + "a" + frameCount + ".png");

  if (frameCount == 100) { // n枚作ったら止める
    noLoop(); // 止める

    //launch("start " + sketchPath()); // Windows専用 エクスプローラでフォルダを開く
    //exit(); // 終了
  }
}

void addCircle() {
  while (circles.size() < sizes.length) { // 円のデータの個数が、必要サイズ候補数より少ない間ループ
    // サイズを取得（配列は０始まりなので、circles.size()が0の時は0番目、circles.size()が1の時は1番目...
    int diameter = sizes[circles.size()];

    // 3次元のベクトルのうちxyを2次元座標、zを円の直径として利用している
    PVector c = new PVector(random(30,570), random(30,570), diameter);
    boolean overlapping = false;

    for (PVector p : circles) {
      // zは直径なので理屈的には割る2 くっついて見えるのがまずい場合は、少し足すなりなんなり
      if (dist(c.x, c.y, p.x, p.y) < (c.z + p.z) / 2) {
        overlapping = true;
        break;
      }
    }

    if (!overlapping) {
      circles.add(c);
    }
  }
}

これからしたいこと
円の直径をランダムにしたいです
大　36px→2248px
中　24px→821px
小　12px→1~7px
の様にそれぞれの区分に幅を持たせ画像を保存するごとに異なる直径の円を描画したいです。
円が重ならないことや、大、中、小の数は自分で指定出来ることはそのままにしたいです。
そこでコードを変更しました。
しかし、思ったように円の直径が変わりません。
どうしたらよいでしょうか？

// 必要サイズ候補を羅列(大きい順のほうが少し安全？ 時間がかかったり無限ループになりにくい)
int[] sizes = {
  int(random(22,49)),int(random(22,49)), 
  int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)), 
  int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),
  int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),int(random(8,22)),
  int(random(1,8)),int(random(1,8)),
};
ArrayList<PVector> circles; // 円のデータ

void setup() {
  size(600, 600);
  smooth();

  frameRate(10); // 1秒に10回再描画（数字を増やすと早くなる）
}

void draw() {
  background(255);
  circles = new ArrayList<PVector>(); // 毎回circlesを作り直す

  // 円のデータを準備
  addCircle();

  // 円を全部描画
  for (int i = 0; i < circles.size(); i++) {
    PVector p = circles.get(i);
    noStroke();
    fill(0);
    ellipse(p.x, p.y, p.z, p.z);
  }

  // 画像の保存 a1.png a2.png ...
  save("F:/a/1/" + "a" + frameCount + ".png");

  if (frameCount == 100) { // n枚作ったら止める
    noLoop(); // 止める

    //launch("start " + sketchPath()); // Windows専用 エクスプローラでフォルダを開く
    //exit(); // 終了
  }
}

void addCircle() {
  while (circles.size() < sizes.length) { // 円のデータの個数が、必要サイズ候補数より少ない間ループ
    // サイズを取得（配列は０始まりなので、circles.size()が0の時は0番目、circles.size()が1の時は1番目...
    int diameter = sizes[circles.size()];

    // 3次元のベクトルのうちxyを2次元座標、zを円の直径として利用している
    PVector c = new PVector(random(30,570), random(30,570), diameter);
    boolean overlapping = false;

    for (PVector p : circles) {
      // zは直径なので理屈的には割る2 くっついて見えるのがまずい場合は、少し足すなりなんなり
      if (dist(c.x, c.y, p.x, p.y) < (c.z + p.z) / 2) {
        overlapping = true;
        break;
      }
    }

    if (!overlapping) {
      circles.add(c);
    }
  }
}

回答お願いします。

Answer 1

int[] sizesは、プログラム開始時に1回だけ作られます。
そのため一度決まってしまったら、その数値が繰り返し使われます。

ではどうしたらいいでしょうか？
circlesと同じように、毎回作り直せばよいのです。

一番楽なのはint[] sizesの宣言をファイル先頭から、void addCircle()の中に移動することです。

ArrayList<PVector> circles;

void setup() { /* 省略 */ }
void draw() { /* 省略 */ }

void addCircle() {
  int[] sizes = { /* 省略 */ };
  
  while (circles.size() < sizes.length) {
// 省略

Comments

[21J]

回答ありがとうございます。
解決しました。