vbaで配列に入れた番号の行を一気に選択するには？

Question

条件に沿った行番号を配列に入れていきます。
その後配列内にある番号の行をすべて選択状態にするにはどうすればいいでしょうか。ローカルウィンドウで配列にpushされているのは確認しています。

行の一括削除が遅くて困っています。
フィルターかけて削除も考えましたが動的配列を練習で使ってみたくて・・・

Sub test()
    Dim i As Long, n As Long, m As Long
    Dim buf() As Integer
    
    i = 1
    ReDim buf(i)
    
    For n = 1 To 10
    If Cells(n, 2) = "" Then
    ReDim Preserve buf(i)
    buf(i) = n
    i = i + 1
    End If
    Next n
    
    'bufの行を一気に選択したい
    
End Sub

Answer 1

飛び飛びのセル範囲は Union で纏めることができます。そのうえで、Delete すればいいでしょう。

Sub test()
    Dim i As Long, n As Long, m As Long
    Dim buf() As Integer

    i = 1
    ReDim buf(1 To i)

    For n = 1 To 10
        If Cells(n, 2) = "" Then
            ReDim Preserve buf(1 To i)
            buf(i) = n
            i = i + 1
        End If
    Next n

    Dim r As Range
    Set r = Rows(buf(LBound(buf)))
    
    For n = LBound(buf) + 1 To UBound(buf)
       Set r = Union(r, Rows(buf(n)))
    Next
    
    r.Delete
End Sub

ただ、動的配列使わずに、直接Unionで纏めれば済む話ではあります。

Sub test1()
    Dim n As Long
    Dim r As Range    
     
    For n = 1 To 10
        If Cells(n, 2) = "" Then
           If r Is Nothing Then
               Set r = Rows(n)
           Else
               Set r = Union(r, Rows(n))
           End If
        End If
    Next n
    
    r.Delete
End Sub

Comments

[Izumo1101]

ありがとうございました

Answer 2

ReDimで一つずつ要素を追加しなおすのはcollectionのaddとは違いReDimする度に全要素を再設定しなおしているはずなので遅くなるはずです。
単純に高速化したいのであれば初回設定時に必要な範囲を一括で配列取得した方が効率的です。

ちなみに選択したいとのタイトルですが、選択後に一括削除したいという形であれば

Sub main()
Dim buf As Variant
'A列の10行目まで取得
buf = Range(Cells(1, 1), Cells(10, 1))
'～for文などで中身のデータを処理～
'A列に10行分貼り付け
Range(Cells(1, 1), Cells(UBound(buf, 1), 1)) = buf
End Sub

という形で上から張りなおした方が配列を使用する上では簡単です。