LEX,Yaccでの電卓環境構築

Question

前提・実現したいこと

大学でYaccやLEXについて学んでいます。
課題で分からなくなりましたので質問させていただきます。
電卓のプログラムが作成されており、そのコードを改良する課題です。

　(1) 実行文を:で区切って、１行に複数の文を記述する（全体で１つの複文となる）
　　　　例　a=0:b=1:c=2　　（ただし、複文は左の文から順に実行される）
　(2) 次のようなif文を使えるようにする。
　　　　if( 条件式 ) 実行文
　　　　例：if( a-b>15 ) a=a-1
　　　　条件式の演算子には、> または < が使用できるものとする。条件式が成立していたときには、実行文（複文も可）を実行する。

発生している問題・エラーメッセージ

問2の書き方が分かりません

該当のソースコード

%{
#include <stdio.h>
#include <stdlib.h>
#include "ch3-05.h"
#include <string.h>
#include <math.h>
%}

%union {
	double dval;
	struct symtab *symp;
}

%token <symp> NAME
%token <dval> NUMBER
%left '+' '-'
%left '*' '/'
%nonassoc UMINUS

%type <dval> expression
%%

statement_list:	statement '\n'
	|	statement_list statement '\n'
	;

statement:	NAME '=' expression	{ $1->value = $3; }
	|	expression		{ printf("= %g\n", $1); }
        |       statement ':'
	|       statement NAME '=' expression {$2 -> value = $4;}
	;

expression: expression '+' expression	{ $$ = $1 + $3; }
	|   expression '-' expression	{ $$ = $1 - $3; }
	|   expression '*' expression	{ $$ = $1 * $3; }
	|   expression '/' expression	{ if($3==0.0) yyerror("Divide by Zero");
					  else $$ = $1 / $3;  }
	|   '-' expression %prec UMINUS	{ $$ = -$2; }
	|   '(' expression ')'		{ $$ = $2; }
	|   NUMBER			{ $$ = $1; }
	|   NAME			{ $$ = $1->value; }
	|   NAME '(' expression ')'	{ if( $1->funcptr ) $$ = ($1->funcptr)($3);
					  else {
						printf("%s not a function.\n", $1->name);
					  }
					}
	;

%%

/* look up a symbol table entry, add if not present */
struct symtab *symlook(char *s)
{
	char *p;
	struct symtab *sp;

	for(sp=symtab; sp<&symtab[NSYMS]; sp++) {
		/* is it already here? */
		if( sp->name && !strcmp(sp->name, s) )  return sp;

		/* is it free */
		if( !sp->name ) {
			sp->name = strdup(s);
			return sp;
		}
		
		/* otherwise continue to next */
	}
	yyerror("Too many symbols");
	exit(1);   /* cannot continue */
} /* end of symlook */

void addfunc(char *name, double (*func)())
{
	struct symtab *sp = symlook(name);
	sp->funcptr = func;
}

int main()
{
	extern double sqrt(), exp(), log(), sin(), cos();

	addfunc("sqrt", sqrt);
	addfunc("exp",  exp);
	addfunc("log",  log);
	addfunc("sin",  sin);
	addfunc("cos",  cos);

	yyparse();

        return 0;
}

%{
#include "y.tab.h"
#include "ch3-05.h"
#include <math.h>
%}

%%

([0-9]+|([0-9]*.[0-9]+)([eE][-+]?[0-9]+)?)	{
				yylval.dval = atof(yytext);
				return NUMBER;  }

[ \t]		;  /* ignore white space */

[A-Za-z][A-Za-z0-9]*	{  /* return symbol pointer */
		  struct symtab *sp = symlook(yytext);
		  yylval.symp = sp;
		  return NAME; 
		}

"$"		{ return 0;  /* end of input */ }


\n	|":"
.		return yytext[0];
%%
void yyerror(char *errmsg)
{
    fprintf(stderr,"ERROR: %s at %s\n", errmsg, yytext);
}
yywrap() { }

試したこと

問1は”：”が入った際の処理を書くことで解決できましたが
問2では実行文にIFを入れなければならないのでつまずいてしまいました。
どのような書き方をすれば改良できるのでしょうか？
またプログラミング言語のYaccやLEXはどのように学習すればよいのでしょうか？
現在教授のレジュメのみで学習しているのですが、あまり深く学べていません。

Answer 1

ch3-05.h の内容がないので、struct symtab がどう定義されているか
よくわかりませんが、次の修正で何とかなりませんか？

yacc

 #include <math.h>
+double cond = 1;
 %}
 
+%token IF
 %token <symp> NAME
 %token <dval> NUMBER
+%left '<' '>'
 %left '+' '-'
 
-statement_list:    statement '\n'
-    |    statement_list statement '\n'
+statement_list:    statement '\n' { cond = 1; }
+    |   statement_list statement '\n' { cond = 1; }
     ;
 
-statement:    NAME '=' expression    { $1->value = $3; }
-    |    expression        { printf("= %g\n", $1); }
+statement:    NAME '=' expression    { if (cond) $1->value = $3; }
+    |   expression        { if (cond) printf("= %.15g\n", $1); }
         |       statement ':'
-    |       statement NAME '=' expression {$2 -> value = $4;}
+    |   statement NAME '=' expression {if (cond) $2 -> value = $4;}
+    |   IF  '(' expression ')' { cond = $3; }
     ;
 
     |   expression '/' expression    { if($3==0.0) yyerror("Divide by Zero");
                       else $$ = $1 / $3;  }
+    |   expression '<' expression    { $$ = $1 < $3; }
+    |   expression '>' expression    { $$ = $1 > $3; }

Lex

+if  { return IF; }
+
 ([0-9]+|([0-9]*.[0-9]+)([eE][-+]?[0-9]+)?)    {

Comments

[Amateur0845]

コメントありがとうございます。
正しく出力できました。
IFを1つのトークンとして考えるのですね
貴重なお時間を頂きましてありがとうございました。

Answer 2

ご参考: http://160.16.241.20/lectures/95/1995-04-SoftengExpr8.pdf

課題でこういうのを参考にするのもどうかと思いますが、入手しやすい参考資料があまりないんですよね。GNU 版の bison や flex にしても日本語マニュアルや書籍は入手しづらいでしょうし、もし本物の yacc, lex を使っているなら機能の差異があるでしょうし。

Comments

[Amateur0845]

なかなか難しいです。
参考になりました。
ありがとうございます。

[68user]

しょうもない訂正ですが、bison は GNU project での開発ですが、flex は GNU とは無関係でした。