windows bat で複数の異なるファイル名を取得し、異なる変数に格納したい。

Question

現在、Testフォルダというフォルダが作成されており、その配下に名前の異なるファイルが複数ある状態です。
下記に簡単な構造を書きました。

Test
|
|-------- File5
|
|-------- test_file
|
|-------- log
|
|-------- local_file
|
...etc

これら複数のファイル名をwindows bat ですべて異なる変数
例えば
%file1%=File5
%file2%=test_file

というようにファイル名を変数に格納していく処理を作成したいと考えています。
なお、このファイルの数は可変なので決まった数ではないです。

インターネットを使用して検索などはしましたが

for /f %%i in (Test/*) do (
echo %%i
)

というように1つの変数(%%i)にファイル名を格納していき
出力するという手法は見つかるのですが
ループごとに異なる変数に格納させるという方法がどうしてもみつからずに困っています。

どなたかご教授、お力添えをいただけないでしょうか？
よろしくお願いいたします。

Answer 1

バッチファイルに配列変数はありません。

変数名を動的に作成することで、擬似的に配列を実現することも可能ですが、配列に入れた後、どうしたいかをきちんと考えた上で、全体の処理を設計した方が良いです。

#回答追記

@echo off
setlocal
set N=0
for %%A in (X*) do call :SET "%%A"

echo 下記のどれかを選んでください
for /L %%I in (1,1,%N%) do call echo %%I: %%A%%I%%
:LOOP
set /P ANS="対象を番号で選択してください(1-%N%)>>"
if not defined ANS goto LOOP
if %ANS% LSS 1 goto LOOP
if %ANS% GTR %N% goto LOOP

call echo %%A%ANS%%%

exit /b

:SET
set /a N+=1
call set A%N%=%~1
exit /b

Comments

[tennk]

アドバイス、並びにご回答いただきありがとうございます。

こちらでは表記していなかったのですが
仮に、動的に変数を作成し疑似配列に格納した際は
配列の内容を出力し、ユーザに標準入力で操作したい対象を指定させたいと考えております。

予想しているコード：
rem "疑似配列 array[n]を作成、nはファイルの数だけループし、インクリメントする番号"
rem "=for文ループで取得したTest配下のファイル名を格納""
@array[1]=File5
@array[2]=test_file
@array[3]=log

rem "以下はfor文でn回出力"
echo 1:%array[1]%
echo 2:%array[2]%
echo 3:%array[3]%
rem "ここまで"

set /P ANSWER="対象を番号で選択してください(1/2/3)>>"

という処理を実行させたいと考えております。

[otn]

なるほど。それは配列が欲しいですね。
追記しておきます。

[otn]

A1 A2 A3 A4 。。。 という変数にセットしています。

[tennk]

otn様
お返事が遅れ申し訳ありません。

ご提示いただいたコードで目的の操作を実行することができました！
コードを読み込んだことで大変勉強になり、batにおいて変数をループで作成するノウハウも得られました
本当にありがとうございます。