arduino for文で文字を流したい

Question

前提・実現したいこと

初心者です。arduinoのlcdでfor文を使って文字を流したいのですが、うまく動きませんん。どのように修正するべきか教えていただけると幸いです。

発生している問題・エラーメッセージ

コードを実行すると、arduinoの左上に二本の縦線が表示されます。

該当のソースコード

#include <LiquidCrystal.h>
LiquidCrystal lcd(13,12,11,10,9,8);


void setup() {
  // put your setup code here, to run once:
 lcd.begin(16,2);

lcd.clear();
 delay(2000);
  
}

void loop() {
  char hi[13]="HellowWorld!";
  int p;
  for(p=0; p<=16; p++){
  int a=13;
  int r=0;
  lcd.setCursor(r,0);
  r++;
  if(r>16){
    r=0;
  }
  lcd.print(hi[a]);
  a--;
  if(a<0){
    a=13;
  } 
  delay(500);
  }
  
  
}

補足情報（FW/ツールのバージョンなど）

使用しているのはarduino nanoです。
配線に問題点はないと考えております。

Comments

[y_waiwai]

しつもんはなんでしょうか

[thkana]

配線は「絶対に」間違っていませんか? ショートや断線はありませんか?

[mika9]

y_waiwai様
質問を明記せず申し訳ありません。修正させて頂きます。

[mika9]

thkana様
ご指摘ありがとうございます。
他のプログラムでは問題なくlcdに文字を表示させることができていることから、配線の問題はないと考えております。

Answer 1

多くの間違いがあるので、何をしたいのかが正確に読み取れません。
例えば

for(p=0; p<=16; p++) {

>   int a=13;
>   int r=0;
>   lcd.setCursor(r,0);
>   r++;

は、lcd.setCursor(r,0);
の部分は直前にrを0にしているので
lcd.setCursor(0,0);
にするのと同じです。
ループごと数値を変えるなら
static int r=0;
が適当です。
また、r++となっているのでインクリメントしたいように思われますけど、
文字列をスクロールするのなら本来、読めるように左にスクロールします。
つまり、書き込み位置を買えるならr--が適当だと思います。

lcd.print(hi[a]);

だと、この「一文字」表示ですけど、これは想定通りなのでしょうか？
…

arduinoの左上に二本の縦線が表示

というのも、arduinoではなく、液晶画面ですよね？
現状では、深く追究することは止めておきます。

で、本来、どこからどこまで、またどちらにスクロールしたいのか・・・
また、変数が多くてわかりにくいと思います。

方法はいくつかあるでしょうけど、今回のに近い手法だと下記のような形です。

void loop() {
	char hi[13] = "HellowWorld!";
	for(int pos=16; pos>-13; pos--) {
		lcd.clear();
		if(pos>=0) {//文字が現れて左端に着くまで
			lcd.setCursor(pos, 0);
			lcd.print(hi);
		} else {//最後の消える部分
			lcd.setCursor(0, 0);
			lcd.print(&hi[-pos]);
		}
		delay(1000);
	}
}

他にも、固定した16文字分の表示用文字列を用意して、そこに毎回、表示させる状態に整形してから表示させる手法もよく見かけます。※スケッチは省きます。

もっとかんたんにするなら下記の手法です。
一度書き込んで、ハードのスクロール機能を使います。
いすれにしろ、多少はハード面（ドライバ）の事も知っておいたほうが良いです。

void setup() {
	lcd.begin(16, 2);
	lcd.clear();
	lcd.setCursor(16, 0);
	lcd.print("HellowWorld!");
}

void loop() {
	for(byte i=0; i<28; i++) {//全部
		lcd.scrollDisplayLeft();//左スクロール
		delay(1000);
	}
	lcd.home();
}

Answer 2

aやhi[a]、rが、どいういう値をとっているか、シリアルモニタに出力して、確認してはいかがでしょうか? 想定した値になっていますか?

最低限の修正という意味では、

  for(p=0; p<=16; p++){
  int a=13;
  int r=0;

を

  int a=13;
  int r=0;
  for(p=0; p<=16; p++){

に変更でしょうか。