自動でダウンロード後に自動で開いたExcelブックを取得する方法

Question

マクロを使って自動で以下を実行したいのですが、（★）の部分がどうもうまくいきません。
お知恵を貸していただきたく、考えられる原因等ありましたら指摘頂きたく。
それ以前は動作OKです。

（１）社内のサイトに行く
↓
（２）Excelファイル（正確には拡張子.csv）をダウンロードする
↓
（３）「ダウンロード通知バー」の「開く」を自動で押して、ダウンロードしたExcelファイルを開く
↓
（４）自動で開かれたワークブックオブジェクトを取得する（★）

---

コード

・
'（１）
（省略）
・
・
'（２）
（省略）
・
・
'（３）「ダウンロード通知バー」の「開く」を自動で押して、ダウンロードしたExcelファイルを開く
Dim o As IUIAutomation
Dim e As IUIAutomationElement
Set o = New CUIAutomation
Dim h As LongPtr
h = ie.hwnd
h = FindWindowEx(h, 0, "Frame Notification Bar", vbNullString)
If h = 0 Then Exit Sub

Set e = o.ElementFromHandle(ByVal h)
Dim iCnd As IUIAutomationCondition
Set iCnd = o.CreatePropertyCondition(UIA_NamePropertyId, "ファイルを開く")

Dim Button As IUIAutomationElement
Dim InvokePattern As IUIAutomationInvokePattern

While InvokePattern Is Nothing
DoEvents
Set Button = e.FindFirst(TreeScope_Subtree, iCnd)
Set InvokePattern = Button.GetCurrentPattern(UIA_InvokePatternId)
Wend
InvokePattern.Invoke

・
・
・
'（４）自動で開かれたワークブックオブジェクトを取得する（★）
Dim wb As Workbook
Dim new_wb As Workbook
Dim isFound As Boolean
isFound = False

Do Until isFound = True  ■
    For Each wb In Workbooks
        If wb.Name = "ダウンロードして開いたブック名.csv" Then
            Set new_wb = Workbooks("ダウンロードして開いたブック名.csv")
            isFound = True
        End If
        Exit For
    Next
Loop

Debug.Print (wb.Name) 'ブック名が取得できていない

追記 12/23 - Exit forの位置を修正したが取得できずフリーズする

hatena様のご指摘Exit forの位置を修正の上、再度コードを実行したところ、
呼び出し側のExcelファイルがフリーズしたままになってしまいます。
（エラーは吐かないが、無限ループしている？）

但し、上記コード ■ 部分にブレークポイントを設定し、
■以降をステップイン実行すると、問題なくwb.Nameが取得できます。

気になる点としては、（３）ダウンロードファイルを開く際に
「ダウンロード通知バー」から「開く」を押している点です
（コードは、上記コードブロック中（３）に追記）

Answer 1

Exit For の位置がおかしいです。

Do Until isFound = True
    For Each wb In Workbooks
        If wb.Name = "ダウンロードして開いたブック名.csv" Then
            Set new_wb = Workbooks("ダウンロードして開いたブック名.csv")
            isFound = True
            Exit For 'ここじゃないとダメ    
        End If
        Exit For 'ここだと1回目のループでループを抜けちゃいます。
    Next
Loop

ただ、Workbooks.Open で開いているなら、下記で取得できるはずです。

Workbooks.Open "ANALYSIS.XLS" 
Debug.Print ActiveWorkbook.Name

あるいは、

Dim new_wb As Workbook
Set new_wb = Workbooks.Open("ダウンロードしたブック名.csv")
Debug.Print new_wb.Name

追記

ループ処理の場合は、無限ループ対策を入れておいた方がいいでしょう。（試行回数を制限しておくとか）
また、別スレッドの終了(今回はブックを開く)を待つ場合は、ループ内に DoEvents を入れてOSに制御を返すようにします。

上記を考慮して、

'（４）自動で開かれたワークブックオブジェクトを取得する（★）
Dim wb As Workbook
Dim isFound As Boolean
isFound = False

Dim i As Long
For i = 1 To 1000 '試行回数1000回 適宜調整してください。
    For Each wb In Workbooks
        If wb.Name = "ダウンロードして開いたブック名.csv" Then
            isFound = True
            Exit For
        End If
    Next
    If isFound Then Exit For
    DoEvents
Next

If Not isFound Then
    MsgBox "開いたブックを取得できませんでした。"
    Exit Sub
End If

Debug.Print wb.Name

DoEvents を入れるだけではうまくいかない場合、Sleep か Application.Wait での待機をいれてみてください。

【VBA入門】Sleep関数(API)やWaitメソッドで処理を止める方法 | 侍エンジニア塾ブログ（Samurai Blog） - プログラミング入門者向けサイト

Comments

[koyamashinji]

ご回答誠に有難うございます。Exit forの位置でしたか。。初歩的なミスをやらかしてしまいました。
また、代替方法も提示いただきありがとうございます、そのような方法もあるのですね。参考になります。
ただ、開く際は、ダウンロード通知バーの「開く」をUIAutomationClientでいじっていますので、おそらく今回は使用できないかもしれません。
自宅ではエクセル環境がないので、また明日試してみます。

[koyamashinji]

hatena19様
質問に追記させて頂きましたが、Exit forの位置を修正後コード実行しましたが
呼び出し側Excelがフリーズしてしまいます。
ダウンロードファイルを「開く」コードを 追記しておりますので
考えられる原因があれば、ご教示頂ければ幸いです。

[koyamashinji]

hatena19様
追記に対するご回答誠にありがとうございます。大変助かりました。
DoEventsのみでは、いくらループ回数を増やしても取得できませんでしたが、
DoEventsの後に、Sleep 100 を入れることで、無事取得できました。
（自己解決欄には改めて正常動作を確認したコードを貼りつけます）

[koyamashinji]

hatena19様
> DoEvents を入れるだけではうまくいかない場合、Sleep か Application.Wait での待機をいれてみてください。

今回の場合だと、DoEventsだけでなく、Sleep 100を入れないと、取得できませんでしたが、
DoEventsだけだと うまくいかないのはなぜなのでしょうか。別の質問も立てたのですが、いまいち私の理解が及ばず。。
もし宜しければ教えてください。

Answer 2

hatena19様からご提示頂いたコードに基づき、（★）の部分は以下のコードで正常動作しました。

・
・
・
'（４）自動で開かれたワークブックオブジェクトを取得する（★）
Dim wb As Workbook
Dim isFound As Boolean
isFound = False

Dim i As Long
For i = 1 To 10000
    For Each wb In Workbooks
        If wb.Name = "ダウンロードして開いたブック名.csv" Then
            Set new_wb = Workbooks("ダウンロードして開いたブック名.csv")
            isFound = True
            Exit For
        End If
    Next
    If isFound Then
        Exit For
    Else
        DoEvents
        Sleep 100
    End If
Next

If Not isFound Then
    MsgBox "開いたブックを取得できませんでした。"
    Exit Sub
End If

Debug.Print wb.Name & "取得できました"