ファイルをコピーしたい

Question

前提・実現したいこと

「D:\test\hoge」フォルダにある拡張子が「log」のファイルの中身を「D:\test\hoge\fuga%S%_%SV_NAME%.log」ファイルにコピーするようなバッチファイルを作成したいです。
拡張子が「log」のファイルは複数あり、それぞれの中身を別ファイルにコピーしたいです。
しかし、以下のエラーが出ており、構文の誤りがどう誤っているかが分からないので、ご教授いただきたいです。
ファイル名は動いてから修正しようと考えているため、遅延評価変数が誤っている可能性がありますが、ご了承ください。

発生している問題・エラーメッセージ

コマンドの構文が誤っています。

該当のソースコード(エラーに関係しそうな部分を抜粋)

SET SV_NAME=aaa
FOR /R D:\test\hoge %%i in (*.log) do (
    SET FNAME=%%i
    SET S=!FNAME!:~0,21!
    SET COPY_SRC=D:\test\hoge\!FNAME!
    SET COPY_DST=D:\test\hoge\fuga\%S%_%SV_NAME%.log
    COPY %COPY_SRC% %COPY_DST%
    IF NOT ERRORLEVEL 0 (
        GOTO :ERR1
    )
)
EXIT /B 0

試したこと

FOR文ではなく、ファイル名を直に指定して実行するとしたいように動きました。
FOR文の直前でECHOで文字を出力しようとすると、出力されました。
FOR文の直後(SET FNAMEの直前)で ECHOで文字を出力すると、出力されませんでした。

なので、FOR文が誤っていると考えています。

補足情報（FW/ツールのバージョンなど）

Windows Server2016で動作させたいです。
PowerShellが使用できないため、バッチファイルで作成しています。

Answer 1

まずは間違いの指摘から。

1．for ～～ ( )内で設定した環境変数の値を参照したいのであれば、遅延環境変数展開を使う必要あり。
⇒ %S% を!S!。他も同様

2．環境変数の部分文字列を取り出す構文が間違っている。
⇒ !FNAME!:~0,21!じゃなくて!FNAME:~0,21!

3．&&iにはフルパスが入る。おそらく環境変数FNAMEにセットしたいのは、D:\test\hoge\foobar.logとかじゃなくてfoobar.logでは？
⇒ SET FNAME=%%iじゃなくてSET FNAME=%%~nxi

4．IF NOT ERRORLEVEL 0は、「ERROELEVELが0以上でなければ」、つまり「負なら」という意味だが、負はあり得ないので、絶対に真にならない
⇒ IF ERRORLEVEL 1 「1以上なら」

少なくともこれだけ間違ってます。

あと、FOR /R D:\test\hogeだと、D:\test\hogeにサブフォルダーがあるとその中を全部見ますが、サブフォルダーは無いですか？
って、fugaがありますね。

おそらく、/rを使わず、cdする方が良いと思われる。

setlocal enabledelayedexpansion

SET SV_NAME=aaa
cd /d D:\test\hoge
FOR %%i in (*.log) do (
    SET FNAME=%%i
    SET S=!FNAME:~0,21!
    SET COPY_SRC=!FNAME!
    SET COPY_DST=fuga\!S!_!SV_NAME!.log
    COPY !COPY_SRC! !COPY_DST!
    IF ERRORLEVEL 1 (
        GOTO :ERR1
    )
)
EXIT /B 0

Comments

[natsuki_yamamo]

たくさんの指摘をありがとうございました。
1つずつ修正します。

Answer 2

FOR /R D:\test\hoge %%i in (*.log) do (
%%i の使い方が誤っています。

こちらで実行したら、このようなメッセージ出てますな

---

ちと実行法が間違ってたようで、
真面目に実行させてみました。
D:\test\hoge には、a.logとb.log をいれてあります
COPYはREMにしてあります

D:\Users\Desktop>SET SV_NAME=aaa

D:\Users\Desktop>FOR /R D:\test\hoge %i in (*.log) do (
SET FNAME=%i
 SET S=!FNAME!:~0,21!
 SET COPY_SRC=D:\test\hoge\!FNAME!
 SET COPY_DST=D:\test\hoge\fuga\!FNAME!:~0,21!_aaa.log
 rem COPY D:\test\hoge\!FNAME! D:\test\hoge\fuga\_aaa.log
 IF NOT ERRORLEVEL 0 (GOTO :ERR1 )
)

D:\Users\Desktop>(
SET FNAME=D:\test\hoge\a.log
 SET S=!FNAME!:~0,21!
 SET COPY_SRC=D:\test\hoge\!FNAME!
 SET COPY_DST=D:\test\hoge\fuga\!FNAME!:~0,21!_aaa.log
 rem COPY D:\test\hoge\!FNAME! D:\test\hoge\fuga\_aaa.log
 IF NOT ERRORLEVEL 0 (GOTO :ERR1 )
)

D:\Users\Desktop>(
SET FNAME=D:\test\hoge\b.log
 SET S=!FNAME!:~0,21!
 SET COPY_SRC=D:\test\hoge\!FNAME!
 SET COPY_DST=D:\test\hoge\fuga\!FNAME!:~0,21!_aaa.log
 rem COPY D:\test\hoge\!FNAME! D:\test\hoge\fuga\_aaa.log
 IF NOT ERRORLEVEL 0 (GOTO :ERR1 )
)

ファイル名の生成のところがタコってるようですね