スクリプト言語を使ってバイナリのデータを解析して不要な箇所を削除したい

Question

とあるJpegの送信を行ったTCP通信時のバイナリデータがあります。
そこから不要な情報を削除してJpegデータを復元したいと思っています。
条件は以下の通りです。

[前提条件]
以下のヘッダにJpegを分割してくっ付けて送っています。

identifier[4 byte] = "DCAA"
result[2 byte]
command_id[2 byte] = 0001H～02FFH
length[4 byte] = dataサイズ
data[n byte] = Jpegデータ

ここから分割したJpegデータを抜き出し復元したい(パケットのロスや重複は考えないものとします)

[手順]

1. バイナリデータを先頭から見ていき"DCAA"が出るまで読み飛ばす
2. "DCAA"が出てきたらcommand_idを見て0202Hであるか確認する(それ以外のコマンドが持っているdataはJpegではない)
3. 0202Hであれば identifier～length を削除する
4. 0202H以外であれば identifier～data を削除する
   以下ファイルの終端まで繰り返し

これをperlで実現しようと思っています。

MAIN:{
    my $buf, $size;

    #ファイルオープン
    open ( IN, "< $_$ARGV[0]" ) or die "$!";	# in
    open ( OUT, "> $ARGV[1]]" ) or die "$!";	# out

	binmode IN;
	binmode OUT;

	$size = -s $_$ARGV[0];

	read(IN, $buf, $size);

	my $identifier = "DCAA";

	# 16進バイナリ から 文字列 への変換
	my @ascii = unpack('H*', $buf);
	for my $i (0..$#ascii){
		if ( $#ascii eq $identifier ){
			# ....
		}
	}

ここまでやりました。

教えていただきたい事は

• バイナリデータとアスキーデータの比較
• バイナリデータの削除(これはバイナリ出力時に読み飛ばせばいいかな)
• バイナリデータのシーク

の３つを教えてください。
よろしくお願いします。

Answer 1

unpackしないほうが楽そうだったので、readで少しずつ読みながら基本バイナリのままで処理してみました。
エラー処理など細かいところは省略してます。
なお、シークするにはそのままseekという関数があるのでこれでシークできます（以下のコードでは使ってませんが）。

use strict;
{
  open(my $in, "<:raw", $ARGV[0]) or die $!;
  
  # DCAAまで読み飛ばす
  my $last_4byte;
  read($in,$last_4byte,4); #readの戻り値チェックは省略
  while( $last_4byte ne "DCAA" ){
    # 1byte捨てて1byte読む
    $last_4byte = substr($last_4byte,1);
    if ( read($in,$last_4byte,1,3) < 1 ) {
      die "Not found.";
    }
  }

  # resultとcommand_id、command_idチェック
  my $result;
  my $command_id;
  read($in,$result,2);
  read($in,$command_id,2);
  if ( $command_id ne "\x02\x02" ) {
    die "No JPEG."; #読み飛ばしは省略、後ろで$data捨てれば良い
  }

  # length
  my $length;
  read($in,$length,4);
  my $length_val = unpack("N", $length); # 符号無し4バイト整数、ビッグエンディアン

  # data
  my $data;
  read($in,$data,$length_val);

  #必要なところだけ出力
  open(my $out, ">:raw", $ARGV[1]) or die $!;
  print $out $data;
  close($out);


  #繰り返し省略

  close($in);
}

---

それから、この部分ですが、

# 16進バイナリ から 文字列 への変換
my @ascii = unpack('H*', $buf);

このコメントは不正確で、正しくはバイナリを16進数文字列に変換します（1バイトが16進数2文字になる）。
要素数は1になるので、後ろのループは1回しか回らないですね。

my $hex_str = unpack('H*', "123");
if ( $hex_str eq "313233" ) {
  print "Match!\n";
}

#これだと各バイトを数値にした配列が得られる
my @bytes = unpack('C*', "123");
if ( $bytes[0] == 0x31 && $bytes[1] == 0x32 && $bytes[2] == 0x33 ) {
  print "Match!\n";
}

Comments

[izuki_y]

回答ありがとうございます。

unpackを使わない条件比較の方法など大変参考になりました。
今は教えていただいた事を参考にしながら組んでいます。

```
while( $last_4byte ne "DCAA" ){
# 1byte捨てて1byte読む
$last_4byte = substr($last_4byte,1);
if ( read($in,$last_4byte,1,3) < 1 ) {
die "Not found.";
}
}
```
で読み取りが飛ばされる事がある気がしてましてそれを検証しています。
本当なら整形する元データを提示したいのですが、申し訳ないです。
また分かりしだいコメントを書かせてください。

[izuki_y]

失礼な事を言って申し訳ありませんでした。
読み飛ばしてると感じたのはこちらの確認ミスでした。

改めてもう一度やり直したら正しくデータを取得することが出来ました。
本当にありがとうございました。