【Excel】マクロでの自動転記の際、転記先を自動で次の行にするVBA

Question

お世話になります。
Excelで次のような行を自動転記したいです。
その際、転記先に毎回次の行に自動転記するVBAを教えていただきたいです。

品番	品名	金額
1090	えんぴつ	500円

'
' Macro1 Macro
'
    Range("A2:C2").Select
    Selection.Copy
    Workbooks.Open Filename:="C:\Users\tkyks\Desktop\data.xlsx"
    Range("A1").Select
    ActiveSheet.Paste
    Range("A2").Select
End Sub

コード

上記のVBAだと毎回転記先（data.xlsx）のA1に転記されてしまうので、それを毎回次の行に転記するようにしたいです。

マクロ、VBAはまったくの初心者のため初歩的な質問申し訳ありません。
どうぞ宜しくお願い申し上げます。

Answer 1

ちゃんとやるならこんな感じでしょうかね。
※SelectやActiveSheetを対象とした処理はお勧めしないので、全面的に修正しています。

Dim aws As Worksheet
Dim wb As Workbook
Dim ws As Worksheet
Dim lastRow As Long

Set aws = ActiveSheet
Set wb = Workbooks.Open(Filename:="C:\Users\tkyks\Desktop\data.xlsx")
Set ws = wb.Worksheets(1)

lastRow = ws.Cells(Rows.Count, 1).End(xlUp).Row
If ws.Cells(lastRow, 1) <> "" Then lastRow = lastRow + 1

aws.Range("A2:C2").Copy ws.Cells(lastRow, 1)

Comments

[tkyk.]

ttyp03さん
ありがとうございます！
教えていただいたVBAで出来ました！！
ただ内容は全く理解できず･･･
ちなみにSelectやActiveSheetを対象とした処理はなぜお勧めしないのでしょうか。

[ttyp03]

>ただ内容は全く理解できず･･･
簡単に説明しておきます。
最初のSetの3行はわかりますよね。
マクロを実行している自身のシートと、新たにオープンするブックから一番目のシートをオブジェクト変数に格納しています。
lastRowを求める処理は、シート内最終行(Rows.Count)から上(xlUp)に向かって入力があるセルを探します。
キーボードでCtrl+↑をやるのと同じ操作です。
If文は初回の空シート時の対応です。
最後の行でコピペです。

>SelectやActiveSheetをお勧めしない理由
まずは処理速度の問題です。
特定のシートを選択してアクティブにして、という動作は時間がかかるものです。
次に動作環境に左右されるのを避けるためです。
アクティブになっていることを前提として作ると、今のPCで今の処理であれば問題ないですが、将来的に処理を追加したり、別のPC（処理速度が遅いPCとか逆に快適すぎるPCとか）で実行した場合に意図した動作にならない場合が多々あります。
同じPCであっても裏で何か重い処理をしているとアクティブにしたつもりでも切り替わりに時間がかかってしまい、目的のシートを参照できない可能性があります。

[tkyk.]

ttyp03さん
ご説明いただきありがとうございます！
また、お返事が遅くなり大変申し訳ありません。
ちなみに上記のVBAで出来たのですがセルの値のみ転記したい場合は下記VBAをどのように変えれば良いのでしょうか。
aws.Range("A2:C2").Copy ws.Cells(lastRow, 1)
重ねての質問すみません。
宜しくお願い致します。

[ttyp03]

こんな感じでできると思います。

aws.Range("A2:C2").Copy
ws.Cells(lastRow, 1).PasteSpecial Paste:=xlPasteValues

[tkyk.]

ttyp03さん
ありがとうございます！
無事に出来ました。
本当に助かりました。
ありがとうございます。
また質問させていただく際は新たにページ作成させていただきます。

[tkyk.]

度々申し訳ございません。
ちなみにですが、転記したい元のシートを指定することは可能でしょうか。
シート名は「転送用シート」です。
可能な場合、どの部分にどのようなVBAを追加すれば宜しいのでしょうか。
重ねての質問申し訳ありません。
宜しくお願い致します。

[tkyk.]

すみません。
自己解決出来ました！
ありがとうございます。
また宜しくお願い致します。

Answer 2

"次の行"が、転記先Bookの、転記元で選択した行の次の行ということですよね。
以下でいかがでしょうか。

・Range("A2:C2").Select の次に現在の行番号を変数として取得します。
例）SourceCellRow = ActiveCell.Row
・ファイルを開いた後に、上記の次の行を選択させます。
例）Cells(SourceCellRow + 1, 1).Select
・ペーストします。

Comments

[tkyk.]

Otoniseさん
ありがとうございます！
”次の行”は転記先Bookの次の行という意味でした。
例）転記元Book　A2:C2　を　転記先Book　A2　に転記
　　　↓
　　転記元Book　A2:C2　を　転記先Book　A3　に転記
というように転記先のみ次の行に移動して行を足していくイメージです。
文章では伝わりにくく申し訳ありません。