複数条件での数列を挿入

Question

前提・実現したいこと

A-1-1,
A-1-2
：
：
A-2-1
A-2-2
:
:
B-1-1
B-1-2……というように特定の順番でできた文字列を順番にセルに挿入したい。
最後の番号が20になると、2番目の番号が変化し、また最後の番号が20になるまで繰り返S。

発生している問題・エラーメッセージ

挿入するセル行の変更がうまくゆかず、他の文字列に上書きされている。

該当のソースコード

言語はVBAです。
Dim i, j As Long
Dim c As String
For i = 1 To 7
For j = 1 To 20
c = Chr(i + 64)
Range("D" & i + j + 1).Value = c & "-" & i & "-" & j
Next j
Next i

試したこと

セル行をカウントする代数を入れたが、同じ文字列を繰り返すだけだった。

Answer 1

行を指定するカウンター変数をループ変数とは別に用意してみました。

Sub ABC()
    'VBAの場合、変数ごとに型指定
    Dim i As Long, j As Long, k As Long 'ループ変数
    Dim Cnt As Long 'カウンター変数
    Cnt = 3
    For i = 1 To 26
        For j = 1 To 20
            For k = 1 To 20
                Range("D" & Cnt).Value = Chr(i + 64) & "-" & j & "-" & k
                Cnt = Cnt + 1
            Next k
        Next j
    Next i
End Sub

Answer 2

3つの値が必要なのにループが2つという時点でおかしいですね。
計算で挿入位置を求めてもよいですが、行カウンターを用意する方がわかりやすいでしょう。

Dim i, j, k, r As Long
Dim c As String
r = 1
For i = 1 To 7
    c = Chr(Asc("A") + i - 1)
    For j = 1 To 10
        For k = 1 To 20
            Cells(r, "D").Value = c & "-" & j & "-" & k
            r = r + 1
        Next k
    Next j
Next i

また余談ですがChr(i + 64)では可読性が悪いので、上記サンプルではAを基準として計算するように修正しています。

Answer 3

最後の番号は20までというのは分かったが、2番目の番号はいくつまでか不明です。
2番目の番号も20までとすると、下記のコードでどうでしょうか。

Sub Test()
    Dim i As Long, j As Long, k As Long, r As Long
    Dim c As String

    r = 1
    For i = 1 To 7
        c = Chr(i + 64)
        For j = 1 To 20
            For k = 1 To 20
                Range("D" & r).Value = c & "-" & j & "-" & k
                r = r + 1
            Next k
        Next j
    Next i

End Sub

---

別案
変数は一つ、ループも１階層で。

Sub Test2()
    Dim r As Long

    For r = 0 To 7 * 20 * 20 - 1
        Range("E" & r + 1).Value = Chr(r \ (20 * 20) + 65) & "-" & _
                               (r \ 20) Mod 20 + 1 & "-" & r Mod 20 + 1
    Next r

End Sub