複数フィールドをAND検索で抽出する場合の「実施日の期間の抽出」部分の記述

Question

前提・実現したいこと

業務でACCESSを使い検索フォームを作ることになり勉強中の身です。
本やネットを参考にしながらプロシージャを書いています。
カテゴリと内容の抽出などはうまく動いてくれるのですが、
下記の検索ボタン部分のプロシージャの記述に沿った
「実施日」の期間を指定する書き方がわからずにいます。
ご教授いただければ幸いです。
こういった場に質問を書き込むのも初めてな為、
不足している内容があれば追記させていただきます。
よろしくお願いいたします。

発生している問題・エラーメッセージ

Private Sub 検索_Click()
Dim strSearch As String

　strSearch = ""
If txt面談ID <> "" Then
strSearch = "(面談ID Like '" & txt面談ID & "*')"
End If

　（※実施日の抽出）

　If cmb実施者 <> "" Then
If strSearch <> "" Then strSearch = strSearch & " AND "
strSearch = strSearch & "(実施者 Like '" & cmb実施者 & "')"
End If

　If cmbカテゴリ <> "" Then
If strSearch <> "" Then strSearch = strSearch & " AND "
strSearch = strSearch & "(カテゴリ Like '" & cmbカテゴリ & "')"
End If

　If txt内容 <> "" Then
If strSearch <> "" Then strSearch = strSearch & " AND "
strSearch = strSearch & "(内容 Like '" & txt内容 & "')"
End If

　If txt備考 <> "" Then
If strSearch <> "" Then strSearch = strSearch & " AND "
strSearch = strSearch & "(備考 Like '" & txt備考 & "')"
End If

　Forms!F_面談.Filter = strSearch
Forms!F_面談.FilterOn = True
Forms!F_面談.AllowAdditions = False

End Sub

試したこと

検索フォーム部分には
「txt実施日開始」と「txt実施日終了」の入力欄を置いています。
開始から終了までの期間に実施された面談の情報に絞り込みたいです。

Answer 1

txt実施日開始やtxt実施日終了の入力形式をどのようにしているかや実施日の型が不明ですが、それぞれ日付の形式であるとして回答します。

複数の項目による条件式の場合、文字列としての結合を一定にして、最終的に不要部分をカットするようにするとすっきりします。

strSearch = ""

If txt面談ID <> "" Then strSearch = strSearch & " AND " & "(面談ID Like '" & txt面談ID & "*')"

If cmb実施者 <> "" Then strSearch = strSearch & " AND " & "(実施者 Like '*" & cmb実施者 & "*')"

If cmbカテゴリ <> "" Then strSearch = strSearch & " AND " & "(カテゴリ Like '*" & cmbカテゴリ & "*')"

If txt内容 <> "" Then strSearch = strSearch & " AND " & "(内容 Like '*" & txt内容 & "*')"

If txt備考 <> "" Then strSearch = strSearch & " AND " & "(備考 Like '*" & txt備考 & "*')"

If IsDate(txt実施日開始) Then strSearch = strSearch & " AND (実施日>=#" & txt実施日開始 & "#)"

If IsDate(txt実施日終了) Then strSearch = strSearch & " AND (実施日<=#" & txt実施日終了 & "#)"

If strSearch <> "" Then
    Forms!F_面談.Filter = Mid(strSearch, 5)
    Forms!F_面談.FilterOn = True
    Forms!F_面談.AllowAdditions = False
End If

Comments

[ohana_kirei]

お返事が遅くなってしまいすみません。
実施日は日付の形式で入れておりました。
説明不足で申し訳ないです。
記述の部分ですが、このようにすっきりと書けるものなのですね。
とても参考になりました。
今後フォームを作るときはこの書き方でやってみたいと思います。
ご回答いただきありがとうございました。

Answer 2

検索フォーム部分には

「txt実施日開始」と「txt実施日終了」の入力欄を置いています。
開始から終了までの期間に実施された面談の情報に絞り込みたいです。

以下でどうでしょうか。

    If Me.txt実施日開始 <> "" Then
        If IsDate(Me.txt実施日開始) Then
            If strSearch <> "" Then strSearch = strSearch & " AND "
            strSearch = strSearch & "(実施日>=#" & Me.txt実施日開始 & "#)"
        Else
            Me.Me.txt実施日開始.SetFocus
            MsgBox "正しい日付を入力してください。"
            Exit Sub
        End If
    End If

    If Me.txt実施日終了 <> "" Then
        If IsDate(Me.txt実施日終了) Then
            If strSearch <> "" Then strSearch = strSearch & " AND "
            strSearch = strSearch & "(実施日<=#" & Me.txt実施日終了 & "#)"
        Else
            Me.Me.txt実施日終了.SetFocus
            MsgBox "正しい日付を入力してください。"
            Exit Sub
        End If
    End If

開始のみ入力の場合は、開始以降すべて
終了のみ入力の場合は、終了以前すべてを抽出するという仕様です。

Comments

[ohana_kirei]

お返事が遅くなってしまいすみません。
ご回答いただきありがとうございます。
教えていただいた部分を入れたところ、正しく動作するようになりました。
前後の記述にも合わせてくださったおかげで読みやすく管理もしやすそうです。
大変助かりました、ありがとうございました。