ACCESS 空白日付でのレコード抽出方法

Question

前提・実現したいこと

ACCESSにて、下記の様に２つのテキストボックスに日付を入れるとレコードが抽出できるフォームを作成しました。

テキストボックス１（yyyy/mm/dd）
テキストボックス２（yyyy/mm/dd）
[検索ボタン]

日付の始まりと終わりを入れると、レコードは抽出できるのですが、
⇒始まりが空白の場合は、終わりの日付より前の日付を全て抽出
⇒終わりが空白の場合は、始まりの日付より後の日付を全て抽出
最終的に、上記の様したいのですがうまくいきません。

コードが原因かと思うのですが、どのように改善したらよろしいでしょうか？

試したこと

テキストボックスが空白の場合、
テキストボックスの値が、1000/01/01　or　9999/12/31　となるようにしたらよいかなと思い、
下記コードにしたのですが、デバックするとテキストボックスが空白とみなされていないようです。

Nullのところを””にしても同じ結果でした。

該当のソースコード

Private Sub btn_3_Click()
  
  Me.FilterOn = False
  
  If Me.tx1 = Null Then
     Me.tx1.Value = "1000/01/01"
  End If
  
  If Me.tx2 = Null Then
     Me.tx2.Value = "9999/12/31"
 End If
  
  Me.Filter = "Day Between #" & tx1 & "# And #" & tx2 & " #"
  Me.FilterOn = True

End Sub

ご教授よろしくお願いいたします。

Answer 1

  If Me.tx1 = Null Then

Null値は=では判定できません。IsNull関数を使ってください。

  If IsNull(Me.tx1) Then

あるいは、空白が入力されていたり、""（長さ0の文字列）の場合も考慮するなら、下記の方かいいでしょう。

  If Trim(Nz(Me.tx1))="" Then

---

解決済みですか、補足説明。
蛇足かもしれませんが、現状だと日付として正しくないものを入力したときにエラーになります。
例えば、"2020/11/31"とか。IsDate関数で日付として正しいかもチェックした方かいいでしょう。

自分が書くなら下記のような感じになります。

Private Sub btn_3_Click()
  Dim strFilter As String

  If Trim(Nz(Me.tx1.Value))="" Then
     Me.tx1.Value = Null
  ElseIf IsDate(Me.tx1.Value) Then
     strFilter =" AND Day >= #" & Me.tx1.Value & "#
  Else
     Msgbox "日付として正しい値を入力してください。"
     Me.tx1.SeFocus
     Exit Sub
  End If

  If Trim(Nz(Me.tx2.Value))="" Then
     Me.tx2.Value = Null
  ElseIf IsDate(Me.tx2.Value) Then
     strFilter =" AND Day <= #" & Me.tx2.Value & "#
  Else
     Msgbox "日付として正しい値を入力してください。"
     Me.tx2.SeFocus
     Exit Sub
  End If

  strFilter = Mid(strFilter, 6) '先頭の" AND "を削除
  Me.Filter = strFilter
  Me.FilterOn = (strFilter <> "")

End Sub

Comments

[YISS]

解決しました。ありがとうございます。

[YISS]

アドバイスありがとうございます。より、よくすることができました。

質問なのですが、
Me.FilterOn = (strFilter <> "" )と、
Me.FilterOn =True
では、結果が変わってくるのでしょうか？

ちなみに、コードは最終的に下記の様にさせて頂きました

Private Sub btn_3_Click()

Me.FilterOn = False
Dim strFilter As String

If Me.tx1 > Me.tx2 Then
MsgBox "開始日が、終了日より後の日付です"
Exit Sub
End If

If Trim(Nz(Me.tx1.Value)) = "" Then
Me.tx1.Value = Null
ElseIf IsDate(Me.tx1.Value) Then
strFilter = " AND Day >= #" & Me.tx1.Value & "#"
Else
MsgBox "日付として正しい値を入力してください。"
Me.tx1.SetFocus
Exit Sub
End If

If Trim(Nz(Me.tx2.Value)) = "" Then
Me.tx2.Value = Null
ElseIf IsDate(Me.tx2.Value) Then
strFilter = strFilter & " AND Day <= #" & Me.tx2.Value & "#"
Else
MsgBox "日付として正しい値を入力してください。"
Me.tx2.SetFocus
Exit Sub
End If

strFilter = Mid(strFilter, 6)
Me.Filter = strFilter
Me.FilterOn = (strFilter <> "")

End Sub

[hatena19]

Me.FilterOn = (strFilter <> "" )
の意味ですが、strFilter <> "" は strFilter が空("")のときFalse、文字が格納さていればTrueになります。
日付テキストボックスが両方とも未入力の場合、strFilter が空("")になるのでMe.FilterOn はFalseに、
条件式が格納されていればMe.FilterOn がTrueになるということになります。

[YISS]

理解できました。ご丁寧にありがとうございます。