VBA - 複数のAND条件のコードを簡略化できないか

Question

下記のコードは、cells(i, "B")の値が「特定の文字列」でないものを、行ごと削除するマクロです。
条件文And Notを以下のように条件数の分だけ書くほかに、もっと簡略な記述方法があれば教えていただきたく。
是非よろしくお願いします。

（省略）
For i = LastRow To 2 Step -1
    Dim cellValue As String
    cellValue = Cells(i, "B").Value
    If Not cellValue = "文字列１"  And Not cellValue = "文字列２" _
                            And Not cellValue = "文字列３" _ 
                            And Not cellValue = "文字列４" _
                            And Not cellValue = "文字列５" _
                            And Not cellValue = "文字列６" _
                            And Not cellValue = "文字列７" _
                            And Not cellValue = "文字列８" _    
　　　　　　　　　　　　　　　　 ・
　　　　　　　　　　　　　　　　 ・
　　　　　　　　　　　　　　　　（省略）
　　　　　　　　　　　　　　　　 ・
　　　　　　　　　　　　　　　　 ・
                            And Not cellValue= "文字列２０" Then
        Cells(i, "B").EntireRow.Delete
    End If
Next i

Answer 1

アルファベットのa~zまでの場合でないもの

Like演算子を使うと簡単です。

    cellValue = Cells(i, "B").Value
    If Not cellValue Like "[a-z]" Then
        Rows(i).Delete
    End If

Like 演算子 | Microsoft Docs

---

単純に抽出したい条件が膨大な量存在する（cells(i,"B").valueが●●でもなければ、■■でもなく、▽▽でもなく、▲▲でもなく・・・（続く）」場合、

    Dim strList As String
    strList = ";●●;■■;▽▽;▲▲;"

    cellValue = Cells(i, "B").Value
    If InStr(strList, ";" & cellValue & ";") = 0 Then
        Rows(i).Delete
    End If

---

数が膨大かつ修正することを結構あるのなら、シート上に入力しておいて、FindメソッドがMatch関数で検索するのがいいでしょう。

Match関数を使用する場合のコード例

ItemListシートのA1からワードのリストを入力しておく。

標準モジュールに下記の関数を作成

'Item が List に存在したら True を返す
Public Function ListCheck(Item As String) As Boolean
    Dim r As Double
    On Error Resume Next
    r = Application.Match(Item, Worksheets("ItemList").Range("A1").CurrentRegion, 0)
    ListCheck = (Err = 0)
End Function

行削除処理

    cellValue = Cells(i, "B").Value
    If Not ListCheck(cellValue) Then
        Rows(i).Delete
    End If

Comments

[koyamashinji]

ご回答誠に有難うございました。簡潔なコードで大変わかりやすいです。またよろしくお願いいたします。

Answer 2

正規表現を使うなど、他にもいろいろ手段はありそうですがこの条件であればASCIIコードを利用してチェックするのが手っ取り早そうです。

前提知識

• 文字には1文字ずつ ASCIIコード と呼ばれる番号が振られている
• a は 97 、以降アルファベット順に z は 122 まで連番で振られている（つまりASCIIコードの数値比較で判定できる）
• 対象の文字のASCIIコードが 97 ～ 122 でなければ、a ～ z ではない
• ただし、VBAでASCIIコードを取得する関数 ASC() は引数に与えられた文字列の1文字目のASCIIコードを返すため対象の文字列が1文字かどうかを判定しておく必要がある

コード例

' 文字列が1文字でない場合、
' または 文字列のASCIIコードが "a" のものより小さい
' または 文字列のASCIIコードが "z" のものより大きい
If (Len(cellValue) <> 1) _
    Or (Asc(cellValue) < Asc("a")) _
    Or (Asc(cellValue) > Asc("z")) Then

    ' i 行を削除
    Rows(i).Delete
End If

参考） https://www.relief.jp/docs/excel-vba-for-next-from-a-to-z.html

追記 2020-12-04 23:40

コメントでいただいた要件を踏まえたサンプルコードです。

メイン処理側の呼び出し例

別途作成した str_check関数 を条件として行削除するコード例。

If str_check(cellValue) Then
    ' i 行を削除
    Rows(i).Delete
End If

チェック関数例

同じファイルのシート cond のA列に A1セル A2セル ・・・ にチェック対象となるリストが作られている想定。
リストに空白はなく、各行を評価して空白セルが出てきたらリストの終了とみなす

' チェック関数 ： この関数の返り値が true の場合、行削除
Function str_check(check_strings As String) As Boolean
    Dim tmpRet As Boolean   ' チェック結果を管理しておく変数
    tmpRet = True   ' デフォルト True （=削除対象）と考える

    
    ' 仮に同じブックの cond シートのA列に対象外としたい文字列のリストがあるとした場合
    Dim ws As Worksheet
    Set ws = ActiveWorkbook.Sheets("cond")  ' cond シート

    Dim rowCount As Long    ' cond シートの参照行番号
    rowCount = 1

    
    ' cond シートのA列を1行目からたどる
    '   A列の rowCount 行が空白となった場合、リストの終了とみなす
    Do Until ws.Cells(rowCount, 1).Value = ""
    
        '   文字列と一致した場合、関数の結果を false としてチェックを終了する
        If check_strings = ws.Cells(rowCount, 1).Value Then
            tmpRet = False
            Exit Do
        End If
        
        ' リストの次の行を参照先としてループ
        rowCount = rowCount + 1
    Loop
    

    ' 関数の返り値を設定
    str_check = tmpRet
End Function

Comments

[koyamashinji]

なるほど。大変勉強になります。

条件がアルファベットa~zに限らず、単純に抽出したい条件が膨大な量存在する（cells(i,"B").valueが●●でもなければ、■■でもなく、▽▽でもなく、▲▲でもなく・・・（続く）」場合、どのような簡略化が考えられるでしょうか。

[kaz.Suenaga]

規則性がない文字列、ということであれば別途用意したシート上でも、ソースコード内でコードとして書くにしても、何かの形でリストを作ることは必要になりますね。

そのリストを基に、別途チェック関数を作り、その関数の結果を true / false で返すようにし、その関数を If の条件式に使う、というのが標準的な方法になると思います。

条件に利用したい文字列がどこかで定義されている、など、何か要件はありますか。

[koyamashinji]

条件に利用したい文字列は、コードの中に直接記述してしまおうかと思っていましたが、都度管理が大変なので（対象文字列の数が増えたり減ったりする）、別シートに記載し可変範囲として定義するのが良いかと考えています。

[kaz.Suenaga]

回答に追記しました。

[koyamashinji]

ご回答誠に有難うございました。
丁寧に具体的なコードの説明をしてくださり、考え方を理解することができました。週明けに会社で早速試してみます。

Answer 3

以下でどうでしょうか。

・・・省略・・・
    cellValue = Cells(i, "B").Value
    If Len(cellValue) <> 1 Or Asc(cellValue) < Asc("a") Or Asc(cellValue) > Asc("z") Then
        Cells(i, "B").EntireRow.Delete
    End If
・・・省略・・・